Vitesse d'exécution

Hamza · 26 Décembre 2014

Bonjour le forum,

J'ai un problème de vitesse d'exécution j'ai essayé de voir sur le forum des problèmes similaires mais pareil je n'arrive pas à améliorer la vitesse d'exécution (6 s). je voudrais savoir s'il est possible d'accélérer la vitesse d'exécution du code VBA ci-dessous.

Merci d'avance

Hamza

Private Sub ComboBox_Armoire_Change()

Application.ScreenUpdating = False

'Remplir le tableau LCB
Dim Derlig As Long
Dim y As Integer
Dim j As Integer
Dim lig As Long

Range("C20:O21").ClearContents

'Derlig = Sheets("LCB_List").Range("A65536").End(xlUp).Row

lig = 3

For j = 2 To 600
For y = 3 To 90

If Sheets("LCB_List").Cells(j, 1).Formula = Sheets("Informatique client").Range("Used_Name").Text _
And Sheets("LCB_List").Cells(j, 2).Formula = Sheets("PLC et Equipements").ComboBox_Armoire.Text _
And Sheets("LCB_List").Cells(j, y).Value <> "" Then

Sheets("PLC et Equipements").Cells(21, lig).Value = Sheets("LCB_List").Cells(j, y).Value
Sheets("PLC et Equipements").Cells(20, lig).Value = Sheets("LCB_List").Cells(1, y).Value

lig = lig + 1

End If

Next

Next

Application.ScreenUpdating = True

End Sub

mapomme · 26 Décembre 2014

Re : Vitesse d'exécution

Bonsoir Hamza,

Un fichier joint inciterait les forumeurs à se pencher sur votre problème et à pouvoir tester...

Dranreb · 26 Décembre 2014

Re : Vitesse d'exécution

Bonsoir.

Essayez ça :

VB:

Private Sub ComboBox_Armoire_Change()
Dim NomCli As String, Armoire As String, _
   Te(), Le As Long, Ce As Long, Ts(), Cs As Long
With Worksheets("LCB_List")
   Te = .[A1].Resize(.[A65536].End(xlUp).Row, 100).Value
   NomCli = .[Used_Name].Text
   End With
ReDim Ts(1 To 2, 1 To 100)
Armoire = Sheets("PLC et Equipements").ComboBox_Armoire.Text
For Le = 2 To UBound(Te, 1)
   For Ce = 3 To UBound(Te, 2)
      If Te(Le, 1) = NomCli And Te(Le, 2) = Armoire And Te(Le, Ce) <> "" Then
         Cs = Cs + 1
         Ts(1, Cs) = Te(Le, Ce)
         Ts(2, Cs) = Te(1, Ce)
         End If: Next Ce, Le
With Worksheets("PLC et Equipements")
   .[C21].Resize(2, 100).ClearContents
   .[C21].Resize(2, Cs).Value = Ts: End With
End Sub

À tester, puisque je ne le pouvais…

Remarque: Ça devrait être des milliers de fois plus rapide vu qu'il n'y a que 5 accès aux contenus de feuilles, 3 en entrée, 2 en sortie contre quelques dizaines de milliers dans votre code initial.

Hamza · 29 Décembre 2014

Re : Vitesse d'exécution

Bonjour,

Dranreb Merci Beaucoup ça marche bien comme il faut, je viens juste de l'essayer et ça marche du premier coup.

Cordialement

Hamza

Vitesse d'exécution

Hamza

Guest

mapomme

XLDnaute Barbatruc

Dranreb

XLDnaute Barbatruc

Hamza

Guest

Discussions similaires

Vitesse d'exécution

Hamza

Guest

mapomme

XLDnaute Barbatruc

Dranreb

XLDnaute Barbatruc

Hamza

Guest

Discussions similaires

Privacy & Transparency

Privacy & Transparency