XL 2019 Supprimer les doublons si la date est la meme VBA

[Jackdu95]

Bonjour,

J'aimerais supprimer les doublons de la colonne B si dans la colonne A j'ai la meme date. Le resultat est en colonne H et I.
Tout ca avec un macro en VBA.
Sachant que la date en colonne A peut decendre tres loin par exemple jusqu'à aujourd'hui avec pour chaque date plusieurs lignes.

Merci

Jack

 

[cp4]

Bonjour,

Code à mettre dans un module standard.

Option Explicit

Sub supprimer_doublon()
    Dim tb, i As Long, d As Object
    Set d = CreateObject("scripting.dictionary")
    With Feuil1 ' à adapter'
        .Range("o:p").ClearContents 'à adapter'
        tb = .Range("a1").CurrentRegion
        For i = 1 To UBound(tb)
            d(tb(i, 1) & "|" & tb(i, 2)) = ""
        Next i
        ''''
        .[O1].Resize(d.Count) = Application.Transpose(d.Keys)    'report sur la feuille à adapter
        'éclater colonne 1 en plusieurs suivant delimiteur choisi ("|")
        .Range("O:O").TextToColumns DataType:=xlDelimited, Other:=True, OtherChar:="|"    ' à adapter
    End With
End Sub

 

[mapomme]

Bonsoir à tous,
Une autre manière de faire:
Code dans le module de la feuille "Feuil1" :

Sub SupprDoublon()
   Range("a:b").Copy Range("h:i")
   Range("h:i").CurrentRegion.RemoveDuplicates Array(1, 2), xlNo
End Sub

edit: bonsoir @cp4

 

[Jackdu95]

Merci beaucoup a vous deux.