XL 2019 Afficher le résultat d'une formule dans un popup par exemple

sum01 · 13 Mars 2023

Bonsoir le forum,

J'ai repris une toute récente discussion dont faisait partie ce fichier qui en était parmi les premières versions. Mais le sujet n'étant pas le même, j'espère faire juste en ouvrant une nouvelle discussion. La feuille 1 renvoie les pays qui répondent à la condition "merci". Pour des questions de facilité de lecture entre les deux tableaux, je me demandais comment récupérer l'information complète de la Feuille 2, par exemple lorsque je passe sur la cellule A2 de la Feuille 1, un popup (ou autre) s'affiche avec le texte complet de la cellule E3 de la Feuille 2. Je ne peux pas utiliser les liens hypertextes, car à chaque à mise à jour du tableau, les pays peuvent changer. Pour l'Australie sera sera la cellule H4 de la Feuille 2 et pour le Canada se sera la cellule K3 de la Feuille 2 par exemple.

Merci d'avance et toute bonne soirée

job75 · 13 Mars 2023

Bonsoir sum01,

sum01 à dit:
Pour des questions de facilité de lecture entre les deux tableaux, je me demandais comment récupérer l'information complète de la Feuille 2, par exemple lorsque je passe sur la cellule A2 de la Feuille 1, un popup (ou autre) s'affiche avec le texte complet de la cellule E3 de la Feuille 2.

A priori il faut que le texte recherché soit mis dans un commentaire en Feuil1, c'est faisable en VBA.

A+

sum01 · 14 Mars 2023

job75 à dit:
Bonsoir sum01,

A priori il faut que le texte recherché soit mis dans un commentaire en Feuil1, c'est faisable en VBA.

A+

Bonjour job75,
Plaisir de vous retrouver. Encore merci pour votre dernière réponse. Cela m’aide beaucoup !
Par rapport à votre réponse ci-dessus, il faut que la solution passe par des commentaires qui s’afficheraient sur les cellules visitées et qui reprendraient le texte complet ?
Merci d’avance et belle journée à vous

job75 · 14 Mars 2023

Bonjour sum01, le forum,

Voyez le fichier joint et le code de la 1ère feuille :

VB:

Option Compare Text 'la casse est ignotée

Private Sub Worksheet_Activate()
Dim critere$, P As Range, nlig&, j%, a$(), b$(), i&, n%
critere = "*merci*"
Set P = Sheets("Feuil2").UsedRange
nlig = P.Rows.Count
For j = 1 To P.Columns.Count
    If Application.CountIf(P.Columns(j), critere) Then
        ReDim Preserve a(n) 'base 0
        ReDim Preserve b(n) 'base 0
        a(n) = P(1, j)
        For i = 2 To nlig
            If P(i, j) Like critere Then b(n) = b(n) & vbLf & P(i, j)
        Next i
        b(n) = Mid(b(n), 2) 'supprime le 1er vbLf
        n = n + 1
    End If
Next j
'---restitution---
Application.ScreenUpdating = False
If FilterMode Then ShowAllData 'si la feuille est filtrée
With [A2] '1ère cellule de destination
    .Resize(Rows.Count - .Row + 1).Clear 'RAZ
    If n = 0 Then Exit Sub
    .Resize(n) = Application.Transpose(a) 'Transpose est limitée à 65536 lignes
    For i = 1 To n
        .Cells(i).AddComment b(i - 1) 'crée un commentaire
        With .Cells(i).Comment.Shape
            .Width = 1000
            .TextFrame.AutoSize = True 'ajustement largeur
        End With
    Next
    .Resize(n).Sort .Cells, xlAscending, Header:=xlNo 'tri
End With
End Sub

La macro se déclenche quand on active la feuille.

A+

job75 · 14 Mars 2023

Dans ce fichier (2) j'ai ajouté l'adresse de la cellule où se trouve le texte :

VB:

        For i = 2 To nlig
            If P(i, j) Like critere Then b(n) = b(n) & vbLf & P(i, j).Address(0, 0) & " - " & P(i, j)
        Next i

sum01 · 15 Mars 2023

job75 à dit:
Dans ce fichier (2) j'ai ajouté l'adresse de la cellule où se trouve le texte :

VB:

For i = 2 To nlig If P(i, j) Like critere Then b(n) = b(n) & vbLf & P(i, j).Address(0, 0) & " - " & P(i, j) Next i

Bonsoir Job75,

Merci infiniment pour votre réponse et superbe code. J'ai tenté de l'adapter également sur un autre type fichier semblable mais déception, je pensais l'avoir appréhendé et pouvoir l'appliquer. Le retour de bâton est bien violent. Sur c'est autre fichier, et c'est normal, je n'arrive pas à faire fonctionner le process. Le principe est le même.
Le tableau dans l'onglet Reporting est dynamique. Les données vont être alimentées de manière mensuelle sur la base des onglets 12.2022, 01.2023, etc... Les analyses menées vont déterminer dans quelle catégorie (1-2-3-4-5) les pays seront classés. Je voulais appliquer le même code de façon à ce qu'un commentaire associé à la cellule A11 apparaisse dans reporting et reprenne le texte correspondant de la dans la cellule B6 de l'onglet 12.2022 si on fait l'analyse du mois de décembre 2022, et ainsi de suite. Mais coup dans l'eau, à nouveau je suis dans l'obscurité totale.

Un immense merci pour votre précieuse aide

job75 · 15 Mars 2023

Bonjour sum01,

Désolé mais je n'ai rien compris.

Ce ne semble plus être le même problème, créez une nouvelle discussion et soyez plus clair.

A+

sum01 · 15 Mars 2023

job75 à dit:
Bonjour sum01,

Désolé mais je n'ai rien compris.

Ce ne semble plus être le même problème, créez une nouvelle discussion et soyez plus clair.

A+

Bonsoir job75,
C'est noté, je vais ouvrir une nouvelle discussion. Navré pour manque de clarté

Bonne soirée à vous

XL 2019 Afficher le résultat d'une formule dans un popup par exemple

sum01

XLDnaute Occasionnel

Pièces jointes

job75

XLDnaute Barbatruc

sum01

XLDnaute Occasionnel

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

sum01

XLDnaute Occasionnel

Pièces jointes

job75

XLDnaute Barbatruc

sum01

XLDnaute Occasionnel

Discussions similaires