VBA - élément d'un tablo

[Hervé]

bonjour

petite interrogation de ma part, alors je me tourne vers vous.

je ne comprend pas pourquoi cette macro ne fonctionne pas, elle doit simplement mettre en minuscule un texte :

Sub macro1()
Dim tablo, element
Dim texte As String

texte = "VIVE LE VENT D'HIVER"
tablo = Split(texte, " ")

For Each element In tablo
    element = LCase(element)
Next element

MsgBox Join(tablo, " ")
End Sub

alors que celle-ci fonctionne :

Sub macro2()
Dim tablo
Dim i As Byte
Dim texte As String

texte = "VIVE LE VENT D'HIVER"
tablo = Split(texte, " ")

For i = 0 To UBound(tablo)
    tablo(i) = LCase(tablo(i))
Next i

MsgBox Join(tablo, " ")
End Sub

dans la premiere macro, la variable élément ne serait-elle pas attaché au tableau ?

en vous remerciant par avance.

salut

 

[Jacques87]

Re : VBA - élément d'un tablo

jour Hervé

il me semble que dans ta première macro, ce n'est pas parce que tu changes ton texte de majuscule en minuscule que les éléments du tableau subissent cette transformation.
Il te faut reconstuire le tableau avec les nouveaux éléments en minuscule

d'où

Sub macro1()
Dim tablo As Variant, element As Variant
Dim texte As String
Dim i as integer
texte = "VIVE LE VENT D'HIVER"
tablo = Split(texte, " ")
i = 0
For Each element In tablo
    element = LCase(element)
    tablo(i) = element: i = i + 1
Next element
MsgBox Join(tablo, " ")
End Sub
 
enfin ce n'est que mon avis
 
Amicalement

 

[Ti_]

Re : VBA - élément d'un tablo

Salut

En fait, ici le changement n'est pas répercuté sur les éléments du tableau parce que ce ne sont que des variables String "simples" et non pas des objets. Si ton tableau était composé d'objets (des Range par exemple) alors le changement se ferait bien directement dans le tableau, parce que tu référencerais l'objet source lui-même, alors que là ton "element" est une variable qui a pris le type String et qui récupère la valeur de chacune des chaînes du tableau - mais ce ne sont pas les chaînes elles-mêmes.
Pour aller modifier directement chacune des chaines du tableau avec une syntaxe de ce type, il faudrait utiliser un pointeur, ce que d'autres langages plus évolués permettent, mais hélas pas le VBA...

Je ne sais pas si mon explication est très claire. Si on a compris ça, on a compris globalement la différence entre une variable simple et une variable objet.

 

[Hervé]

Re : VBA - élément d'un tablo

bonjour a vous deux

merci pour ces explications 🙂

salut