trouver la dernière valeur d'une colonne

[AlphaOne]

Bjr le forum,

j'aurai une question somme toute simple pour un expert mais un peu floue pour un novice:
comment trouver la dernière valeur d'une colonne à l'aide d'une formule ??
quelqu'un aurais t-il une piste a me donner ?
merci
@+

 

[Jocelyn]

Re : trouver la dernière valeur d'une colonne

Bonjour le Forum,
Bonjour Alphaone,

A tester si tes valeurs sont en colonne A et quelles sont alpha

=RECHERCHE("zzz";A:A)

et pour des valeurs numériques

=RECHERCHE(9^9;A:A)

Cordialement

 

[Misange]

Re : trouver la dernière valeur d'une colonne

Bonjour

Ce lien n'existe plus
Si tu nommes Zone (insertion> nom> définir) la région qui t'intéresse:
{=INDIRECT(ADRESSE(MAX((LIGNE(Zone)*(Zone<>"")));COLONNE(Zone)))}
Formule matricielle : ne pas saisir les accolades mais valider par ctrl+maj+entrée

en VBA
Ce lien n'existe plus
et le classeur exemple d'Alain vallon avec toutes les variantes sur ce thème

[edit bing Philippe et Jocelyn 🙂
il y a aussi cela pour du texte
Ce lien n'existe plus (daniel maher et Alain Vallon)
Comment trouver dans une colonne qui contient à la fois des nombres et du texte la dernière valeur en texte ? Et celle contenant des nombres ?
Dernier TEXTE d'une Plage avec cellules vides ou quasivides (les quasivides sont des formules qui produisent des vides):
=RECHERCHE(2;1/NON((Plage="")+ESTNUM(Plage));Plage)
Dernière valeur numérique : (non matricielle)
=RECHERCHE(9^9;A:A) PS : Eventuellement, remplacer 9^9 par 9^9^9 voire plus ;-)

et encore celle-là
Ce lien n'existe plus

bref le sujet est quasi inépuisable et les définitions de "la dernière cellule" multiples... ]

 

[phlaurent55]

Re : trouver la dernière valeur d'une colonne

Bonjour AlphaOne,

avec cette formule pour trouver la dernière valeur de la colonne A

=RECHERCHE(9^9;A:A)

à+
Philippe

Edit: Bing Bonjour Jocelyn, Misange

 

[Abel]

Re : trouver la dernière valeur d'une colonne

Bonjour AlphaOne,

Essaie :
=LIGNE(INDEX(A1:A100;MAX(NON(ESTVIDE(A1:A100))*LIGNE(A1:A100))))

En formule matricielle (à valider par ctrl+shift+entrée).
Attention, les formules matricielles n'accèptent pas les colonnes entières (en tous cas, pas chez moi) ou alors ça donnera un résultat bidon.
Il faut donc que tu adaptes la plage à ton besoin.
Je n'ai pas essayé avec une plage nommée dynamique.

Abel.

Edit : rhôôôô, phlaurent55, j'en peux rien si ch'uis un peu lent.
ps : ma formule teste le numérique et l'alpha.
Ah zut. Jocelyn et Misange aussi. Oulà, vraiment pas frais, moi, cet après midi ...

 

[AlphaOne]

Re : trouver la dernière valeur d'une colonne

Merci à tous, je vais pouvoir faire mon marché dans vos propositions !!
@+

 

[Dull]

Re : trouver la dernière valeur d'une colonne

Salut AlphaOne, le Forum

Par VBA

Sub EssAi()
Dim DerLig As Long
DerLig = Range("A" & Rows.Count).End(xlUp).Row
MsgBox Range("A" & DerLig).Address
End Sub

Par Formule

=RECHERCHE("ZZZZZZZZZ";Feuil1!A:A)

pour les valeurs alpha

et

=RECHERCHE(9^9;Feuil1!A:A)

pour les valeurs numériques

EDITION: Salut Jocelyn🙂, Flo🙂, Philippe🙂, Abel🙂, EtlesAutres...Là...J'suispasd'accord...Y'a des substances illicites dans VOS 4'heures😡 Certes... y'a le décalage horaire mais vous êtes de vraies boules de nerfs 😛 aussitôt posté... aussitôt répondu🙂 . Heureusement que vous êtes là les amis (es). 🙂🙂😎

Bonne Journée

 

[phlaurent55]

Re : trouver la dernière valeur d'une colonne

Re,

EDITION: Salut Jocelyn🙂, Flo🙂, Philippe🙂, Abel🙂, EtlesAutres...Là...J'suispasd'accord...Y'a des substances illicites dans VOS 4'heures😡 Certes... y'a le décalage horaire mais vous êtes de vraies boules de nerfs 😛 aussitôt posté... aussitôt répondu🙂 . Heureusement que vous êtes là les amis (es). 🙂🙂😎

Ici on est tous dopés à la viande de cheval (de course) 🙂🙂🙂

à+
Philippe