Tableau de données sur excel

[laika25]

Bonjour,
je souhaite obtenir de l'aide sur le sujet suivant:

Tableau excel initial
en colonnes, il y a les n° de semaines
en lignes les n° des machines
aux intersections les types d'articles fabriqués.

la modification rapide que je souhaite faire afin d'obtenir un 2ème tableau sur une autre feuille excel est la suivante

en colonnes,laisser les n° de semaines
en lignes positionner les types d'articles fabriqués
aux intersections retrouver les n° de machines fabricantes

merci de m'apporter de l'aide( fonction recherche ou macro)

Cordialement

 

[david84]

Re : Tableau de données sur excel

Bonjour,
Sans fichier exemple comme demandé lors de l'ouverture de la discussion, difficile de t'aider.
Peut-être utiliser une fonction du type recherche.v ou index+equiv.
A+

 

[laika25]

Re : Tableau de données sur excel

Tableau initial
S1 S2 .. Sn
M1 a1 a1 … a1
M2 a2 a3 … a5
M3 a3 a3 a4
..
Mn a3 … … a4



Tableau cible

S1 S2 .. Sn
a1 M1 M1 … M1
a2 M2 vide … vide
a3 M3 M2 .. vide
a3 vide M3 … vide
a4 vide vide … M3
a4 vide vide … Mn
a5 vide vide … M2



voila le type de manip à effectuer en auto

merci pour ta dispo

 

[laika25]

Re : Tableau de données sur excel

il faut décaler les semaines d'in cran S1 au dessus de M1 etc...

 

[david84]

Re : Tableau de données sur excel

Re
je crois qu'on ne s'est pas compris : pour t'apporter une réponse adaptée il te faut placer un exemple explicite sur un fichier Excel. C'est à toi de le faire pour qu'il n'y ait pas d’ambiguïté. Place manuellement les résultats attendus avec les explications qui nous permettrons de comprendre ta demande.
Pour cela aller en mode avancé=> gérer les pièces jointes=>parcourir=>sélectionner ton fichier=>envoyer=envoyer la réponse.
A+

 

[laika25]

Re : Tableau de données sur excel

merci David pour ta rapidité de réponse.
j'enverrai un fichier demain car ce soir je n'ai plus le temps
encore merci

à bientôt

 

[Hippolite]

Re : Tableau de données sur excel

Bonjour à tous,
Données en Feuil1 début du tableau en A1, résultats en Feuil2
Peut être placé dans un module :

Public Sub Tableau()
    Dim i As Long, j As Long, Dlgn As Long, Dcol As Long, c As Range
    Dim a, b, Mondico, Mdc
    Application.ScreenUpdating = False
    Dlgn = Sheets("Feuil1").Cells(Rows.Count, 1).End(xlUp).Row
    Dcol = Sheets("Feuil1").Cells(1, Columns.Count).End(xlToLeft).Column
    'Effacement de la feuille 2
    Feuil2.UsedRange.Clear
    'Report des semaines
    Sheets("Feuil1").Rows(1).Copy Destination:=Sheets("Feuil2").Rows(1)
    'Création de la listevdes articles
    Set Mondico = CreateObject("Scripting.Dictionary")
    a = Sheets("Feuil1").Range("B2", Sheets("Feuil1").Cells(Dlgn, Dcol).Address).Value
    For Each b In a
        Mondico(b) = b
    Next b
    Mdc = Mondico.Count
    With Sheets("Feuil2")
        .Cells(2, 1).Resize(Mondico.Count, 1) = Application.Transpose(Mondico.keys)
        'Tri de la liste des articles
        Call Tri(.Range("A1:A" & Mdc), 1, Mdc)
        'Remplissage du tableau par les machines
        For i = 2 To Dlgn
            For j = 2 To Dcol
                With .Range("A2:A" & Mdc)
                    Set c = .Find(Sheets("Feuil1").Cells(i, j), LookIn:=xlValues)
                    If Not c Is Nothing Then
                        c.Offset(, j - 1) = c.Offset(, j - 1) & ", " & Sheets("Feuil1").Cells(i, 1)
                    End If
                End With
            Next j
        Next i
        For i = 2 To Mdc    'suppression des premières virgules
            For j = 2 To Dcol
                .Cells(i, j) = Mid(.Cells(i, j), 2)
            Next j
        Next i
    End With
    Application.ScreenUpdating = True
    Set c = Nothing
End Sub

Sub Tri(a, gauc, droi)    ' Tri rapide
    ref = a((gauc + droi) \ 2)
    g = gauc: d = droi
    Do
        Do While a(g) < ref: g = g + 1: Loop
        Do While ref < a(d): d = d - 1: Loop
        If g <= d Then
            temp = a(g): a(g) = a(d): a(d) = temp
            g = g + 1: d = d - 1
        End If
    Loop While g <= d
    If g < droi Then Call Tri(a, g, droi)
    If gauc < d Then Call Tri(a, gauc, d)
End Sub

A+

 

[laika25]

Re : Tableau de données sur excel

Bonsoir et merci beaucoup

 

[laika25]

Re : Tableau de données sur excel

Re
je crois qu'on ne s'est pas compris : pour t'apporter une réponse adaptée il te faut placer un exemple explicite sur un fichier Excel. C'est à toi de le faire pour qu'il n'y ait pas d’ambiguïté. Place manuellement les résultats attendus avec les explications qui nous permettrons de comprendre ta demande.
Pour cela aller en mode avancé=> gérer les pièces jointes=>parcourir=>sélectionner ton fichier=>envoyer=envoyer la réponse.
A+

Bonsoir

je fais parvenir le fichier

merci beaucoup

 

[Hippolite]

Re : Tableau de données sur excel

Re,
J'ai ajouté un fichier au post #7
A+

 

[laika25]

Re : Tableau de données sur excel

Re,
J'ai ajouté un fichier au post #7
A+

Bonjour Hippolite

cela signifie quoi?

merci

 

[laika25]

Re : Tableau de données sur excel

Bonjour Hippolite

cela signifie quoi?

merci

Merci Hippolite j'ai trouvé le fichier c'est super
merci beaucoup

Cordialement