Ajouter données dans listbox

[JORDAN]

Bonjour tout le monde,

je n'arrive pas à trouver de solution pour ajouter des données dans une listbox
je choisis dans une Listbox une donnée
ensuite je recherche cette valeur dans une feuille de calculs
Cette valeur est obligatoirement sur la ligne 1
et j'aimerai pouvoir mettre les valeurs des cellules pleines de cette colonne sans la 1ere ligne dans une autre listbox
Exemple :
si F1 est la cellule trouver
comment rapatrier les données à partir de F2 jusqu'à F? (la dernière cellule pleine)
dans une autre listbox

Voici mon début de code

Sub ChercheCat()
Dim NomCherche As String
   NomCherche = ListBox2.Value
   Sheets("DONNEES").Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues).Select
End Sub

Merci pour vos infos

 

[BERRACHED said]

Re : Ajouter données dans listbox

Salut,JORDAN

tu peux joindre un fichier d'après ce que j'ai compris tu veux alimenter une listbox par une valeur recherché qui ce trouve sur un autre listbox.

Cordialement

 

[JORDAN]

Re : Ajouter données dans listbox

Bonsoir Said
Voici mon fichier
Merci pour ton aide

 

[skoobi]

Re : Ajouter données dans listbox

Bonjour Jordan,
Saïd 🙂,

A tester:

Sub ChercheCat()
  Dim NomCherche As String, Trouve As Range, DerLig As Long, Elmnt As Range
  With Sheets("DONNEES")
    NomCherche = ListBox2.Value
    Set Trouve = .Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues)
    DerLig = .Cells(65536, Trouve.Column).End(xlUp).Row
    For Each Elmnt In .Range(.Cells(2, Trouve.Column), .Cells(DerLig, Trouve.Column))
      UserForm1.ListBox2.AddItem Elmnt.Value
    Next
  End With
End Sub

Je te conseille fortement de préciser la valeur de l'argument LookAt pour Find qui peuvent être XlPart ou XlWhole (recherche partielle ou entière dans la cellule)

Edit: ce code ne tiens pas compte du fichier que tu viens d'envoyer (j'ai pas mis 3mn à le faire mais un peu plus 😀)

 

[JORDAN]

Re : Ajouter données dans listbox

Bonsoir Skoobi, le Forum,

Merci pour ton aide
ça marche tres bien, j'ai juste changé
UserForm1.ListBox2.AddItem Elmnt.Value par
UserForm1.ListBox3.AddItem Elmnt.Value
et rajouté en début de code
listbox3.clear
sinon j avais des données en top

Merci beaucoup pour ton aide
bonne soirée

 

[JORDAN]

Re : Ajouter données dans listbox

Re,
Je reviens pour une question de facicilité
Est-il possible de trier les données directement avant de les intégrer
dans la listbox, ou alors il faut passer par une étape intermédiaire
telle que mettre les valeurs dans des cellulles, les triés puis les
mettre dans la listbox ??
Merci

 

[skoobi]

Re : Ajouter données dans listbox

Oui c'est possible mais là le temps me manque, je passe la main.

 

[JORDAN]

Re : Ajouter données dans listbox

re,
Ok merci pour l'info je vais essayer de trouver quelques chose là-dessus
Bonne soirée

 

[skoobi]

Re : Ajouter données dans listbox

Re,

je vois que dans le code tu utilises déjà une procédure de tri de tableau VBA, autant s'en servir 😉.

Sub ChercheCat() 'Recherche puis affichage sous-catégorie dans LBX3
Dim NomCherche As String, Trouve As Range, DerLig As Long, X As Long, Tablo()
  LBX3.Clear
'Recherche de la catégorie d'après la LBX2
  NomCherche = LBX2.Value
  With Sheets("DONNEES")
    Set Trouve = .Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues)
    NomCherche = LBX2.Value
    Set Trouve = .Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues)
    DerLig = .Cells(65536, Trouve.Column).End(xlUp).Row
    ReDim Tablo(DerLig - 2)
    'on transfert chaque élément de la colonne vers un tableau VBA
    For X = 2 To DerLig
      Tablo(X - 2) = .Cells(X, Trouve.Column).Value
    Next
  End With
  Call Tri(Tablo, LBound(Tablo), UBound(Tablo))
  LBX3.List = Tablo
End Sub

Bon test.

 

[JORDAN]

Re : Ajouter données dans listbox

Bonjour Skoobi, le Forum,

Je viens de tester ton code et j'ai une erreur
Excel bloque sur cette ligne : ReDim Tablo(DerLig - 2)
Merci pour ton aide et bonne journée

 

[skoobi]

Re : Ajouter données dans listbox

Bonjour,

Le code fonctionne chez-moi. Envoie le fichier que l'on voit ce qui se passe.

 

[JORDAN]

Re : Ajouter données dans listbox

Re,
Voici mon fichier
Merci

 

[skoobi]

Re : Ajouter données dans listbox

Il faut mettre une condition car à l'ouverture de l'USF, la combobox2 est vide:

Sub ChercheCat() 'Recherche puis affichage sous-catégorie dans LBX3
Dim NomCherche As String, Trouve As Range, DerLig As Long, X As Long, Tablo()
  LBX3.Clear
'Recherche de la catégorie d'après la LBX2
  NomCherche = LBX2.Value
  If NomCherche <> "" Then
    With Sheets("DONNEES")
      Set Trouve = .Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues)
      NomCherche = LBX2.Value
      Set Trouve = .Range("C1:M1").Find(What:=NomCherche, LookIn:=xlValues)
      DerLig = .Cells(65536, Trouve.Column).End(xlUp).Row
      ReDim Tablo(DerLig - 2)
      'on transfert chaque élément de la colonne vers un tableau VBA
      For X = 2 To DerLig
        Tablo(X - 2) = .Cells(X, Trouve.Column).Value
      Next
    End With
    Call Tri(Tablo, LBound(Tablo), UBound(Tablo))
    LBX3.List = Tablo
  End If
End Sub

 

[JORDAN]

Re : Ajouter données dans listbox

Re,
Je viens de tester avec ta modif
ça fonctionne très très bien
Merci pour ton aide et bonne journée