XL 2019 vba : copier en valeur un onglet avant envoi par mail

[douguy]

bonjour le forum

Je bute sur un problème de copie valeur
je veux envoyer un onglet par mail avec VBA
L'onglet en question a des formules que je souhaite remplacer par la valeur avant envoi
Le code marche super sauf qu'il reprend les formules puisqu'il ne fait pas le coller pastespecial xlvalue
comment indiqué ce collage spécial?

MErci pour votre aide

le code utilisé est le suivant

Sub EnvoiMailavecPJ()
 
    Dim chemin As String, fichier As String
 
    chemin = ThisWorkbook.Path
    fichier = chemin & "\" & "fichier" & Range("A3") & ".xls"
 
    ThisWorkbook.Sheets("base").Copy
    ActiveWorkbook.SaveAs Filename:=fichier
 
    Dim MonOutlook As Object
    Dim MonMessage As Object
 
    Set MonOutlook = CreateObject("Outlook.Application")
    Set MonMessage = MonOutlook.CreateItem(0)
 
        MonMessage.To = "xxxxx@yyyy.fr"
        MonMessage.Subject = "pppp"
        MonMessage.body = "Bonjour," & _
                    Chr(13) & Chr(13) & "Veuillez trouver, ci-joint, fichier pppp ." & _
                    Chr(13) & Chr(13) & "Bonne réception."
 
        MonMessage.Attachments.Add ActiveWorkbook.FullName
        MonMessage.display
 
    ActiveWorkbook.Close
 
    Set MonOutlook = Nothing
 
End Sub

 

[Compte Supprimé 979]

Bonjour Douguy

Merci d'éditer votre post et de mettre le code entre balises SVP 🙄

Sinon, voici comment on peut faire

ThisWorkbook.Sheets("base").Copy
With ActiveWorkbook
  With .Sheets(1)
    .Cells.Copy
    .Cells.PasteSpecial Paste:=xlPasteValues
  End With
  .SaveAs Filename:=Fichier
End With

A+

 

[Staple1600]

Bonsoir le fil

Puisqu'on parle édition, tant qu'on y est, si j'étais moi, je mettrai un mail factice
Du genre : jean.bon@blanc.com
Ah, non , c'est vrai, c'est pas woke
Préférez alors : sojatofu@vegan.edu
😉

PS: Salutations, BrunoM45

 

[Staple1600]

Re

Une autre syntaxe possible
(test OK sur mon PC- le classeur contenant le code VBA doit être enregistré au préalable)

Sub copievaleursseules()
ThisWorkbook.Sheets("base").Copy
ActiveSheet.UsedRange = ActiveSheet.UsedRange.Value
With Workbooks(ActiveSheet.Parent.Name)
    .SaveAs ThisWorkbook.Path & "\test1.xlsx", 51
    .Close 0
End With
End Sub

 

[douguy]

bonjour à vous
Merci pour votre aide. j'ai utilisé la méthode de Bruno !
Ca fonctionne nickel
J'ai édité mon message 😀
Bon dimanche