XL 2016 VBA - Comment détecter la changement de position d'une fenêtre ?

Option Explicit
Rem. Cette classe a pour but de permettre un traitement périodique dans un module objet.
Event Intervient(ByVal Tic As Long)
Rem. Évènement. Se produit périodiquement.
'           Tic: Nombre de millisecondes écoulées depuis le lancement.
Private Idt As Long, Tac As Long
Public Sub Lancer(Optional ByVal FréqHz As Double = 25#)
Rem. Méthode. Démarrage. Préalablement stoppé s'il était déjà lancé.
'           FréqHz: Fréquence en Hertz des déclenchements de Intervient.
'              Facultatf. Fréquence conseillée d'une animation assumée si omis.
   If Idt > 0 Then XRythmeur.StopperRythmeur Idt
   Idt = XRythmeur.IdtRythmeurLancé(Me, FréqHz, Tac)
   End Sub
Public Sub Stopper()
Rem. Méthode. Arrêt. Sans effet s'il n'est pas lancé.
   If Idt <= 0 Then Exit Sub
   XRythmeur.StopperRythmeur Idt: Idt = 0
   End Sub
Public Function Lancé() As Boolean
Rem. Propriété en lecture seule. Condition Rythmeur actif.
   Lancé = Idt > 0
   End Function
Public Sub Actionner(ByVal Tic As Long)
Rem. Méthode. Déclenche l'évènement Intervient.
'       Son invocation par le module objet détenteur n'est pas pertinente.
'       Elle est réservée au dispositif de service XRythmeur.TimerProc, dont l'exécution
'       pérodique est instaurée par une invocation de la méthode Lancer.
   RaiseEvent Intervient(Tic - Tac)
   End Sub

Rem. Module de servive effecteur de tâches des objets Rythmeur.
'    NE PAS UTILISER EN PROGRAMMATION APPLICATIVE.
Option Explicit
               #If VBA7 Then
Private Declare PtrSafe Function GetTickCount Lib "kernel32.dll" () As Long
Private Declare PtrSafe Function SetTimer Lib "user32.dll" _
   (ByVal Hwnd As Long, ByVal Idt As Long, ByVal DuréeMS As Long, ByVal AdrSub As LongPtr) As Long
Private Declare PtrSafe Function KillTimer Lib "user32.dll" _
   (ByVal Hwnd As Long, ByVal Idt As Long) As Long
               #Else
Private Declare Function GetTickCount Lib "kernel32.dll" () As Long
Private Declare Function SetTimer Lib "user32.dll" _
   (ByVal Hwnd As Long, ByVal Idt As Long, ByVal DuréeMS As Long, ByVal AdrSub As Long) As Long
Private Declare Function KillTimer Lib "user32.dll" _
   (ByVal Hwnd As Long, ByVal Idt As Long) As Long
                  #End If
Private TRythmeurs() As Rythmeur, Idt As Long
Public Function IdtRythmeurLancé(ByVal Ryth As Rythmeur, ByVal FréqHz As Double, ByRef Tac As Long) As Long
   Dim P As Long, M As Long
   On Error Resume Next: M = UBound(TRythmeurs): If Err Then ReDim TRythmeurs(1 To 1): M = 1
   On Error GoTo 0
   For P = 1 To M: Idt = Idt Mod M + 1
      If TRythmeurs(Idt) Is Nothing Then Exit For
      Next P
   If P > M Then ReDim Preserve TRythmeurs(1 To P): Idt = P
   Set TRythmeurs(Idt) = Ryth
   SetTimer ThisWorkbook.Windows(1).Hwnd, Idt:=Idt, DuréeMS:=Int(1000 / FréqHz + 0.5), AdrSub:=AddressOf TimerProc
   Tac = GetTickCount: IdtRythmeurLancé = Idt
   End Function
Public Sub StopperRythmeur(ByVal Idt As Long)
   On Error Resume Next
   KillTimer ThisWorkbook.Windows(1).Hwnd, Idt
   Set TRythmeurs(Idt) = Nothing
   End Sub
Private Sub TimerProc(ByVal Hwnd As Long, ByVal uMsg As Long, ByVal Idt As Long, ByVal Tic As Long)
   On Error Resume Next
   TRythmeurs(Idt).Actionner Tic
   If Err Then KillTimer Hwnd, Idt
   End Sub

Public Function TimerX(c As Long)
Dim t
t = Timer
Do While Timer - t < c / 1000: DoEvents: Loop
End Function