XL 2013 calcul de charge + planification

[jasmine]

Salut Forum,
je bosse sur un projet de panification de l'activité du "contrôle qualité" mais je bloque sur un truc. Donc j'ai décidé de me diriger vers vous en espérant que vous m’aiderez par ce que c’est super important dans mon stage.
J’ai mis un fichier joint pour mieux décrire la situation.
J’ai pour mission de calculer la charge à long terme de l'activité.
Contraintes:
-différents types de tests,
-les opérateurs n'ont pas tous les mêmes compétences,
-les tests peuvent se faire sur plusieurs jours
-les temps de main d'œuvre ne sont pas successifs, avec des temps d'arrêts/d'attentes
J’ai commencé à travailler sur Excel en essayant de faire la charge à la semaine:
-j'ai les temps de main d'œuvre pour les tests et la ressource disponible (les opérateurs présents)

*** j’essaie de savoir comment faire (une formule) pour savoir si on à la ressource suffisante pour réaliser les tests en tenant en compte les contraintes citées ci-dessus? Peut-être pas toutes les contraintes.
Regarde la pièce jointe planif2.xls
Sachant que pour la semaine 5, 33 produits sont à tester qui « fait 191 heures de temps main d’œuvre ». Sachant que l’on dispose 390h de ressource (nombre d’opérateur*nombre de jours présents*7:30).
Cela peut paraitre simple vue que nous avons plus de temps’ressource’ que de temps ‘MO testing’ mais Les tests se fond sur plusieurs jours, ce qui complique la situation, car ici les 191 heures sont concentrés (somme de tous les temps MO de testing).

Mervi d'avance

 

[jasmine]

Re : calcul de charge + planification

Bonsoir

Alors, pour t'aider, une "petite" explication de la formule dans K14.

Imaginons qu'il faille faire 4 (= K4) tests Bases2X en 22:00 (= K3), donc que chaque test prenne 5:30 (durée d'un test = K3/K4).
POURQUOI 22H? CE N'EST PAS 11 (=K3)?

 

[CISCO]

Re : calcul de charge + planification

Bonsoir

POURQUOI 22H? CE N'EST PAS 11 (=K3)?

C'est juste un exemple.

@ plus

 

[jasmine]

Re : calcul de charge + planification

Bonsoir,
dans ton post 41:
*(SOMME(K$13:K13)+K$3/K$4<=K$3) : --> et que la somme des données de la colonne+durée d'un test soit <= à K3 (la somme doit être <= à 22:00 et il faut encore pouvoir y ajouter au moins 5:30 tout en restant <= à 22:00) (rem : le * remplace un ET. Ex ET(1;1)=1*1=1, ET(1;0)= 1*0=0)

*(SOMME($J14:J14)+K$3/K$4<=$D$1/24) : --> et la somme des données de la ligne + durée d'un test soit <= à D1/24 pour ne pas dépasser les 35 h hebdomadaires

dans les cellules K13 et J14 sont vides dans le fichier que j'ai. tu voulais parlé de la cellules K14 à la place de K13? ou c'est peut être qu'on a pas la même version d'excel c'est ce qui explique le décalage de cellule.
encore merci de ta promptitutde.
A+

 

[CISCO]

Re : calcul de charge + planification

Bonsoir

En pièce jointe, un fichier avec une macro prenant en charge 52 semaines, avec une disposition un peu différente pour pouvoir mettre ces 52 semaines les unes en dessous des autres. La semaine 42 pose un peu problème. Comme certaines valeurs sont tirées au hasard, on peut passer à coté d'un ensemble de résultats convenant si on n'autorise qu'un petit nombre de tirages. La macro va maintenant jusqu'à 5000 tirages au max par semaine. Certaines fois, pour cette semaine 42, il a fallu plus de 300 tirages, et une fois même, lors d'un de mes essais, un peu plus de 1900.
D'ailleurs, ce n'est pas parce que la macro affiche 52 tableaux que cela convient. Il faut regarder s'il ni y a que des OK dans la colonne de droite. Si après 5000 tirages pour une semaine donnée, la macro ne trouve pas de résultats convenant, elle affiche le dernier tableau concernant cette semaine avec un NON, et passe à la semaine suivante.

