Microsoft 365 comment rendre l'affichage d'une cellule bien plus visible, lors du résultat d'une recherche dans un tableau.?

[MARC91]

Bonjour
l'age aidant je trouve que l'affichage de la céllule résultat lors d'une recherche n'est pas trés "visible" "ça ne saute pas aux yeux". Mes tableaux sont trés colorés, la cellule résultat n'est pas suffisamment mise en avant à mon goût.
je ne veux pas modifier la résolution de mon ecran, y a t-il moyen de demander à excel d'afficher la cellule résultat soit avec une plus grosse police, soit avec une couleur trés vive ou encore avec un encadrement de cellule trés épais?
merci pour votre aide.

 

[MARC91]

Bonjour,
C'est normal
Après avoir fait Alt+F11 tu tombes sur un écran vide sur la partie de gauche tu as Feuil1, Feuil2, Feuil3, etc tu double clic dans la feuille adéquat et là tu pourras de nouveau coller ton code

Tiens moi au courant

SltsRegarde la pièce jointe 1195281

Je n'avais pas non plus la fenétre de gauche j'ai trouvé l'icône explorateur de projet du coup en selectionnant le feuil qui va bien j'ai pu coller la macro. et... ça fonctionne, sauf qu'il doit encore y avoir un réglage car ça me redimentionne mes colonnes en trés large le parametre Columns. AutoFit ne doit pas convenir??
pendant que j'y suis quel serait le parametre pour regler hauteur de ligne si besoin?
je sens que l'on tient le bon bout.

 

[riton00]

Bonsoir

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Range("A1:L100,O10,Q6:Q16").Font.Size = 11 'taille de l'écriture normale
If Not Intersect(Target, Range("A1:L100,O10,Q6:Q16")) Is Nothing Then Target.Font.Size = 60 'taille de l'écriture cellule sélectionné
Columns.AutoFit
End Sub

Il faut diminuer Font.Size = 60
Pour un essai change 60 par 50 et si ça ne te convient toujours pas tu peux soit augmenter ou diminuer à toi de trouver la bonne valeur
Slts

 

[Dudu2]

Bonjour,
J'avais fait ça autrefois...

Rechercher des valeurs dans une feuille Excel avec marquage visuel (couleur et flèche) des trouvés

Le fichier à télécharger contient un Module_FindHighlight et sa fonction FindHighlight qui permet de faire une recherche dans une feuille Excel en marquant visuellement par une couleur de fond et une forme flèche les occurrences trouvées. Pour...

excel-downloads.com

Après, si tu veux l'avoir et permanence, tu ajoutes un Application.Onkey "^+f" (Ctrl + SHift + "f") sur la macro dans le Workbook_Open() et enregistres ce fichier en tant que complément.

 

[MARC91]

Bonsoir

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Range("A1:L100,O10,Q6:Q16").Font.Size = 11 'taille de l'écriture normale
If Not Intersect(Target, Range("A1:L100,O10,Q6:Q16")) Is Nothing Then Target.Font.Size = 60 'taille de l'écriture cellule sélectionné
Columns.AutoFit
End Sub

Il faut diminuer Font.Size = 60
Pour un essai change 60 par 50 et si ça ne te convient toujours pas tu peux soit augmenter ou diminuer à toi de trouver la bonne valeur
Slts

Bonjour j'avais compris cela , la police du résultat est bien reduite mais , mes colonnes sont maintenant extra large, je les ai pourtant redimensionnées mais rien n'y fait j'ai un binz total dans toute ma feuille heureusement que c'était un test. Je dois préciser aussi que j'ai un trés grand range
mon écriture est-elle correcte? pour 22790 lignes et 17 colonnes
-------------------------------------------------------
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Range("A2:Q22790").Font.Size = 11 'taille de l'écriture normale
If Not Intersect(Target, Range("A2:Q22790")) Is Nothing Then Target.Font.Size = 25 'taille de l'écriture cellule sélectionné
Columns.AutoFit
End Sub
........................................................................................................
merci pour votre aide

 

[riton00]

Bonjour,
Ne pourrais-tu pas mettre un bout de fichier anonymisé à la dispo puisque j'ai recopier le code que tu as fourni au post #19 et chez moi cela n'agit pas sur les colonnes à part bien sûr si dans les cellules tu as une grande longueur de texte. Puisque logiquement cela agit sur la cellule cliqué
Slts

 

[fanch55]

Salut à tous,
La méthode d'agir sur les polices et taille des colonnes sur une grande plage est assez destructrice et consommatrice de mémoire et de temps .
Tel que c'est proposé, cela est une bonne idée si l'utilisateur se fout complètement de la mise en page et des largeurs de colonnes. Imposer une largeur de colonne par défaut peut faire augmenter la hauteur de certaines lignes quand le contenu est plus grand que la cellule contenant .

