VBA 1ère cellule vide d'une ligne

[Magg]

Bonjour,

Je voudrais mettre le résultat d'une ImputBox dans la première cellule vide de la ligne 2.
Je suis donc en train de travailler sur comment rechercher la 1ère cellule vide d'une ligne. En cherchant sur internet je ne trouve que des réponses pour des colonnes mais pas pour une ligne. J'ai essayé de les adapter en utilisant End(xlToRight) au lieu de xlDown mais j'ai des résultats incohérents. Je mets le code que je travaille, peut-être ai-je loupé quelque chose... Avez-vous des idées ?

Sub XY()
Dim r As Long
    r = Range("A2").End(xlToRight).Row + 1
MsgBox "La 1ère cellule vide ligne 2 est : " & r
End Sub

Je n'ai pas fichier à vous montrer comme je travaille sur un fichier vierge mais si vraiment mes propos ne sont pas clairs je peux en bricoler un pour illustrer.

Merci d'avance.

 

[M12]

Bonjour,
Il faut pas mélanger les lignes et les colonnes
lignes=rows
colonnes=columns

Sub XY()
Dim r As Long
    r = Cells(2, Columns.Count).End(xlToLeft).Column + 1
MsgBox "La 1ère cellule vide ligne 2 est : " & r
End Sub

 

[JBARBE]

Bonjour à tous,
Peut-être ceci : en supposant que cela concerne les lignes vides !

Sub XY()
Dim r As Long, vDerniereLigne As Long
vDerniereLigne = ActiveSheet.UsedRange.Rows.Count
    For r = vDerniereLigne To 1 Step -1
    If Application.CountA(Rows(r)) = 0 Then
    MsgBox "La derniere ligne vide est : " & r
    Exit Sub
    End If
    Next r
End Sub

Bonne journée !

 

[Patrice33740]

Bonjour,

La première cellule vide d'une ligne n'est pas obligatoirement la cellule située à droite de la dernière cellule utilisée sur cette ligne !

Sub t()
Dim c As Range
Dim L As Long
  L = 2 'numéro de ligne
  Set c = Rows(L).SpecialCells(xlCellTypeBlanks).Cells(1, 1)
  MsgBox "Première cellule vide de la ligne " & L & " : " & c.Address(False, False)
End Sub

 

[Magg]

Merci pour toutes vos réponses !
J'ai compris où était mon erreur, je me coucherai moins bête.

Bon weekend.