Transposition et collage données

Option Explicit
Option Compare Text

Sub Traitement()
    'Déclaration des variables
    Dim f1 As Worksheet, f2 As Worksheet, f3 As Worksheet, f4 As Worksheet, f5 As Worksheet, f6 As Worksheet, f7 As Worksheet
    Dim DerLig_f1 As Long, DerLig_f2 As Long, DerLig_f3 As Long, DerLig_f4 As Long, DerLig_f5 As Long, DerLig_f6 As Long, DerLig_f7 As Long
    Dim i As Long
    Dim DateSaisie As Double, DateNew As Double
    Dim x As Range, d As Range
    Dim FirstPassageOk As Boolean, SndPassageOk As Boolean
    Set f1 = Sheets("Données Analyse Charge")
    Set f2 = Sheets("Data")
    Set f3 = Sheets("Transfert & Retard")
    Set f4 = Sheets("Bilan")
    Set f5 = Sheets("Extraction")
    Set f6 = Sheets("Liste délai court")
    Set f7 = Sheets("Paramètre")
    
    Application.ScreenUpdating = False 'Evite les scintillements de l'écran et accélère l'exécution du programme
    DerLig_f7 = f7.Range("A" & Rows.Count).End(xlUp).Row 'dernière ligne de la feuille "Paramètre"
    
    '**************************************************************************************************************************************************
    f3.Range("A2:C" & f3.Range("A" & Rows.Count).End(xlUp).Row + 1).ClearContents 'efface les précédents résultats de la feuille ""Transfert & Retard"
    f5.Select 'on se positionne sur la feuille "Extraction"
    
    '**************************************************************************************************************************************************
    '1ère étape :  trier les données en fonction des dates de la plus ancienne saisie à la plus récente de l'onglet "Extraction" en colonne I.
    DerLig_f5 = f5.Range("A" & Rows.Count).End(xlUp).Row 'dernière ligne de la feuille "Extraction"
    f5.Range("A2:M" & DerLig_f5).Sort [I1], 1 'filtrage par date
    
    DerLig_f1 = f1.Range("A" & Rows.Count).End(xlUp).Row 'dernière ligne de la feuille "Données Analyse Charge"
    FirstPassageOk = False 'Le premier passage n'a pas encore eu lieu
    SndPassageOk = False 'Le deuxième passage n'a pas encore eu lieu
    
    '**************************************************************************************************************************************************
    For i = 2 To DerLig_f5 'De la ligne 2 à la dernière ligne de la feuille "Extraction"
        'feuille "Paramètre", on applique la formule en colonne M et on fige les valeurs pour pouvoir les exploiter par la suite
        f7.Range("M2:M" & DerLig_f7).FormulaR1C1 = "=IFERROR(VLOOKUP(RC[-2],'Données Analyse Charge'!C[-10]:C[-4],7,FALSE),0)"
        f7.Range("M2:M" & DerLig_f7).Value = f7.Range("M2:M" & DerLig_f7).Value
        '2ème étape : Une fois triées, elle va faire une recherche V des données de la colonne C de l'onglet Données Analyse Charge par rapport aux données _
            de l'onglet Paramètre en K, et copier coller les valeurs de la colonne L (onglet Paramètre) vers Colonne D (onglet Données Analyse Charge).
       If FirstPassageOk = False Then 'si c'est le premier passage
            'on traite la première ligne de "Extraction"
            f1.Range("D5:D" & DerLig_f1).FormulaR1C1 = "=VLOOKUP(RC[-1],Paramètre!C[7]:C[9],2,FALSE)" 'on récupère les valeurs de la colonne L de "Paramètre" avec une rechercheV
        ElseIf SndPassageOk = False Then 'Si ce n'est plus le premier passage, on traite les lignes suivantes de "Extraction"
            '2ème passage
                '1ère étape : copier les valeurs de la colonne I (Onglet Données Analyse Charge) sur la colonne M (Onglet Paramètre) via une recherche V (la valeur à _
                    rechercher se fait en fonction de la colonne K onglet Paramètre), il faudra faire un copier coller d'un onglet à l'autre via une fonction recherche V
            f7.Range("M2:M" & DerLig_f7).FormulaR1C1 = "=IFERROR(VLOOKUP(RC11,'Données Analyse Charge'!C3:C9,7,FALSE),0)" 'Copie dans M de "Paramètre" avec une rechercheV
            f1.Range("D5:D" & DerLig_f1).FormulaR1C1 = "=VLOOKUP(RC3,Paramètre!C11:C13,2,FALSE)" 'on récupère les valeurs de la colonne M de "Paramètre" dans "D" de "Données Analyse Charge"
            SndPassageOk = True
        End If
        'f1.Range("D5:D" & DerLig_f1).Value = f1.Range("D5:D" & DerLig_f1).Value 'on remplace les formules par leurs valeurs
        
        '3ème étape : Sur (onglet Extraction), en colonne I prendre la première date saisie et la coller en B15 (onglet Data).
        If f5.Cells(i, "I") <> f5.Cells(i - 1, "I") Then 'si les dates sont différentes
            f2.Range("B15").Value = f5.Cells(i, "I").Value ' on copie la date traitée de "Extraction" vers B15 de "Data"
            
            '4ème étape : Une fois le collage en B15 Faite, il va prendre la valeur de la date en B16 (onglet Data) copier et coller en colonne A (démarrage en A2, onglet Transfert & Retard),
            DerLig_f3 = f3.Range("A" & Rows.Count).End(xlUp).Row + 1 'dernière ligne de la feuille "Transfert & Retard"
            f3.Cells(DerLig_f3, "A") = f2.Range("B16").Value 'Copie de la date saisie en B16 de "Data"
            DateSaisie = f3.Cells(DerLig_f3, "A") 'Attribution de la date à la variable "DateSaisie"
            
            'Puis en B (démarrage en B2, onglet Transfert & Retard) la charge à transférer qui se trouve en G (onglet Données Analyse Charge), la cellule _
                à prendre se retrouve en fonction de la croix sur la colonne V du même onglet. S'il identifie une croix, alors il va sur la même ligne en G, _
                copie et colle la valeur sur la colonne B (démarrage en B2, onglet Transfert & Retard)
            If FirstPassageOk = False Then 'si c'est le premier passage
                Set x = f1.Range("C1:C" & DerLig_f1).Find(DateSaisie, LookIn:=xlValues, lookat:=xlWhole) 'on recherche la date saisie
                If Not x Is Nothing Then 'Si la date est trouvée
                    If f1.Cells(x.Row, "V") = "x" Then 'on regarde s'il y a un "x" dans la colonne "V"
                        f3.Cells(DerLig_f3, "B") = f1.Cells(x.Row, "G") 'on copie en "B" la valeur trouvée en "G"
                        'En colonne C (démarrage en C2), sera le retard de la charge planifiée. La valeur est obtenue en fonction des conditions de la colonne F et W _
                            (onglet Données Analyse Charge). Regarder la colonne V, s'il y a une croix alors aller sur la colonne F de cette même ligne.
                        If f1.Cells(x.Row, "F") > 0 Then 'Si la valeur est supérieure à 0. Alors la valeur à mettre en colonne C (onglet Transfert & Retard) sera 0.
                            f3.Cells(DerLig_f3, "C") = 0
                        ElseIf f1.Cells(x.Row, "F") <= 0 Then 'Si inférieure ou égale à 0, alors il faut faire une recherche V de la valeur se trouvant en colonne C (onglet Données Analyse Charge), _
                            mais faire cette recherche V sur la valeur en ligne+1 en partant de la ligne où il y a la croix.
                            DateNew = f2.Range("B6") 'Nouvelle date à rechercher, équivaut à B6 de la feuille "Data"
                            Set x = f1.Range(f1.Cells(x.Row, "C"), f1.Cells(DerLig_f1, "C")).Find(DateNew, LookIn:=xlValues, lookat:=xlWhole)
                            f3.Cells(DerLig_f3, "C") = f1.Cells(x.Row, "D") 'la valeur à coller sur ma colonne C (Onglet Transfert & Retard) sera Le résultat trouvée en colonne L (onglet Paramètre) en fonction de la valeur cherchée en C (onglet Données Analyse Charge).
                        End If
                    End If
                End If
            ElseIf FirstPassageOk = True Then 'si ce sont les passages suivants
                Set x = f1.Range("C1:C" & DerLig_f1).Find(DateSaisie, LookIn:=xlValues, lookat:=xlWhole) 'on recherche la date saisie
                If Not x Is Nothing Then 'Si la date est trouvée
                    If f1.Cells(x.Row, "V") = "x" Then 'on regarde s'il y a un "x" dans la colonne "V"
                        f3.Cells(DerLig_f3, "B") = f1.Cells(x.Row, "G") + f3.Cells(DerLig_f3 - 1, "B") 'on copie en "B" la valeur trouvée en "G" + l'ancienne valeur de charge
                        If f1.Cells(x.Row, "F") > 0 Then 'Si la valeur est supérieure à 0. Alors la valeur à mettre en colonne C (onglet Transfert & Retard) sera 0.
                            f3.Cells(DerLig_f3, "C") = 0
                        ElseIf f1.Cells(x.Row, "F") <= 0 Then 'Si inférieure ou égale à 0, alors il faut faire une recherche V de la valeur se trouvant en colonne C (onglet Données Analyse Charge), _
                            mais faire cette recherche V sur la valeur en ligne+1 en partant de la ligne où il y a la croix.
                            DateNew = f2.Range("B6") 'Nouvelle date à rechercher, équivaut à B6 de la feuille "Data"
                            Set d = f1.Range(f1.Cells(x.Row, "C"), f1.Cells(DerLig_f1, "C")).Find(DateNew, LookIn:=xlValues, lookat:=xlWhole)
                            If Not d Is Nothing Then
                                f3.Cells(DerLig_f3, "C") = f1.Cells(d.Row, "D") + f3.Cells(DerLig_f3 - 1, "C") 'la valeur à coller sur ma colonne C (Onglet Transfert & Retard) + l'ancienne valeur de charge
                            End If
                        End If
                    End If
                End If
            End If
        End If
        FirstPassageOk = True 'le premier passage à eu lieu, donc lors des prochains passages on exécutera les lignes suivantes
    Next i

    f7.Range("M2:M" & DerLig_f7).FormulaR1C1 = "=IFERROR(VLOOKUP(RC[-2],'Données Analyse Charge'!C[-10]:C[-4],7,FALSE),0)" 'réécriture des formules en colonne M de "Paramètre"
    f3.Select ' affichage de la feuille "Transfert & Retard"
    
    '**************************************************************************************************************************************
    'Libération de la mémoire
    Set d = Nothing
    Set x = Nothing
    Set f1 = Nothing
    Set f2 = Nothing
    Set f3 = Nothing
    Set f4 = Nothing
    Set f5 = Nothing
    Set f6 = Nothing
    Set f7 = Nothing
End Sub