SVP confirmation : rechercheV et valeur arrondie supérieure

M

Monique

Nous a quitté

Repose en paix

• 12 Mai 2009

• #2

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

Fais un essai comme ça :

=INDEX(F13:F23;EQUIV(C7-1/10000;E13:E23;1)+1)

 

Vote positif 0 Vote négatif

J

ju_fra

XLDnaute Nouveau

• 13 Mai 2009

• #3

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Ralala merci bcp !!!

En plus, cette fonction dépasse largement la mienne, puisque la mienne ne fonctionnait qu'a condition que la valeur a rapporter ne soit incrementée que de maniere simple (+1 ou +2 ... )


Vraiment merci !

Maintenant ... il faut que je comprenne le sens de votre formule ( sa logique )

 

Vote positif 0 Vote négatif

J

ju_fra

XLDnaute Nouveau

• 13 Mai 2009

• #4

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Compris !

remarquez que cette formule ne fonctionne qu'a la condition que la premiere colonne soit classée dans l'ordre croissant ( puisque vous programmé un +1, qui dit en fait rajouter 1 au numéro de colonne renvoyé par equiv).

Ca fonctionne dans mon cas, c'est tres bien et je vous remercie, mais mon esprit de "doctrinisateur" me pousse a vous demander s'il existe une formule qui renvoie la valeur sans que le tableau soit classé !

merci par avance !

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 13 Mai 2009

• #5

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonsoir ju fra,

Monique a du aller faire dodo.

Cette formule fonctionne même si la colonne E n'est pas classée :

Code:

=INDEX(F13:F23;EQUIV(MIN(SI(E13:E23>=C7;E13:E23));E13:E23;0))

Formule matricielle à valider par Ctrl+Maj+Entrée.

Edit : elle fonctionne même si des valeurs alpha sont intercalées parmi les valeurs numériques ou s'il y a des cellules vides, car on utilise l'argument 0 dans EQUIV.

A+

 

Dernière édition: 13 Mai 2009

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 13 Mai 2009

• #6

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

A essayer :

Code:

[FONT=Verdana]=MIN(SI(E13:E23>=C7;F13:F23))[/FONT]

Formule matricielle, à valider par ctrl, maj et entrée

 

Vote positif 0 Vote négatif

J

ju_fra

XLDnaute Nouveau

• 13 Mai 2009

• #7

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Merci a vous, effectivement cela fonctionne.

C'est dommage que l'on ne puisse pas parametrer "rechercheV" plus simplement.

 

Vote positif 0 Vote négatif

T

tibj26

Guest

• 18 Novembre 2011

• #8

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

bonjour,

Je me permet de relancer ce post, car avec mes connaissances limitées sur excel, je n'arrive pas à appliquer ces formules, de manière à obtenir le resultat voulu.
J'ai cherché partout depuis un bon moment sans comprendre.

Le probleme c'est l'incapacité de la fonction recherchev à trouver une valeur supérieure directement, dommage.
Voici mon probleme, c'est peut etre simple mais...

Le plus simple est que je joigne un fichier, non?

La fonction recherche me donne dans le cas, les mauvais resultats car ne se fixe pas sur le seuil le plus haut.

merci beaucoup!!!

 

Pièces jointes

• essai recherche.xlsx

  12.5 KB · Affichages: 203
• essai recherche.xlsx

  12.5 KB · Affichages: 236
• essai recherche.xlsx

  12.5 KB · Affichages: 251

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 18 Novembre 2011

• #9

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour tibj26,

Comme les températures en colonne A ont un pas de 0,5 °C utiliser la fonction PLAFOND :

Code:

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;1;VRAI)

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;2;VRAI)

qu'on peut d'ailleurs résumer en une seule formule en F3 :

Code:

=RECHERCHEV(PLAFOND(E3;1/2);$A$2:$B$31;COLONNES($F:F);VRAI)

à tirer à droite et vers le bas.

A+

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 18 Novembre 2011

• #10

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Re,

Bon OK, en A2 et A3 il y a 0 et 15...

Donc si en colonne E il y a des températures < 15 °C, mettre en F3 la formule :

Code:

=RECHERCHEV(PLAFOND(E3;SI(E3<15;15;1/2));$A$2:$B$31;COLONNES($F:F);VRAI)

A+

 

Vote positif 0 Vote négatif

H

hoerwind

XLDnaute Barbatruc

• 18 Novembre 2011

• #11

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour, salut job,

Il y a aussi en G3, formule à copier vers le bas :

Code:

=RECHERCHEV(E3+4/10;A$1:B$31;2;1)

4/10 pouvant être remplacé par 0.4 ou 0,4 suivant le type de séparateur décimal

 

Vote positif 0 Vote négatif

T

tibj26

Guest

• 19 Novembre 2011

• #12

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

bonjour.

Génial j'ai adapaté tres légèrement à mon cas reel et ca marche nickel.

Merci à vous, et en plus super réactifs!

bye

 

Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 19 Novembre 2011

• #13

Re : SVP confirmation : rechercheV et valeur arrondie supérieure

Bonjour,

Si les valeurs de température sont 'rangées' de manière aléatoire, on peut essayer cette formule matricielle en G3:
=INDEX($B$2:$B$31;(EQUIV(MIN(SI($A$2:$A$31-E3>=0;$A$2:$A$31-E3;""));$A$2:$A$31-E3;0)))

Cette formule est une formule matricielle. Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique. Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}. Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

Dernière édition: 19 Novembre 2011

Vote positif 0 Vote négatif