XL 2010 Calcul du nombre de jour et nombre mois sur année 2020

Marylgb · 12 Avril 2021

bonjour

j'aimerai pouvoir calculer le nb de jour et le nb de mois entre deux date ou "sans date de fin".
En PJ le fichier exemple.
merci d'avance
bonne journée

Dan · 12 Avril 2021

Bonjour

pour les jours, à essayer en D2 pour tirer vers le bas
=SI(C2<>"";DATEDIF("1/1/2020";C2;"yd")&" jours ";DATEDIF("1/1/2020";AUJOURDHUI();"yd")&" jours ")

Crdlt

JHA · 12 Avril 2021

Bonjour à tous,
Bonjour @Dan

Dans la même lignée avec datedif() et ce que je comprends
Nbre de jours

VB:

=SI($B2>"31/12/2020"*1;"";DATEDIF(MAX($B2;"01/01/2020"*1);SI($C2="";"31/12/2020"*1;MIN($C2;"31/12/2020"*1));"d"))

Nombre de mois

Code:

=SIERREUR(SI($B2>"31/12/2021"*1;"";DATEDIF(MAX($B2;"01/01/2021"*1);SI($C2="";MIN(AUJOURDHUI();"31/12/2021"*1);MIN($C2;AUJOURDHUI()));"m"));"")

JHA

mapomme · 12 Avril 2021

Bonjour,

Un autre calcul de jours de "présence".
Pour moi, un quidam embauché pour un jour entre, par exemple, le 05/02/2020 et sort le même jour. Il a un jour de présence. En fait ce qui compte et fait sens (à mon avis) n'est pas sa date de sortie, mais son dernier jour de présence (qu'il faut comptabiliser).

Formule :

VB:

=SOMMEPROD(--(ANNEE(LIGNE(INDIRECT($B2& ":" & MIN($C2;SI($C2="";AUJOURDHUI();$C2)))))=2020))

Quant au mois, c'est une notion que je ne connais pas sans précision.

X rentre le 1 janvier quitte le 15 janvier. Combien de mois ?
X rentre le 1 janvier quitte le 15 février. Combien de mois ?

job75 · 12 Avril 2021

Bonjour Marylgb, Dan, JHA, mapomme,

Oui il faut compter le 1er jour de présence et le dernier, formule en D2 :

Code:

=MAX(0;SI(C2="";"31/12/2020";MIN(C2;DATEVAL("31/12/2020")))-MAX(B2;DATEVAL("1/1/2020"))+1)

Et en E2 le nombre de mois avec au moins 1 jour de présence :

Code:

=MAX(0;JOURS360(MAX(DATEVAL("31/12/2019");DATE(ANNEE(B2);MOIS(B2);0));SI(C2="";"31/12/2020";MIN(DATEVAL("31/12/2020");DATE(ANNEE(C2);MOIS(C2)+1;0))))/30)

Notez que pour alléger on peut omettre le zéro quand l'argument d'une fonction MAX ou DATE est nul.

A+

XL 2010 Calcul du nombre de jour et nombre mois sur année 2020

Marylgb

XLDnaute Occasionnel

Pièces jointes

Dan

XLDnaute Barbatruc

JHA

XLDnaute Barbatruc

Pièces jointes

mapomme

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

Discussions similaires