Trier sans macro

[Sandra75]

Bonjour !

Voilà plusieurs heures que je me case la tete sur une formule, si vous pouviez m'aider svp 😕

j'ai une liste de noms et chiffres que je veux trier en case A
A1:0
A2:5
A3:voiture
A4:8
A5:avion
A6:2

Je cherche a faire dans mes case B un trie, avec juste les noms, sans passer par le system de trie et que tout se fasse automatiquement sans l'aide d'un click, et surtout l'un un dessous de l'autre sans espace.

Mes cases en B doit afficher donc :
B1:voiture
B2:avion

 

[Sandra75]

Re : Trier sans macro

J'ai tenter de mettre dans mes cases :
B1 => =SI(ESTTEXTE(A1);A1;SI(ESTTEXTE(A2);A2;SI(ESTTEXTE(A3);A3;SI(ESTTEXTE(A4);A4;SI(ESTTEXTE(A5);A5;SI(ESTTEXTE(A6);A6;""))))))

B2 => =SI(ET(ESTTEXTE(A1);B2<>B1);A1;SI(ET(ESTTEXTE(A2);B2<>B1);A2;SI(ET(ESTTEXTE(A3);B2<>B1);A3;SI(ET(ESTTEXTE(A4);B2<>B1);A4;SI(ET(ESTTEXTE(A5);B2<>B1);A5;SI(ET(ESTTEXTE(A6);B2<>B1);A6;""))))))

Mais ça ne fonctionne pas :/

 

[CISCO]

Re : Trier sans macro

Bonjour

Une possibilité en pièce jointe, avec une formule matricielle à valider donc avec Ctrl+maj+entrée (d'où les { } devant et derrière la formule).

@ plus

 

[Sandra75]

Re : Trier sans macro

ha c'est presque ça !
car si j'ajoute un mot dans la case A1 à la place du '0' il existe 3 mots dans les cellules A, malheureusement les cellules B m'affiche que 2 mots.

En tout cas beau boulot déjà !

 

[JHA]

Re : Trier sans macro

Bonjour à tous,

Problème de "$"

=SI(LIGNE()<=NB.SI($A$1:$A$22;"><"&"");INDEX(A$1:A$22;PETITE.VALEUR(SI(ESTTEXTE(A$1:A$22);LIGNE(A$1:A$22));LIGNE()));"")

JHA

 

[Dull]

Re : Trier sans macro

Salut Sandra, Cisco🙂, le Forum

Pour quelques Dollars de Plus!!!😉

Ajoute des $ à la Belle Formule Matricielle de l'ami Cisco🙂
revalide avec CTRL+SHIFT+ENTER et incrémente vers le bas

=SI(LIGNE()<=NB.SI(A$1:A$22;"><"&"");INDEX(A$1:A$22;PETITE.VALEUR(SI(ESTTEXTE(A$1:A$22);LIGNE(A$1:A$22));LIGNE()));"")

EDITION: Bing! Salut JHA🙂

Bonne Journée

 

[CISCO]

Re : Trier sans macro

Bonjour à tous

Et voui, j'avais oublié les $. Sur un si petit exemple, je n'avais pas vu cette erreur...

@ plus

 

[R@chid]

Re : Trier sans macro

Bonjour @ tous,
Pour le fun, une autre avec tri par ordre croissant...
en B1,

=SIERREUR(INDEX(A$1:A$21;EQUIV(PETITE.VALEUR(SI(ESTTEXTE(A$1:A$21);NB.SI(A$1:A$21;"<"&A$1:A$21));LIGNE());SI(ESTTEXTE(A$1:A$21);NB.SI(A$1:A$21;"<"&A$1:A$21));0));"")

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas
@ +

 

[Sandra75]

Re : Trier sans macro

Un grand merci pour votre aide, ça fonctionne parfaitement ! 🙂