bouton d'analyse entre feuilles

[adrien51]

Voici le probleme

J'ai 2 feuilles excel,

Dans la premier feuille, j'ai un numero de poste et des numero de compte.
Dans la deuxieme feuille je retrouve mes numero de poste et à la place des numero de compte, j'ai des case ok ou des cases vides.

comment créer un bouton en feuille 1 pour :

- qu'une analyse se fasse en feuille 1 pour que les numero de poste où des chiffres sont present dans la colonne à coté compare en feuille 2 si le meme numero de poste est ok ( si ok alors numero de poste sur les 2 feuilles de couleur jaune )

- qu'une analyse se fasse en feuille 1 pour que les numero de poste où des chiffres sont present dans la colonne à coté compare en feuille 2 si le meme numero de poste est vide ( si vide alors aucune couleur )

- qu'une analyse se fasse en feuille 1 pour que les numero de poste où des chiffres sont present dans la colonne à coté compare en feuille 2 si le meme numero de poste est vide ( si vide alors numero de poste sur les 2 feuilles de couleur rouge )

Merci

 

[Guest]

Re : bouton d'analyse entre feuilles

Bonjour Adrien,

Voci une solution pour les deux premières conditions pour la troisième, rien compris, elle ressemble à la deuxième!?

A bientôt

[Edition] un petit bonjour aurait été apprécié.

 

[adrien51]

Re : bouton d'analyse entre feuilles

pour la troisieme condition,

si en feuille 1 on trouve un numero en face du numero de poste et si en feuille 2 pour ce meme numero on ne trouve pas de ok alors couleur en rouge sur les 2 feuilles pour le numero de poste.

Merci de le reintégrer au fichier excel

Merci, beaucoup

 

[Guest]

Re : bouton d'analyse entre feuilles

Adrien,

Voici la macro, modifiée.

Sub compareCompteOk()
    Dim plage1 As Range, Plage2 As Range, c1 As Range, c2 As Range
    With Sheets("Feuil1")
        Set plage1 = .Range("A" & .Rows.Count).End(xlUp)
        If plage1.Row > 1 Then Set plage1 = .Range("A2", plage1) Else Set plage1 = Nothing
    End With
    With Sheets("Feuil2")
        Set Plage2 = .Range("A" & .Rows.Count).End(xlUp)
        If Plage2.Row > 1 Then Set Plage2 = .Range("A2", Plage2) Else Set Plage2 = Nothing
    End With
    If plage1 Is Nothing Or Plage2 Is Nothing Then Exit Sub
    For Each c1 In plage1.Cells
        Set c2 = Plage2.Find(What:=c1, LookIn:=xlValues, LookAt:=xlWhole)
        'Si le numéro est trouvé dans feuille2
        If Not c2 Is Nothing Then
            'Si le compte est  vide en feuil1
            If IsEmpty(c1(1, 2)) Then
                'Si le compte est vide en feuil1
                c1.Interior.ColorIndex = xlColorIndexAutomatic
                c2.Interior.ColorIndex = xlColorIndexAutomatic
            Else
                'Si le compte en feuil2 est ok
                If UCase(c2.Offset(, 1)) = "OK" Then  'Si Ok
                    'couleur jaune
                    c2.Interior.ColorIndex = 6
                    c1.Interior.ColorIndex = 6
                Else 'sinon
                    'Couleur Rouge
                    c2.Interior.ColorIndex = 3
                    c1.Interior.ColorIndex = 3
                End If
            End If
        Else
            'Si le numéro n'est pas dans feuil2
            c1.Interior.ColorIndex = xlColorIndexAutomatic
        End If
    Next c1
End Sub

A+