tempo fermeture excel

[jv]

Bonjour à tous,
je cherche le moyen de fermer excel après une tempo de quelques minutes.

Effectivement, j'ai concu une appli pour une entreprise, utilisée par l'ensemble du personnel. Le problème est que certaine personne ne pense pas à fermer l'appli après l'avoir utilisée donc je voudrais que l'application se ferme automatiquement après un certain temps d'execution car il ne m'est pas possible de savoir quel poste utilise le logiciel.

Merci de vos suggestion.

JV

 

[Jon]

bonjour

regarde les méthodes ontime et wait par exemple
pour des exemples, regarde les anc messages ou par exemple le lien suivant :
<http://xlbysteph.free.fr/aideinformatique/actionvba2.htm>

ou fais la contrôle la différence entre l'heure à un moment donné et l'heure d'ouverture du fichier que tu auras préalabelment sotcké dans uen variable.

bye

 

[@+Thierry]

Salut STéphane, JV, le Forum,


On avait eu la même question par Christophe sur le Forum... Ti m'avait repris pour trouver la solution...

Dans le Private Module de ThisWorkBook

Option Explicit

Private Sub Workbook_BeforeClose(Cancel As Boolean)
ScheduleOff
End Sub

Private Sub Workbook_Open()
Timing
End Sub

Private Sub Workbook_SheetCalculate(ByVal Sh As Object)
LastChange = Now
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
LastChange = Now
End Sub


Dans un Module Standard

Option Explicit
Option Private Module
'@+Thierry et Ti 27-12-02

Public LastChange
Dim Fin

Sub Timing(Optional Heure)
If IsMissing(Heure) Then Heure = Now
Fin = Heure + TimeValue("00:15:05")
Application.OnTime Fin, "Alerte"
End Sub

Sub Alerte()
Dim DiffTime
DiffTime = Now - LastChange
If Minute(DiffTime) = 15 Then
'MsgBox "veuillez sauver et quitter l'application"
'Application.OnTime Now + TimeValue("00:00:10"), "Quitte"
Quitte

Else
Timing LastChange
End If
End Sub

Sub ScheduleOff()
On Error Resume Next
Application.OnTime EarliestTime:=Fin, Procedure:="Alerte", _
LatestTime:=Fin + TimeValue("00:00:01"), schedule:=False
On Error GoTo 0
End Sub

Private Sub Quitte()
ThisWorkbook.Close True
End Sub

Si celà peut te servir...

Bon Aprèm
@+Thierry