Aide sur jeux d'icone avec ou sans VBA

Tophe2 · 27 Septembre 2013

Bonjour Le forum,

J'essai de mettre en place dans un fichier qui contient beaucoup de colonne une mise en forme avec les jeux d'icones. Je ne souhaiterai pas ajouter une colonne pour y placer mon icone (si possible) je souhaiterai que l'icone s'affiche dans une cellule contenant déjà des informations, est ce possible je ne sais pas ??

La condition serait, si le texte de la colonne A (ex: A3) est en gras mettre l'icone Validé (qui est en vert dans la MFC) dans la colonne B correspondante (ex : B3), j'ai cherché un peu partout je ne sais pas si cela est réalisable.

Si quelqu'un à une idée ou une piste. L'objectif est de ne pas ajouter de colonne, si possible, est d'avoir visuellement donc rapidement le dossier qui est validé grâce à l'icone.

Je joins un fichier excel avec deux colonnes essentiellement (A et B).

Merci pour votre aide
Cordialement
Christophe.

Tophe2 · 1 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Bonjour Le forum,
Bonjour Job75 et Si...

En utilisant les différentes propositions pour insérer l'icone validation j'ai opté dans certains fichier pour al proposition de job75 présente dans le fichier joint.

Cependant dans un fichier que j'utilise régulièrement je souhaiterai voir apparaitre l'icone validation dans la listbox que j'utilise pour placer les personnes (feuille 2 du fichier joint).

la listbox fait référence à la liste présente dans la feuille 1.

Ma question est il possible de faire apparaitre dans la listbox l'icone validation à côté du nombre d'enfant colonne AE. Peut être faudrait il qu'il apparaisse en plus de la colonne C dans la colonne AE de la feuille 1 puis sur la zone qui est lien sur la feuille 2 (P:S) avant de l'avoir visuellement sur la listbox, je ne sais pas trop mais j'essai mais je n'y arrive pas.

La listbox apparait uniquement sur la cellule bleu dans le fichier joint.

Peut être que l'on peut obtenir ce même résultat en passant par une autre solution, pas de problème.

Merci pour votre aide
Bonne Journée
Christophe.

Tophe2 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Bonjour le Forum,

Je reviens vers vous pour savoir s'il existe un moyen de faire apparaitre la coche de validation dans une listbox ou autre élément tout en gardant le principe présent dans la feuille 2 du fichier joint dans le message précédent.

Merci pour votre aide
Bonne Journée
Christophe.

job75 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Bonjour Tophe2,

Tophe2 à dit:
Ma question est il possible de faire apparaitre dans la listbox l'icone validation à côté du nombre d'enfant colonne AE.

Réponse : NON, ni une icône, ni un "ü" formaté par la police Wingdings.

Il aurait été sympa de rendre la ListBox visible non ??

A+

Tophe2 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Bonjour Job75,

Merci pour ta réponse je vais chercher un autre moyen pour que visuellement on puisse voir les ligne validés (couleur ou autre ....) je vais chercher.

Concernant la listbox je suis sincèrement désolé j'ai dû faire une mauvaise manip (copier/coller) mais cela me semblait évidemment de mettre la listbox fonctionnelle.

Dans le fichier joint la listbox fonctionne correctement, on ne sait jamais si une manip pour que visuellement cela fonctionne.

Encore désolé pour cette erreur ou oubli.

Bonne Journée
Christophe.

job75 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Plutôt que vous casser la tête avec des coches, repérez par des caractères "classiques".

En Feuil2, il suffit de mettre le format @" *" en colonne S au bon endroit :

Code:

Sub AstérisquesListBox()
'Feuil1 et Feuil2 sont les CodeNames des feuilles
Dim i&
With Feuil2
  For i = 5 To .Range("S" & Rows.Count).End(xlUp).Row
    .Cells(i, "S").NumberFormat = _
      "@" & IIf(Feuil1.Cells(i - 3, "A").Font.Bold, """ *""", "")
  Next
  .OLEObjects("MaListBox").ListFillRange = "P5:S32" 'pour MAJ
End With
End Sub

L'astérisque est placé si la police en colonne A de Feuil1 est en gras.

Fichier joint.

PS : j'ai viré vos macros qui semaient le pataquès...

A+

job75 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Bien entendu on peut mettre n'importe quel texte à la place de l'astérisque :

Code:

Sub MAJ_ListBox()
'Feuil1 et Feuil2 sont les CodeNames des feuilles
Dim i&
With Feuil2
  For i = 5 To .Range("S" & Rows.Count).End(xlUp).Row
    .Cells(i, "S").NumberFormat = _
      "@" & IIf(Feuil1.Cells(i - 3, "A").Font.Bold, """ attention !""", "")
  Next
  .OLEObjects("MaListBox").ListFillRange = "Tab" 'pour MAJ
End With
End Sub

Noter que j'ai défini le tableau dynamiquement par le nom Tab :

Code:

=DECALER('feuille 2'!$P$4;1;;EQUIV("zzz";'feuille 2'!$P:$P)-LIGNE('feuille 2'!$P$4);4)

Fichier joint.

A+

Tophe2 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

