Test sur le nom éventuel d'une cellule

[BenHarber]

Bonjour le Forum,
Je souhaiterais trouver le code VBA qui me permette de tester si une cellule (disons la cellule active) porte un nom ou pas.

Avez-vous une idée ?

Merci d'avance pour vos idées et suggestions qui me dépannent régulièrement !

BH

 

[job75]

Re : Test sur le nom éventuel d'une cellule

Bonjour BenHarber,

Par exemple :

Dim c As Range, x$
Set c = ActiveCell 'pour tester
x = ""
On Error Resume Next
x = c.Name.Name
MsgBox "Cellule " & c.Address(0, 0) & IIf(x = "", " sans nom", " nommée '" & x & "'")

A+

 

[job75]

Re : Test sur le nom éventuel d'une cellule

Re,

On peut étendre le problème à l'appartenance à une plage nommée :

Dim c As Range, flag As Boolean, nom As Name
Set c = ActiveCell 'pour tester
flag = False
For Each nom In ThisWorkbook.Names
  If TypeName(Evaluate(nom.Name)) = "Range" Then
    If Evaluate(nom.Name).Parent.Name = c.Parent.Name Then
      If Not Intersect(c, Evaluate(nom.Name)) Is Nothing Then
        flag = True
        MsgBox c.Address(0, 0) & IIf(Evaluate(nom.Name).Count > 1, " appartient à la plage nommée '", " est nommée '") & nom.Name & "'"
      End If
    End If
  End If
Next
If Not flag Then MsgBox c.Address(0, 0) & " n'appartient à aucune plage nommée"

A+

 

[BenHarber]

Re : Test sur le nom éventuel d'une cellule

Bonjour Job75
Ben voilà : c'est exactement ce que je ne parvenais pas à écrire !
(c'est le c.Name.Name que je ne comprends pas vraiment)

Merci beaucoup pour ces lignes.

@+

BenHarber

 

[job75]

Re : Test sur le nom éventuel d'une cellule

Bonjour BenHarber,

(c'est le c.Name.Name que je ne comprends pas vraiment)

Quand c est une cellule nommée c.Name renvoie un objet de la collection ThisWorkbook.Names.

Et c.Name.Name donne alors son nom.

Si la cellule n'est pas nommée c.Name crée une erreur et x n'est pas recalculé.

A+

 

[BenHarber]

Re : Test sur le nom éventuel d'une cellule

OK, job75 : je me coucherai moins bête ce soir... 🙂
Merci pour ces explications.
@+
BH