VBA : Insertion de saut de page

[dionys0s]

Bonjour le forum

j'ai une zone d'impression comme ceci par exemple :
ZonImpr = "A1:AY27,A28:AY45,AZ46:BL63,BM64:BT75,BM76:BT87"

et j'aimerais, juste après avoir défini la zone d'impression (Feuil.PageSetup.PrintArea = Feuil.Range(ZonImpr).Address(False, False)) ajouter un saut de page entre chaque zone de la zone d'impression.

D'avance merci pour votre aide ^^

 

[job75]

Re : VBA : Insertion de saut de page

Bonjour dionys0s, le forum,

Il faudrait savoir ce que vous voulez imprimer exactement.

S'il s'agit d'imprimer chacune des 5 zones sur une page en largeur, l'ajout de sauts de page n'est pas une bonne solution.

Il faut alors imprimer chaque zone séparément :

Sub Imprimer()
Dim ZonImpr$, s
ZonImpr = "A1:AY27,A28:AY45,AZ46:BL63,BM64:BT75,BM76:BT87"
With ActiveSheet.PageSetup 'feuille à définir
  .Orientation = xlLandscape
  .Zoom = False
  .FitToPagesWide = 1
  .FitToPagesTall = False
  .Parent.ResetAllPageBreaks
  For Each s In Split(ZonImpr, ",")
    .PrintArea = .Parent.Range(s).Address
    .Parent.PrintPreview '.Parent.PrintOut
  Next
  '---RAZ facultatif---
  .Zoom = 100
  .FitToPagesWide = False
  .PrintArea = ""
End With
End Sub

A+

 

[job75]

Re : VBA : Insertion de saut de page

Re,

Avec des sauts de page horizontaux et une seule impression :

Sub Imprimer()
Dim ZonImpr$, s
ZonImpr = "A1:AY27,A28:AY45,AZ46:BL63,BM64:BT75,BM76:BT87"
With ActiveSheet 'feuille à définir
  With .PageSetup
    .Orientation = xlLandscape
    .Zoom = False
    .FitToPagesWide = 1 '1 page en largeur
    .FitToPagesTall = False
    .Parent.ResetAllPageBreaks
    .PrintArea = ZonImpr
  End With
  For Each s In Split(ZonImpr, ",")
    .HPageBreaks.Add .Range(Split(s, ":")(1))(2)
  Next
  .PrintPreview '.PrintOut
End With
End Sub

A+