A mon avis ( ce n'est que le mien ... ), il vaut mieux laisser les hauteurs de lignes et largeurs de colonne telles qu'elles existent et de se servir du subterfuge d'un ou plusieurs shapes ( formes graphiques ) pour signaler la cellule sélectionnée ou recherchée ( voir le post @Dudu2 ) ou utiliser le code ci-dessous :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next: [Select_Box].Delete: [Big_Text].Delete: On Error GoTo 0
    Select Case True
        Case Target.Count > 1
        Case Target = ""
        Case Else
            With Shapes.AddShape(msoShapeRoundedRectangle, _
                    Target.Left - 5, Target.Top - 5, _
                    Target.Width + 10, Target.Height + 10)
                .Name = "Select_Box"
                .Fill.Visible = msoFalse
                .Line.Visible = msoTrue
                .Line.Weight = 1.5
                .Line.ForeColor.RGB = vbRed
            End With
            With Shapes.AddShape(msoShapeLeftArrowCallout, _
                    [Select_Box].Left + [Select_Box].Width, [Select_Box].Top, _
                     200, 200)
                .Name = "Big_Text"
                .Fill.ForeColor.RGB = RGB(255, 255, 204)
                With .TextFrame2
                    .VerticalAnchor = msoAnchorMiddle: .HorizontalAnchor = msoAnchorCenter
                    .MarginLeft = 1:                   .MarginRight = 1
                    .TextRange.Font.Bold = msoTrue
                    .TextRange.Font.Size = Target.Font.Size * 3
                    .TextRange.Font.Fill.ForeColor.RGB = RGB(0, 0, 0)
                    .TextRange.Characters.Text = Target.Text
                    .WordWrap = msoFalse
                    .AutoSize = msoAutoSizeShapeToFitText
                End With
                .Adjustments.Item(4) = 0.85
                .Top = [Select_Box].Top - (.Height - [Select_Box].Height) / 2
            End With
    End Select
End Sub

 

[MARC91]

Salut à tous,
La méthode d'agir sur les polices et taille des colonnes sur une grande plage est assez destructrice et consommatrice de mémoire et de temps .
Tel que c'est proposé, cela est une bonne idée si l'utilisateur se fout complètement de la mise en page et des largeurs de colonnes. Imposer une largeur de colonne par défaut peut faire augmenter la hauteur de certaines lignes quand le contenu est plus grand que la cellule contenant .

A mon avis ( ce n'est que le mien ... ), il vaut mieux laisser les hauteurs de lignes et largeurs de colonne telles qu'elles existent et de se servir du subterfuge d'un ou plusieurs shapes ( formes graphiques ) pour signaler la cellule sélectionnée ou recherchée ( voir le post @Dudu2 ) ou utiliser le code ci-dessous :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next: [Select_Box].Delete: [Big_Text].Delete: On Error GoTo 0
    Select Case True
        Case Target.Count > 1
        Case Target = ""
        Case Else
            With Shapes.AddShape(msoShapeRoundedRectangle, _
                    Target.Left - 5, Target.Top - 5, _
                    Target.Width + 10, Target.Height + 10)
                .Name = "Select_Box"
                .Fill.Visible = msoFalse
                .Line.Visible = msoTrue
                .Line.Weight = 1.5
                .Line.ForeColor.RGB = vbRed
            End With
            With Shapes.AddShape(msoShapeLeftArrowCallout, _
                    [Select_Box].Left + [Select_Box].Width, [Select_Box].Top, _
                     200, 200)
                .Name = "Big_Text"
                .Fill.ForeColor.RGB = RGB(255, 255, 204)
                With .TextFrame2
                    .VerticalAnchor = msoAnchorMiddle: .HorizontalAnchor = msoAnchorCenter
                    .MarginLeft = 1:                   .MarginRight = 1
                    .TextRange.Font.Bold = msoTrue
                    .TextRange.Font.Size = Target.Font.Size * 3
                    .TextRange.Font.Fill.ForeColor.RGB = RGB(0, 0, 0)
                    .TextRange.Characters.Text = Target.Text
                    .WordWrap = msoFalse
                    .AutoSize = msoAutoSizeShapeToFitText
                End With
                .Adjustments.Item(4) = 0.85
                .Top = [Select_Box].Top - (.Height - [Select_Box].Height) / 2
            End With
    End Select
End Sub

Regarde la pièce jointe 1195418

Bonjour fanch55
je viens de tester cette macro, elle répond pleinement à mon attente, j'ai pu l'intégrer dans ma feuille sans aucune difficulté ça fonctionne trés bien, mes hauteurs et largeurs ne sont pas affectées.
je valide, je considére ce sujet réglé un grand merci à vous pour votre aide.

Un grand merci aussi à riton00 qui m'a ouvert les yeux sur les macros dans excel il a su m'expliquer, pourtant je partais de loin.

En régle générale un grand bravo encore à ce forum et à ses membres , cela fait deux fois que je vous solicite j'y ai trouvé à chaque fois les bonnes réponses sans aucun resenti d'agacement de la part des membres comme ça peut arriver parfois sur des forum spécialisés, j'utilise excel depuis trés longtemps mais seulement peut étre à 20% de ses capacités avec vous j'apprends de plus en plus encore un grand merci.

 

[MARC91]

J'ai signalé comme [RESOLU] à l'admin car je n'ai pas trouvé comment editer le titre de cette discution

 

[TooFatBoy]

J'ai signalé comme [RESOLU] à l'admin car je n'ai pas trouvé comment editer le titre de cette discution

Avez vous vu...? - marquer comme résolu

Bonjour comment mettre une discution comme résolu d avance merci à vous tous

excel-downloads.com

 

[MARC91]

Avez vous vu...? - marquer comme résolu

Bonjour comment mettre une discution comme résolu d avance merci à vous tous

excel-downloads.com

J'ai fait ça je pensais que ça éditait le titre du post.

 

[TooFatBoy]

J'ai fait ça je pensais que ça éditait le titre du post.

Non. Mais pour éditer le titre, il me semble qu'il y a un bouton "Éditer" en haut de page.