Je t'ai mis des commentaires dans la macro pour que tu comprennes comment elle fonctionne (pour voir le code, faire Alt+F11).

@ plus

 

[CISCO]

Re : calcul de charge + planification

Bonsoir

Bonsoir,
dans les cellules K13 et J14 sont vides dans le fichier que j'ai. tu voulais parlé de la cellules K14 à la place de K13? ou c'est peut être qu'on a pas la même version d'excel c'est ce qui explique le décalage de cellule.
encore merci de ta promptitutde.
A+

Non, c'est bien SOMME(K$13:K13) dans K14 (avec un $ devant le premier 13, pour toujours commencer la somme en ligne 13). Il ne faut surtout pas qu'il y ait une valeur numérique dans K13. J'ai fait cela pour avoir une formule que l'on peut copier et coller vers la droite et vers le bas dans tout le tableau. En fait, ce SOMME(K$13:13) = 0 dans K14, et c'est ce qu'on veut. Si tu colles la formule en dessous dans K15, cette partie devient SOMME(K$13:14), donc donne K13+K14. Si tu colles encore cette formule en dessous, en K16, cela donne SOMME(K$13:K15), donc K13+K14+K15. Ainsi, dans cette colonne, où que l'on soit, on obtient le total des heures déjà consacrées pour cette famille de test, donc on peut voir si ce total est inférieur au total d'heures nécessaires pour celle-ci.

Il faut faire le même raisonnement pour SOMME($J14:J14) (avec un $ devant le premier J, pour toujours commencer la somme en colonne J), mais en ligne. Dans L14, cette partie devient SOMME($J14:K14), donc donne J14+K14. Dans M14, cela donne SOMME($J14:L14), donc J14+K14+L14. Ainsi on peut voir si on ne dépasse pas le nombre d'heures hebdomadaires max, 35 h.

@ plus

P.S : Autrement dit, ce SOMME(K$13:K13) n'est pas indispensable dans K14, par contre il est bien pratique pour remplir simplement le reste du tableau.

 

[CISCO]

Re : calcul de charge + planification

Bonjour

En pièce jointe, une version semblable à la dernière, mais prenant en compte un nombre quelconque de semaines (tant qu'on n'écrit rien en dessous de I200, soit environ 90 semaines au max).

Rem : Comme déjà écrit, comme le résultat de certaines cellules est obtenu en tirant un nombre au hasard, certaines fois, la macro ne trouve pas de répartition des horaires convenant. Ainsi, dans l'exemple en pièce jointe, la semaine 12 pose parfois problème. Si cela t'arrive, il faut relancer la macro en espérant que le hasard fasse bien les choses. Si cela t'arrive plusieurs fois de suite pour une même semaine, c'est certainement qu'il y a un problème et que tu as dépassé les capacités de ton équipe. C'est le défaut de la méthode :
* Si elle trouve une solution, c'est que c'est OK.
* Si elle n'en trouve pas,
- c'est peut être qu'il y a moins de répartitions possibles conciliant les capacités de ton équipe/tests à réaliser, et que les tirages sont passés à coté,
- ou qu'on ne peut pas faire le nombre de tests désirés avec cette équipe

La réponse n'est donc pas catégorique dans ce dernier cas. Si j'ai une idée pour lever ce doute, je te la proposerai.

 

[jasmine]

Re : calcul de charge + planification

Bonjour cisco,
dans ton dernier fichier, j'ai essayé de comprendre les formules du tableau I4-N14, que tu m'avais au paravant expliqué (dans la premiére version).
dis moi si je me trompe:

"=SI(I$18=0;"";SI((B4="X")*(SOMME(I$3:I3)<I$17)*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<>I$17);MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))



