XL 2013 tirer une formule avec saut de plage de lignes

[sergio545]

Bonjour

Je dispose d'un tableau de ce type dans la colonne A

1
2
3
4
5
6
7
8
9

Dans la colonne B, je souhaite calculer des sommes sur une plage de 3 cellules : je souhaite écrire dans la case B1 =SOMME(A1:A3), dans la case B2 = SOMME(A4:A6), dans la case B3=SOMME(A7:A9)

Donc faire le calcul en décalant de 3 lignes à chaque fois, et en tirant avec la poignée évidement j'ai SOMME(A1,A3) en B1, SOMME(A2,A4) en B2...

J'ai essayé d'utiliser la fonctionner décaler mais je n'y arrive pas.

Auriez-vous une idée ? Si le code est complexe, pourriez vous me l'expliquer ?

D'avance merci

 

[Hasco]

Bonjour,

En partant de B2 avec décaler:

=SOMME(DECALER($A$1:$A$3;(LIGNE()-2)*3;0;3))

Cordialement

 

[TooFatBoy]

Bonjour,

J'ai essayé d'utiliser la fonction décaler mais je n'y arrive pas.

Pourtant l'idée du DECALER me semblait être bonne.

As-tu essayé avec quelque chose dans ce genre :
=SOMME(DECALER(A$1:A$3;3*(LIGNE()-1);0))

 

[Hasco]

Re,

N'est-ce pas la même chose que

=SOMME(DECALER($A$1:$A$3;(LIGNE()-2)*3;0;3))

A part que l'ami sergio545 commence en ligne 2.
Cordialement

 

[Victor21]

Bonsoir à tous.

En partant de B1 :

=SOMME(INDIRECT("a"&LIGNE(A1)*3-2):INDIRECT("a"&LIGNE(A1)*3))

 

[TooFatBoy]

Re,

N'est-ce pas la même chose que
=SOMME(DECALER($A$1:$A$3;(LIGNE()-2)*3;0;3))
A part que l'ami sergio545 commence en ligne 2.
Cordialement

Si, ça se ressemble beaucoup.


Mais quand j'ai lu sa question je n'ai pas eu l'impression qu'il commençait en ligne 2 :

je souhaite écrire dans la case B1 =SOMME(A1:A3), dans la case B2 = SOMME(A4:A6), dans la case B3=SOMME(A7:A9)

Désolé si je me suis trompé. 😞

 

[sergio545]

Merci à tous pour votre réponse, ça fonctionne!

J'avais effectivement mal formulé ma question, je commence en B2.

Pourriez vous m'expliquer la fin de la formule : (LIGNE()-2)*3;0;3))

Merci!

 

[Hasco]

Bonjour,

La fonction Ligne() sans argument renvoie le numéro de ligne de la cellule dans laquelle la fonction se trouve.
Ligne() en ligne 2 = 2 en ligne 3 = 3 etc...
On veut décaler "A1:A3" d'un multiple de 3 à chaque fois
La première fois de 0 ligne plus loin (A1:A3) ne bougera pas. Donc (Ligne()-2)*3 donner 0 sur la ligne
3 ça fera 1*3 donc 3ème ligne plus bas
les deux autres arguments sont là pour dire à la fonction décaler qu'on ne veut pas de décalage de colonne (0) et qu'on veut une plage d'une hauteur de 3 lignes (3)

Cordialement

 

[TooFatBoy]

qu'on veut une plage d'une hauteur de 3 lignes (3)

Chose que l'on peut ne pas indiquer vu que la plage d'origine fait déjà 3 lignes. 😉

 

[Hasco]

Chose que l'on peut ne pas indiquer vu que la plage d'origine fait déjà 3 lignes

Tout à fait mais que je préfère indiquer pour information et compréhension à la lecture ultérieure (6 mois, un an, deux ans...) de la formule. Trop eu souvent à faire à des formules dont il fallait refaire tout le chemin pour les appréhender et les comprendre après un certain temps. Comme en vba, ma règle est d'en dire trop que pas assez. 🙂

Cordialement

 

[sergio545]

Merci pour votre réactivité et pour les explications.