Supprimer Ligne avec condition

[Niouf]

Salut les gars,

Dites moi, j'essaye de supprimer une ligne entire sous deux conditions :

- Premiere condition, je scanne la premiere colonne, et je supprime la ligne a chaque fois que la cellule corrspondante commence par un R

- Deuxieme condition, je scanne encore cette premiere colonne, et je supprime la ligne a chaque fois aue la cellule correspondante ne commence pas par une letter

J'ai a peu pret reussi pour la premiere, mais je seche pour la deuxieme, voir fichier ci joint 🙂

En esperant avoir ete clair ...

 

[DoubleZero]

Re : Supprimer Ligne avec condition

Bonjour à toutes et à tous,

Salut les gars...

Misogyne ?

Comme ceci ?

Option Explicit
Sub Ligne_supprimer_selon()
    Dim c As Range, i As Long
    With Application: .ScreenUpdating = False: .Calculation = xlManual: .EnableEvents = False: End With
    For i = Cells(Rows.Count, "a").End(xlUp).Row To 2 Step -1
        If Left(Range("a" & i), 1) = "R" Or IsNumeric(Range("a" & i)) Then Rows(i).Delete
    Next
    With Application: .EnableEvents = True: .Calculation = xlAutomatic: .ScreenUpdating = True: End With
End Sub

 

[roro69]

Re : Supprimer Ligne avec condition

Bonjour
Peut etre comme ceci

Sub Test()
Dim Cel, rgNom As Range
Set rgNom = Sheet1.Range("A2", Sheet1.Range("A65536").End(xlUp))
For Each Cel In rgNom
If Left(Cel(1, 1), 1) = "R" Or IsNumeric(Left(Cel(1, 1), 1)) Then Cel.EntireRow.Delete
Next Cel
End Sub

A++

 

[Dranreb]

Re : Supprimer Ligne avec condition

Bonjour.

Ma version :

Sub Test()
LignesOùCondR1C1(Rows(2), "UPPER(LEFT(RC1,1))=""R""").Delete
LignesOùCondR1C1(Rows(2), "EXACT(UPPER(LEFT(RC1,1)),LOWER(LEFT(RC1,1)))").Delete
End Sub

Function LignesOùCondR1C1(ByVal LigneDéb As Range, ByVal CondR1C1 As String) As Range
Rem. ——— Lignes entières partant de LigneDéb qui vérifient une condition R1C1 CondR1C1.
Dim Lignes As Range, ColTrv As Range
With LigneDéb.Worksheet.UsedRange
   Set Lignes = LigneDéb.EntireRow.Resize(.Rows.Count + .Row - LigneDéb.Row)
   Set ColTrv = Intersect(.Columns(.Columns.Count + 1), Lignes): End With
ColTrv.FormulaR1C1 = "=1/(" & CondR1C1 & ")"
On Error Resume Next
Set LignesOùCondR1C1 = ColTrv.SpecialCells(xlCellTypeFormulas, 1).EntireRow
ColTrv.Delete xlShiftToLeft
End Function

 

[Niouf]

Re : Supprimer Ligne avec condition

Merci a tous, j'ai pris une de vos solutions et ca fonctionne nickel 🙂