=SI(I$18=0;"" S’il ni a pas de test à faire, on ne fait rien

;SI((B4="X") il faut que l’employé ai le droit de faire ce test

*(SOMME(I$3:I3)<I$17) et que la somme des données de la colonne + durée d’un test soit < à I17 ( la somme doit etre inferieur à 21h et il faut encore pouvoir y ajouter au moins 5 :30 tout en restant < 21H)
*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18) et la somme des données de la ligne + durée d’un test soit <= à O1 (= 35h)
*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<>I$17);MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1- ??

SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN( si les trois tests précédents sont vrais, on multiplie la durée de test par un nombre entrié puis au hasard entre 0 et la plus petite es deux valeurs suivantes


ENT((I$17-SOMME(I$3:I3))/(I$17/I$18)) la durée du test en cours doit être supérieur à la durée moyenne des tests(tests à faire / tests en cours)


;ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));"")) Si les trois tests précédents ne sont pas tous vrai, ou l’opérateur n’a pas les compétences de faire ce test, ou on ne peut pas rajouter la durée d’un test dans la colonne sans dépasser le total nécessaire en O1 (35H)
"

 

[CISCO]

Re : calcul de charge + planification

Bonsoir

Bonjour cisco,

=SI(I$18=0;"" S’il ni a pas de test à faire, on ne fait rien

;SI((B4="X") il faut que l’employé ai le droit de faire ce test

*(SOMME(I$3:I3)<I$17) et que la somme des données de la colonne + durée d’un test soit < à I17 ( la somme doit etre inferieur à 21h et il faut encore pouvoir y ajouter au moins 5 :30 tout en restant < 21H)
*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18) et la somme des données de la ligne + durée d’un test soit <= à O1 (= 35h)

Jusque là, c'est OK

*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<>I$17)

Si les personnes dans le bas de la liste ne sont pas habilitées (NBVAL(B5:B$15) représente le nombre de X dans le bas de la colonne B) pour réaliser le test Base2X et si on n'a pas encore consacré assez d'heures à ce test (il faut y consacrer I$17 heures)

MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))

REPONSE SI VRAI : Si les deux conditions précédentes sont vérifiées (on n'as encore fait assez de test Base2X et on ne peut pas le faire avec les employés du bas de la liste), on ne tire pas au hasard le contenu de la cellule (car c'est la dernière cellule où on peut encore mettre des tests à réaliser, dans cette colonne), mais on va essayer d'y mettre le maximum d'heures possibles pour réaliser le nombre de test Base2X demandés (ou s'en approcher). On met donc dans cette cellule :
* soit ENT((I$17-SOMME(I$3:I3))/(I$17/I$18)) qui représente le nombre de tests manquant pour répondre à la demande
I$17 représente le nombre d'heures totales à consacrer à ce type de test
SOMME(I$3:I3) représente le nombre d'heures déjà consacrées à ce test
I$17/I$18 la durée d'un de ces test Base2X
* soit ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)), le nombre de tests max que puisse réaliser l'employé sans dépasser ses 35 h hebdomadaires, y compris les heures déjà effectuées, SOMME($H4:H4).

On prend le MIN de ces deux dernières valeurs car rien ne sert de consacrer plus de I$17 h à ce type de test (on n'y gagnerai rien), et on ne peut pas non plus faire travailler l'employé plus de 35 h hebdomadaires.

ALEA.ENTRE.BORNES(0;MIN( ....

REPONSE SI FAUX : Si l'un des deux tests précédents n'est pas réalisé (il y a au moins une autre personne compétente pour réaliser ce type de test dans le bas de la liste ou on a déjà fait assez de test de ce type[SUP]*[/SUP]), on multiplie la durée de test par un nombre entier pris au hasard entre 0 et la plus petite des deux valeurs déjà calculées ci-dessus.

Les calculs sont donc semblables dans le cas REPONSE SI VRAI et REPONSE SI FAUX, sauf que dans le premier cas on prend le MIN des deux valeurs obtenues, et dans le second cas, on prend un nombre entier au hasard entre 0 et ce même MIN. Ce qu'on peut mettre en évidence en donnant des noms à certaines parties de cette formule, ce qui donne par ex dans I4

SI(I$18=0;"";SI((B4="X")*(SOMME(I$3:I3)<I$17)*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<>I$17);MIN(nbredetestsrestantsàfairetype;nbretestparrapportà35h);ALEA.ENTRE.BORNES(0;MIN(nbredetestsrestantsàfairetype;nbretestparrapportà35h)));""))

Petite remarque au passage. On peut modifier un peu la partie centrale de la formule comme suit (A vérifier bien sûr)

SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17);MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));

