Valeur mini par rapport à une date

[sev]

Bonjour à tous,

Avec une formule comment trouver la valeur mini de la colonne N sur la date d'aujourd'hui en colonne C ?
Si en colonne C il n'y a pas la date d'aujourd'hui : il faudrait la valeur mini de la colonne N sur la date inférieure à aujourd'hui en colonne C.

Début de formule :

=MIN(SI(($C$500:$C$65500)=AUJOURDHUI();$N$500:$N$65500;""))

 

[wilfried_42]

Re : Valeur mini par rapport à une date

bonjour

ta formule à l'aire correcte

=MIN(SI(($C$500:$C$65500)=AUJOURDHUI();$N$500:$N$65500;9^9))

il te suffit de la valider en format formule matricielle en appuyant Ctrl + Maj + Entrée

une fois validée correctement, des {} encadreront automatiquement ta formule

 

[sev]

Re : Valeur mini par rapport à une date

Cela ne me donne pas le résultat escompté.

Je ne voie pas comment intégrer le morceau en bleu dans la formule

=MIN(SI(($C$500:$C$65500)=AUJOURDHUI()ou la dernière date avant aujourd'hui;$N$500:$N$65500;""))

 

[wilfried_42]

Re : Valeur mini par rapport à une date

re:

je n'avais pas tout compris, je n'ai pas testé la formule, avec un fichier exemple ca serait plus facil : m'enfin

=si($C$500:$C$65500>AUJOURDHUI();0;$C$500:$C$65500)

cela te donne une matrice avec les dates < ou = à aujourdhui() : en prenant le Max tu recuperes la derniere date. mais cela veut dire que tu n'as qu'une ligne par date.
si tu en à plusieurs, il te faut non pas travailler sur la date, mais sur la ligne

=si($C$500:$C$65500>AUJOURDHUI();0;ligne($C$500:$C$65500))

=Max(si($C$500:$C$65500>AUJOURDHUI();0;ligne($C$500:$C$65500)))

que cela soit avec les date ou les lignes, cela te donne le maximum de la matrice créee

=index($C:$C;Max(si($C$500:$C$65500>AUJOURDHUI();0;ligne($C$500:$C$65500))))

cela te donne aujourdhui() ou la date précedent

=index($N:$N;Max(si($C$500:$C$65500>AUJOURDHUI();0;ligne($C$500:$C$65500))))

Doit pouvoir te donne la correspondance sur la colonne N

si j'ai tout compris, mais formules non testées

 

[Tibo]

Re : Valeur mini par rapport à une date

Bonjour,

J'ai un peu travaillé sur la formule, donc je la propose :

=MIN(SI($C$500:$C$65500=MAX(SI($C$500:$C$65500<=AUJOURDHUI();C500:C65500));
N500:N65500))

Matricielle, donc CTRL + MAJ + ENTREE

à tester quand même

Bon app à tous

@+

Edit : Compte tenu de la taille de la plage de cellules, il y aurait peut-être intérêt à la nommer dynamiquement avec la fonction DECALER

@+

 

[sev]

Re : Valeur mini par rapport à une date

Merci Tibo cela fonctionne ; vous m'avez comprise