3 questions VBA...

[patsyl60]

Bonjour le forum,

Je dois réaliser une étude de plusieurs portefeuilles clients.

Pour être précis, chaque vendeur a des secteurs autorisés ( colonne I de mon fichier( concatenation du code profession et du code département))
et je dois faire ressortir tout ce qui ne correspond pas aux secteurs autorisés.

J'ai commencé mon fichier mais j'ai plusieurs problèmes :

1/ Dans ma macro, je souhaite selectionner uniquement la plage A à F et non la ligne complète.

2/ Le nombre de secteurs autorisés est variable ( 2 dans mon exemple mais peut être de 1 ou 15 selon les vendeurs et je souhaite que le macro compare tous les codes secteurs autorisés, plutôt que de les mettre manuellement dans la macro.

3/ Ma macro fonctionne bien avec le signe = mais ne fonctionne pas avec le signe <>

J'espère avoir été le plus précis possible dans mes explications.

D'avance, merci de votre aide.

Patsyl60 😕

 

[Pierrot93]

Re : 3 questions VBA...

Bonjour,

pour ta 1ère question, modifie peut être ainsi :

Sub Macro1()
Dim i As Integer

'Remise à zéro des couleurs
Cells.Interior.ColorIndex = xlNone
    
' colorier selon secteurs
For i = Range("A65536").End(xlUp).Row To 2 Step -1
If Cells(i, 6).Value = Range("I2").Value Or Cells(i, 6).Value = Range("I3").Value Then
Cells(i, 1).Resize(, 6).Interior.ColorIndex = 2
Else
Cells(i, 1).Resize(, 6).Interior.ColorIndex = 22
End If
Next i
Range("A1").Select
End Sub

bonne journée
@+

 

[patsyl60]

Re : 3 questions VBA...

Bonjour Pierrot93,

Merci pour ta réponse rapide. 1ère question résolue...

Bonne journée.

Patsyl60

 

[suistrop]

Re : 3 questions VBA...

Salut vous 2,

Pour la question 2 peut etre comme cela :

Sub Macro1()
Dim i As Integer

'Remise à zéro des couleurs
Cells.Interior.ColorIndex = xlNone

' colorier selon secteurs
For i = Range("A65536").End(xlUp).Row To 2 Step -1
colorier = False
    For y = 2 To Range("I65536").End(xlUp).Row
        If Cells(i, 6).Value = Cells(y, 9) Then
            Cells(i, 1).Resize(, 6).Interior.ColorIndex = 2
            colorier = True
            Exit For
        End If
    Next y
    If colorier = False Then Cells(i, 1).Resize(, 6).Interior.ColorIndex = 22
Next i
Range("A1").Select
End Sub

 

[patsyl60]

Re : 3 questions VBA...

Salut suistrop,

Merci pour ton aide. Ta macro répond tout à fait à ce que je souhaite.

De plus cela contourne ma 3ème question bien que je ne comprenne pas pourquoi elle ne marche pas...

Je vais maintenant essayer de comprendre ton code...

Encore merci à toi et Pierrot93 pour votre aide.

Patsyl60 😉

 

[suistrop]

Re : 3 questions VBA...

Salut ,

J'ai un peu commenté ma démarche :

Sub Macro1()
Dim i As Integer

'Remise à zéro des couleurs
Cells.Interior.ColorIndex = xlNone
' colorier selon secteurs
For i = Range("A65536").End(xlUp).Row To 2 Step -1

colorier = False 'Ici on creer une variable pour que si la ligne a pas été colorier avec "2" on la colorie avec "22"
    For y = 2 To Range("I65536").End(xlUp).Row 'ici on va parcourir tous les code valide
        If Cells(i, 6).Value = Cells(y, 9) Then 'si on tombe sur un code valide, alors on va le colorier avec "2"
            Cells(i, 1).Resize(, 6).Interior.ColorIndex = 2
            colorier = True 'On a colorier avec 2 donc on met colorier a VRAI
            Exit For 'On a colorier ca sert a rien de parcourir les autres codes de la colonne I
        End If
    Next y
    If colorier = False Then Cells(i, 1).Resize(, 6).Interior.ColorIndex = 22 'Si on a pas colorier avec 2 on colorie avec 22
Next i
Range("A1").Select
End Sub

 

[patsyl60]

Re : 3 questions VBA...

Merci suistrop,

C'est maintenant un peu plus clair pour moi.

Bonne soirée à tous.

Patsyl60 😉

 

[Pierrot93]

Re : 3 questions VBA...

Bonjour Patsyl, Suistrop

une autre solution pour éviter une 2ème boucle :

Sub test()
Dim i As Integer, x As Range
Application.ScreenUpdating = False
Cells.Interior.ColorIndex = xlNone
For i = 2 To Range("A65536").End(xlUp).Row
    Set x = Range("I:I").Find(Cells(i, 6).Value, , xlValues, xlWhole, , , False)
    Cells(i, 1).Resize(, 6).Interior.ColorIndex = IIf(x Is Nothing, 22, 2)
Next i
Application.ScreenUpdating = True
End Sub

bonne journée
@+

 

[patsyl60]

Re : 3 questions VBA...

Merci Pierrot93.

Peux tu me commenter ton "set x =" car je ne comprend pas tout.

Set x = Range("I:I").Find(Cells(i, 6).Value, , xlValues, xlWhole, , , False)
    Cells(i, 1).Resize(, 6).Interior.ColorIndex = IIf(x Is Nothing, 22, 2)

Encore merci.

Patsyl60

 

[Pierrot93]

Re : 3 questions VBA...

Re,

la méthode "find" renvoie un objet range si la valeur est trouvée. J'utilise une variable pour stocker cet objet, par contre si la recherche n'a pas aboutie la variable ne sera pas initialisée et restera affectée du mot clé "nothing" ce qui permet de faire ensuite le test...

 

[patsyl60]

Re : 3 questions VBA...

Merci Pierrot93 pour ta réponse et tes explications.

Bonne fin de journée à tous.

Patsyl60 😉