donc en remplaçant :
* SOMME(I$3:I3)<> I$17 par SOMME(I$3:I3) < I$17 car SOMME(I$3:I3) ne peut pas être > à I$17.
et ENT((I$17-SOMME(I$3:I3))/(I$17/I$18)) par (I$17-SOMME(I$3:I3))/(I$17/I$18) car ( I$17 - SOMME(I$3:I3)) est forcément un multiple de (I$17/I$18)

@ plus

* Dans ce dernier cas, on n'a même plus besoin de faire de tirage au sort, mais comme celui-ci est fait entre 0 et 0, la formule renvoie 0, et c'est ce qu'on voulait.

 

[CISCO]

Re : calcul de charge + planification

Bonjour

Pendant qu'on y est, puisqu'il y a dans la formule dans I4 le test SOMME(I$3:I3)<> I$17 et le test presqu'identique SOMME(I$3:I3) < I$17

SI(I$18=0;"";SI((B4="X")*(SOMME(I$3:I3)<I$17)*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<>I$17);MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

on peut simplifier l'écriture de cette formule en modifiant le début sous la forme SI((I$18=0)+(SOMME(I$3:I3)= I$17);""; (ce qui signifie "si il ni a pas de test à effectuer ou si le nombre d'heures à effectuer est déjà attribué à ce type de test, ne rien mettre"), ce qui donne

SI((I$18=0)+(SOMME(I$3:I3)=I$17);"";SI((B4="X")*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI(NBVAL(B5:B$15)=0;MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

Malheureusement, il y a des problèmes d'arrondi au niveau du SOMME(I$3:I3)= I$17 et Excel ne reconnait pas systématiquement l'égalité alors qu'elle y est. On peut contourner ce problème en utilisant deux ARRONDI, ce qui donne
SI((I$18=0)+(ARRONDI(SOMME(I$3:I3);6)=ARRONDI(I$17;6));"";SI((B4="X")*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI(NBVAL(B5:B$15)=0;MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

On peut aussi faire avec
SI((I$18=0)+(ARRONDI(SOMME(I$3:I3);6)=ARRONDI(I$17;6))+(B4<>"X");"";SI(SOMME($H4:H4)+I$17/I$18<=$O$1;(I$17/I$18)*SI(NBVAL(B5:B$15)=0;MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

On peut espérer y gagner un peu en rapidité, certains calculs étant faits avec l'ancienne formule pour rien dans le bas des colonnes (Tirer un nombre au hasard entre 0 et 0 !). Maintenant, il ni a plus de calculs dès que le total,par exemple I$17 dans la colonne I, est atteint.

@ plus

 

[jasmine]

Re : calcul de charge + planification

donc en remplaçant :
* SOMME(I$3:I3)<> I$17 par SOMME(I$3:I3) < I$17 car SOMME(I$3:I3) ne peut pas être > à I$17.
et ENT((I$17-SOMME(I$3:I3))/(I$17/I$18)) par (I$17-SOMME(I$3:I3))/(I$17/I$18) car ( I$17 - SOMME(I$3:I3)) est forcément un multiple de (I$17/I$18)

EN remplaçent cette partie , j'obtiens:
=SI(I$18=0;"";SI((B4="X")*(SOMME(I$3:I3)<I$17)*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17);MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

cette formule appliquée (fichier joint)

Est obligatoire la formule ARRONDI?? qu'est ce que ça ferait si on ne la met pas? sachant qu'on ne cherche pas à avoir un résultat "precis"
la modification du début de la formule me va "SI((I$18=0)+(SOMME(I$3:I3)=I$17)"

 

[jasmine]

Re : calcul de charge + planification

SI((I$18=0)+(SOMME(I$3:I3)=I$17);"";SI((B4="X") *(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17);MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

cette derniére formule prend en compte les modifications que tu as apporté sauf le ARRONDI

 

[CISCO]

Re : calcul de charge + planification

Bonjour

Moi aussi, je préférerai faire avec un simple SOMME(I$3:I3)=I$17 mais j'ai constaté que cela entrainait parfois des erreurs dans certaines cellules parce que SOMME(....) donnait presque la même valeur que le total désiré, mais pas exactement la même valeur. J'essaye de trouver un exemple.

@ plus

P.S : Dans ton dernier post, le SOMME(I$3:I3)<I$17 au milieu n'est pas la meilleure solution (Dans le fichier 7, ce n'est pas non plus la meilleure solution, il me semble). On se retrouve avec les 4 cas possibles suivants :
(NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17) = VRAI * VRAI = 1 --> calcul avec MIN. OK.
(NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17) = VRAI * FAUX = 0 --> calcul avec aléa entre 0 et MIN, alors qu'on ne devrait pas faire de calcul (on fait un tirage au hasard entre 0 et 0). Comme dans le fichier 7, on fait d'autres tirages avec la macro ou avec F9, cela n'est pas un problème, mais cela rallonge le temps de calcul.
(NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17) = FAUX * VRAI = 0 --> calcul avec aléa entre 0 et MIN. OK. On n'est pas forcé de prendre MIN puisque d'autres employés dans le bas de la liste sont habilités pour faire ce test.
(NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17) = FAUX * FAUX = 0 --> calcul avec aléa entre 0 et MIN. OK

On constate qu'on obtient les mêmes résultats avec uniquement le premier test
(NBVAL(B5:B$15)=0) = VRAI = 1 --> calcul avec MIN. Utile lorsque SOMME(I$3:I3)<I$17 ou inutile lorsque SOMME(I$3:I3)=I$17 (mais pas faux car MIN=0).
(NBVAL(B5:B$15)=0) = FAUX --> calcul avec aléa entre 0 et MIN. OK

En mettant + SOMME(I$3:I3) = I$17 au début, dans le SI initial, on élimine les calculs inutiles dès le début.

 

[CISCO]

Re : calcul de charge + planification

Re

Exemple d'erreur en pièce jointe, obtenu après une dizaine de F9, sans les ARRONDI dans les formules.

@ plus

 

[jasmine]

Re : calcul de charge + planification

re,

=SI(I$18=0;"";SI((B4="X")*(SOMME(I$3:I3)<I$17)*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI((NBVAL(B5:B$15)=0)*(SOMME(I$3:I3)<I$17);MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

cette formule sans les arrondis j'ai l'impression d'avoir les mêmes resultats dans les tirages que:


=SI((I$18=0)+(ARRONDI(SOMME(I$3:I3);6)=ARRONDI(I$17;6));"";SI((B4="X")*(SOMME($H4:H4)+I$17/I$18<=$O$1);(I$17/I$18)*SI(NBVAL(B5:B$15)=0;MIN((I$17-SOMME(I$3:I3))/(I$17/I$18);ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)));ALEA.ENTRE.BORNES(0;MIN(ENT((I$17-SOMME(I$3:I3))/(I$17/I$18));ENT(($O$1-SOMME($H4:H4))/(I$17/I$18)))));""))

 

[CISCO]

Re : calcul de charge + planification

Bonsoir

Bien sûr que tu as les mêmes résultats, aux aléas du tirage au sort près...

La formule du fichier 7, post #51, ou celles que je t'ai proposées ensuite doivent te donner, comme je comprend les choses, les mêmes résultats (aux aléas du tirage au sort près) sauf que les dernières doivent tourner un peu plus vite puisque certains calculs ne sont pas faits inutilement dans le bas de chaque colonne, lorsque le total d'heures à consacrer au test de la colonne en cours est atteint. Dans la colonne I, dès que SOMME(I$3:I...) = I$17, Excel met "" dans la cellule et passe à la cellule suivante, et n'en fait pas plus dans les cellules en dessous dans cette colonne.

@ plus