XL 2021 traitement de texte

[chingilou]

bonsoir tout le monde
je voudrais si possible par formule au mieux ou par vba au pire epurer une rangée de moins de 200 lignes de textes en retirant les espaces superflues au début à la fin et au mileu du texte et aussi (c la mon probleme que je ne sais même pas comment refléchir a la solution) de mettre le texte en nompropre (majuscule de la 1er lettre ) si seulement le mot (le texte d'une cellule contient plus d'un mot 😁) contient plus de 3 lettres)
merci

 

[mapomme]

Bonjour @chingilou 🙂,

Il doit manquer une petit fichier avec des exemples.

 

[chingilou]

pas besoin de fichier exemple je pense
mettre des cellules en worksheet.proper ou nompropre seulement les mots plus de 3 lettres (est-ce que c'est possible et surtout comment ? )

 

[mapomme]

pas besoin de fichier exemple je pense

C'est vous qui voyez... Ce n'est pas moi qui sollicite une réponse.

En passant, que faites vous des mots de moins de 4 lettres : on les passe en minuscule, on les laisse inchangés ou bien encore autre chose ?

 

[AtTheOne]

Bonne nuit les noctambules ! bonne nuit @chingilou
Avec EXCEL 2021

en retirant les espaces superflues au début à la fin et au mileu du texte

Ça se fait avec la fonction SUPPRESPACE(" mon texte b ")

mettre le texte en nompropre (majuscule de la 1er lettre ) si seulement le mot (le texte d'une cellule contient plus d'un mot 😁) contient plus de 3 lettres)

Cette formule fait le boulot :

=JOINDRE.TEXTE(" ";VRAI;LET(Chaîne;" "&SUPPRESPACE(B4);Nb;NBCAR(Chaîne)-NBCAR(SUBSTITUE(Chaîne;" ";""));Marquage;SUBSTITUE(SUBSTITUE(Chaîne;" ";"¯";LIGNE(DECALER(Feuil1!$A$1;0;0;Nb;1)));" ";"¯";LIGNE(DECALER(Feuil1!$A$1;0;0;Nb;1)));Liste;GAUCHE(STXT(Marquage;TROUVE("¯";Marquage)+1;NBCAR(Chaîne));TROUVE("¯";STXT(Marquage;TROUVE("¯";Marquage)+1;NBCAR(Chaîne))&"¯")-1);SI(NBCAR(Liste)>3;NOMPROPRE(Liste);Liste)))

Voir l'exemple en pièce jointe

 

[chingilou]

merci de la réponse rapide mais SUPPRESPACE ne retire pas les ligne vides à la fin du texte par exemple chez moi en tous cas
pour la formule je teste et je te réponderai merci en tout cas

 

[mapomme]

merci de la réponse rapide mais SUPPRESPACE ne retire pas les ligne vides à la fin du texte par exemple chez moi en tous cas

Tiens je croyais qu'un fichier exemple était inutile...

 

[AtTheOne]

Re @chingilou

merci de la réponse rapide mais SUPPRESPACE ne retire pas les ligne vides à la fin du texte

J'ai du mal comprendre ta demande, je traite le texte ligne à ligne

 

[AtTheOne]

Effectivement @mapomme avec un exemple on patine moins dans la choucroute !

 

[chingilou]

une cellule peut contenir un texte à plusieurs lignes j'importe ces textes pour les traiter et ca serai bien d'automatiser le traitement
c'est vrai que je dois donner un fichier exemple désolé mapomme désole

merci pour la formule attheone parfaite

 

[chingilou]

en fin de compte SUPPRESPACE fais son travail je ne sais pas pourquoi j'avais un texte ou la derniere ligne vide du texte était resté
donc les noctambules

[SIZE=4]AtTheOne[/SIZE] et mapomme merci énormément​

solution trouvé donc sujet clos

 

[mapomme]

Re,

Avant de me coucher, une formule assez courte qui doit faire le travail (et qui était prête 😜)
Avec l'exemple de @AtTheOne :

=LET(tablo;FRACTIONNER.TEXTE([@[Texte Brut]];" ");SIERREUR(JOINDRE.TEXTE(" ";VRAI;SI(NBCAR(tablo)>3;NOMPROPRE(tablo);tablo));""))

Allez bonne nuit à tous.

 

[chingilou]

re-MERCI encore
j'utilisais moi ca

=SUPPRESPACE(NOMPROPRE(SUBSTITUE(SUBSTITUE(EPURAGE(B10);CAR(10)&CAR(13);" "); CAR(160);" ")))

pour les lignes vides que j'avais remarqués mais ca me donnais pas le résultat voulu

 

[AtTheOne]

L'inconvénient de la fonction EPURAGE (que j'avais pensé à utiliser) c'est qu'elle supprime carrément tous les caractères de contrôle donc on n'a plus de séparateur entre le dernier mot de la ligne n et le premier mot de la ligne non vide qui suit ...

 

[chingilou]

c'est ce que j'avais c'est pour ça que j'ai abondonné je connaisais pas ça de cette fonction (vilaine fonction😀) merci allez dormez les gars je vous ai assez retenue bonne nuit