MERCI Cela fonctionne Très bien et me permettra de voir très rapidement ceux qui auront été validé.

Peux tu m'expliquer sommairement la macro

For i = 5 To .Range("S" & Rows.Count).End(xlUp).Row
.Cells(i, "S").NumberFormat = _
"@" & IIf(Feuil1.Cells(i - 3, "A").Font.Bold, """ attention !""", "")

Si je souhaite mettre l'Astérix en colonne P je change juste les deux endroits ou il est inscrit "S" ?

Si un format text et non Nombre je change cela Cells(i, "S").NumberFormat et je mets Cells(i, "S").text ?

Modif : Si je vais chercher les données dans un autre fichier puis je faire la même chose en modifiant ceci IIf(Feuil1.Cells(i - 3, "A mais comment écire je veux aller chercher le fichier toto et l'onglet essai pour le reste la mise en forme du tableau reste la même.

Merci encore pour ton aide
Bonne Journée
Christophe.

job75 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Tophe2 à dit:
Peux tu m'expliquer sommairement la macro (...)

Si je souhaite mettre l'Astérix en colonne P je change juste les deux endroits ou il est inscrit "S" ?

Si un format text et non Nombre je change cela Cells(i, "S").NumberFormat et je mets Cells(i, "S").text ?

Faudrait peut-être travailler un peu Tophe2, et faire fonctionner vos méninges.

Sinon vous ne progresserez jamais en VBA 🙄

A+

Tophe2 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Je suis plutôt quelqu'un qui travaille, qui cherche à comprendre en essayant de bien faire (dans la mesure du possible).

Je pense avoir compris une partie du code cependant je peux comprendre que mes questions soient déplacées (1000 excuses) je cherchais juste une explication sur le format nombre.

Je voulais savoir si ce code pouvait être adapté si nous avons une feuille (liste: exemple feuille1) qui se trouve dans un autre fichier ?

Merci
Bonne Journée
Christophe

job75 · 3 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Il suffit de préciser le nom du fichier quand on définit la feuille "feuille1".

Donc remplacer l'expression :

Code:

IIf(Feuil1.Cells(i - 3, "A").Font.Bold, """ attention !""", "")

par :

Code:

IIf(Workbooks("TOTO.xlsm").Sheets("feuille1").Cells(i - 3, "A").Font.Bold, """ attention !""", "")

Le fichier TOTO.xlsm doit être ouvert...

A+

job75 · 4 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Bonjour Tophe2, le forum,

Une autre solution qui utilise une 5ème colonne pour le tableau Tab et la ListBox :

Code:

Sub MAJ_ListBox()
Dim i&, b As Boolean
Application.ScreenUpdating = False
Sheets("Feuille 2").OLEObjects("MaListBox").ListFillRange = ""
For i = 1 To [Tab].Rows.Count
  b = Sheets("Feuille 1").Cells(i + 1, "A").Font.Bold
  'b = Workbooks("TOTO.xlsm").Sheets("Feuille 1").Cells(i + 1, "A").Font.Bold
  [Tab].Cells(i, 5) = [Tab].Cells(i, 4) & IIf(b, "   Validé", "")
Next
Sheets("Feuille 2").OLEObjects("MaListBox").ListFillRange = "Tab"
End Sub

La 4ème colonne de la ListBox est masquée (largeur 0).

Fichier (2).

A+

job75 · 4 Octobre 2013

Re : Aide sur jeux d'icone avec ou sans VBA

Re,

Une dernière solution avec l'affichage des cases d'option dans la ListBox :

Code:

Private Sub MaListBox_Change()
Static flag As Boolean
If flag Then Exit Sub
Dim i&, b As Boolean
flag = True
With MaListBox
  .ListStyle = fmListStyleOption 'affiche les cases d'option
  .MultiSelect = fmMultiSelectMulti
  For i = 0 To .Object.ListCount - 1
    b = Sheets("Feuille 1").Cells(i + 2, "A").Font.Bold
    'b = Workbooks("TOTO.xlsm").Sheets("Feuille 1").Cells(i + 2, "A").Font.Bold
    .Object.Selected(i) = b
  Next
End With
flag = False
End Sub

La macro est dans le code de "Feuille 2"

Elle se lance quand on clique dans la ListBox.

C'est probablement la meilleure des solutions que j'ai proposées.

Fichier (3).

A+

Aide sur jeux d'icone avec ou sans VBA

Tophe2

XLDnaute Impliqué

Pièces jointes

Tophe2

XLDnaute Impliqué

Pièces jointes

Tophe2

XLDnaute Impliqué

job75

XLDnaute Barbatruc

Tophe2

XLDnaute Impliqué

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

Tophe2

XLDnaute Impliqué

job75

XLDnaute Barbatruc

Tophe2

XLDnaute Impliqué

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Aide sur jeux d'icone avec ou sans VBA

XLDnaute Impliqué

Pièces jointes

XLDnaute Impliqué

Pièces jointes

XLDnaute Impliqué

XLDnaute Barbatruc

XLDnaute Impliqué

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Impliqué

XLDnaute Barbatruc

XLDnaute Impliqué

XLDnaute Barbatruc

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

Discussions similaires

Privacy & Transparency

Privacy & Transparency