Algorithme Générer un code ?

[nonifel]

Bonjour,

Je cherche un algorithme qui va générer un code à partir des données indiquées.

Fichier ci-joint.

Merci à vous.

 

[Lolote83]

Re : Algorithme Générer un code ?

Salut Nonifel,
Voir ici si cela te convient.
Fonction personnalisée
@+ Lolote83

 

[nonifel]

Re : Algorithme Générer un code ?

Graaaaaaand Merciiiiiiiiiii Lolote83

 

[VIARD]

Re : Algorithme Générer un code ?

Bonjour Nonifel, Lolote83

J'ai trouvé la fonction impeccable.
Je l'ai modifié pour intégrer les tableaux.

voici le code

Function AvCodage(xPlage As Range)
Dim Lettre(), ChiffreLet()
Dim Chiffre(), LettreCh()
Dim xLettre As Variant
Dim xResult As Variant, xCodFin As Variant, i%, j%

Lettre = Array("A", "B", "C", "D", "E", "F", "G", "H", "I", "J", _
                "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", _
                "U", "V", "W", "X", "Y", "Z")
ChiffreLet = Array(25, 24, 24, 22, 21, 20, 19, 18, 17, 16, 15, _
                14, 13, 12, 11, 10, 9, 8, 7, 6, 5, 4, 3, 2, 1, 0)
Chiffre = Array(0, 1, 2, 3, 4, 5, 6, 7, 8, 9)
LettreCh = Array("A", "B", "C", "D", "E", "F", "G", "H", "I", "J")
'----------- Traitement ----------
    For F = 1 To xPlage.Count
        xCodDep = xPlage(F)  'Range("B" & F)
        For G = 1 To Len(xCodDep)
            xLettre = Mid(xCodDep, G, 1)
            If IsNumeric(xLettre) Then
'---- Traitement du numérique ----
                For i = 0 To 9
                    If Val(xLettre) = Chiffre(i) Then
                        xResult = LettreCh(i)
                    End If
                Next i
            Else
'--- Traitement de Alphabétique --
                For j = 0 To 25
                    If xLettre = Lettre(j) Then
                        xResult = ChiffreLet(j)
                    End If
                Next j
            End If
            xCodFin = xCodFin & xResult
        Next G
    Next F
    AvCodage = xCodFin
End Function

A+ Jean-Paul

 

[mapomme]

Re : Algorithme Générer un code ?

Bonsoir nonifel, à tous,

Pour le fun, en traduisant le tableau directement avec des fonctions vba:

Function Coder$(ParamArray plage())
Dim elem, xcell, i&
  For Each elem In plage
    For Each xcell In elem
      For i = 1 To Len(xcell)
        Select Case Mid$(xcell, i, 1)
          Case "A" To "Z"
            Coder = Coder & (90 - Asc(Mid$(xcell, i, 1)))
          Case "0" To "9"
            Coder = Coder & Chr(Asc("A") + Mid$(xcell, i, 1))
          Case Else
            Coder = Coder & "-"
        End Select
      Next i
    Next xcell
  Next elem
End Function

 

[VIARD]

Re : Algorithme Générer un code ?

Bonjour mapomme et à tous

J'apprécie la compacité de ton code, je me doutais que l'on pouvait faire plus court.
Compliments

A+

Jean-Paul