Attribuer des lettres à des intervalles de chiffres.

[josanche]

Bonjour le forum,

J'aurais besoin votre aide pour résoudre un excercice qui vous semblera certainement facile mais j'ai oublié la formule à utiliser.

Je voudrais attribuer à chaque chiffre de la colonne B une classe qui peut prendre trois lettres possibles A, B, C et j'ai fait un petit tableau ou il est écrit à quoi correspond chaque lettre. En gros, chaque lettre correspond à un intervalle de chiffre bien distincts. J'aimerais une fonction qui puisse me dire pour chaque chiffre de la colonne B à quel classe, il appartient.

Veuillez retrouver mon fichier excel en pièce jointe.

Bon dimanche au forum
!!!

 

[excfl]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonsoir,

=SI(A2>=120;"C";SI(A2>=60;"B";"A"))

excfl

 

[Guest]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonsoir,

fonction à tirer vers le bas: =INDEX({"A";"B";"C"};EQUIV(A2;{0;60;120};1))

ou : =INDEX($E$2:$E$4;EQUIV(A2;{0;60;120};1))

mais en triant E2:E4 par ordre alphabétique.

A+

 

[Victor21]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonsoir, Josanche.

En B2, à recopier vers le bas :

=CHOISIR(EQUIV(A2;{0;60;120};1);"A";"B";"C")

Edit : Bonsoir excfl, Hasco, ROGER2327

 

[ROGER2327]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonjour josanche.

Essayez :​

=CHOISIR((A2>=120)+(A2>=60)+1;"A";"B";"C")

en B2, à recopier vers le bas.​

Bonne soirée.


ROGER2327
#6596

Lundi 9 Palotin 140 (Saints Boleslas et Ladislas, polonais - fête Suprême Quarte)
9 Floréal An CCXXI, 7,6386h - hyacinthe
2013-W17-7T18:19:58Z

 

[ROGER2327]

Re : Attribuer des lettres à des intervalles de chiffres.

Suite...

Une autre :​

=STXT("ABC";(A2>=120)+(A2>=60)+1;1)

ROGER2327
#6597

Lundi 9 Palotin 140 (Saints Boleslas et Ladislas, polonais - fête Suprême Quarte)
9 Floréal An CCXXI, 7,6834h - hyacinthe
2013-W17-7T18:26:24Z

 

[excfl]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonsoir le forum,

"Entre 0 compris et 60 non compris : A "

Un cas particulier : la cellule en A ne contient rien :

=SI(A2="";"";SI(A2>=120;"C";SI(A2>=60;"B";"A")))

2ème cas particulier : la cellule en A contient du texte :

=SI(ESTTEXTE(A2);"";SI(A2="";"";SI(A2>=120;"C";SI(A2>=60;"B";SI(A2<60;"A";"")))))

excfl

 

[mapomme]

Re : Attribuer des lettres à des intervalles de chiffres.

Bonjour à tous,

Pour le fun, une p'tite dernière:

=CAR(65+MIN(ENT(A2/60);2))

Edit : Houps! Remplacé ;3 par ;2 (merci R@chid que je salue)

 

[mapomme]

Re : Attribuer des lettres à des intervalles de chiffres.

(re)Bonjour à tous,

Et sur une astucieuse suggestion de R@chid, on peut laisser travailler Excel à la place d'utiliser ENT():

=CAR(65+MIN(A2/60;2))

Bonne-nuit,