Google Sheets ajout d'une condition sur une formule

[SaeRoS]

Bonjour,

J'ai cette formule :

=ArrayFormula(SIERREUR(INDEX(DECALER('liste client'!$A$3;;;LIGNES(DECALER('liste client'!$S$3;;;(NB.SI('liste client'!$S:$S;"><")+(NB.SI('liste client'!$S:$S;"")))-1)));PETITE.VALEUR(SI((DECALER('liste client'!$S$3;;;(NB.SI('liste client'!$S:$S;"><")+(NB.SI('liste client'!$S:$S;"")))-1)=$A$3);LIGNE(DECALER('liste client'!$S$3;;;(NB.SI('liste client'!$S:$S;"><")+(NB.SI('liste client'!$S:$S;"")))-1))-2);LIGNE(B1));COLONNE(A:A));""))

Qui fonctionne très bien. Mais je n'arrive pas a ajouter une condition.

Alors déjà je récapitule la formule effectue une récupération des données sous la conditions que l'année en cellule A3 est dans les données.

Je souhaite ajouter une condition : 'liste client'!$R:$R="ok"
Mais quelque soit l'endroit ou j'ai essayer de l'ajouter cela n'a pas fonctionner

Merci pour votre retour

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @SaeRoS
Peux-tu envoyer un fichier anonymisé pour faciliter la compréhension ? Parce que là c'est un peu abstrait...
Amicalement
Alain

 

[SaeRoS]

Bonjour @AtTheOne,
désoler pour le temps de réponse, compliquer d'anonymiser et de faire une copie extérieure pour partager (bloquer a la société de base) voici le document.

Tous ce passe dans l'onglet renouvellement en attente, En plus de ma première demande j’essaie aussi de voir pour ajuster le Tarif a la date en A3 si une idée vous viens je suis preneur.

Merci pour les prochaines réponses.

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @SaeRoS

Bon, je ne suis pas familier de GoogleSheets et je n'ai que la version gratuite ...
Du coup j'ai importé dans Excel, cherché une solution et recopié les formules une à une dans la première cellule de chaque colonne, puis copier, collage spécial, seult les formules pour le reste des colonnes ! Ouf !

Un détail j'ai paramétré le tarif en fonction de l'année à renouveler. Ça m'a conduit à transformer les années de "tarifs" en nbre sous forme de texte pour être homogène avec les feuilles "liste client" et "renouvellement en attente".

Le résultat sur la feuille 'Renouvellement en attente ' :
en B1 le nombre de clients

=NB(Indirect("'liste client'!A3:A"&LIGNES('liste client'!A:A)))

en colonne A ( à gauche de ton tableau) la formule suivante :

=ARRAYFORMULA(SIERREUR(LIGNE(INDEX(INDIRECT("'liste client'!S"&SI(ESTVIDE(B3);3;A3+1)&":S"&$B$1+2);EQUIV("ok"&$A$3;INDIRECT("'liste client'!R"&SI(ESTVIDE(B3);3;A3+1)&":R"&$B$1+2)&INDIRECT("'liste client'!S"&SI(ESTVIDE(B3);3;A3+1)&":S"&$B$1+2);0)));"-"))

qui renvoie le N° de ligne dans la la feuille 'liste client' des clients qui correspondent au 2 critères ("ok" et année)​

En colonne B (1ère colonne de ton tableau la formule suivante :

=SI($A4="-";"";INDEX('liste client'!A:A;$A4))

qui renvoie le "Code 2p5"​

Les formules autres colonnes, excepté les tarifs ,sont du même type en faisant varier la colonne de la 'liste client'
Les formules des tarifs recherchent la colonne en fonction de l'année à renouveler, et pour le forfait la colonne en fonction de la case cochée :

Forfait
=SI($A4="-";"";SIERREUR(INDEX(Tarifs!$C$7:$F$15;EQUIV("x";$G4:$L4;0);EQUIV($A$3;Tarifs!$C$6:$F$6;0)+1);0))
Réservations
=SI($A4="-";"";SI($M4<>"";INDEX(Tarifs!$C$13:$F$13;EQUIV($A$3;Tarifs!$C$6:$F$6;0)+1);0))
QR Codes
=SI($A4="-";"";SI($M4<>"";INDEX(Tarifs!$C$15:$F$15;EQUIV($A$3;Tarifs!$C$6:$F$6;0)+1);0))

Le résultat est ici, la version Excel est en pièce jointe.

Amicalement
Alain

 

[SaeRoS]

Bonjour Alain,
Merci pour le retour je vais prendre du temps la semaine prochaine pour regarder tous ça et vous ferrez un retour