supprimer des lignes vides

[Fabien]

Bonjour,

J'ai un tableau qui fait 4000 lignes dont X qui sont vides...
Existe t'il un moyen pour supprimer les lignes vides en une seule fois

Merci pour votre aide et votre promptitude

Fabien

 

[CHti160]

Salut"Fabien"
oui tu peux via une macro ,tu la colles dans le module de ta feuille
ex
Sub SupprimeRow()
Dim DerLgn As Integer ' défini la variable voir Integer
Dim Lgn As Integer 'défini la variable
Application.ScreenUpdating = False ' annule le défilement à l'écran
With ActiveSheet 'pour la feuille active ou mettre With Sheets("nom de la feuille")
DerLgn = .Range("A65536").End(xlUp).Row 'Renvoi la dernière ligne utilisée
'de la colonne A si A est la colonne ou tu peux déterminer la plus Grande Valeur de ligne à traiter
End With
For Lgn = DerLgn To 2 Step -1 'on part du bas
If Cells(Lgn, 1).Value = "" Then ' si la cellule est vide
Cells(Lgn, 1).EntireRow.Select ' la ligne est selectionnée
Selection.EntireRow.Delete Shift:=xlUp 'La ligne entière est supprimée par le Haut
End If
Next
Range("A1").Select
Application.ScreenUpdating = True 'réactive le défilement
End Sub
A+++
Jean Marie

 

[CHti160]

RE "Fabien"
on peut aussi alèger en raccourcisant le code et le nombre de select
en mettant
For Lgn = DerLgn To 2 Step -1 'on part du bas
If Cells(Lgn, 1).Value = "" Then ' si la cellule est vide
Cells(Lgn, 1).EntireRow.Delete Shift:=xlUp ' la ligne de la cellule détectée est Supprimée
End If
Next
A+++
Jean Marie

 

[CHti160]

re re Fabien" une autre version Adapter
car dans un test sur une colonne des cellules peuvent être vide sans que la ligne complète soit vide. donc cette version
determine la plage à tester puis dans cette plage, vérifie que les cellules vides font parties ,d'une ligne entièrement vide avant suppression
Sub SuppLgnEntireVide()

Application.ScreenUpdating = False

Dim NbreLgn As Long
Dim NuLgn As Long
Dim DerLgn As Integer
Dim DerCol As Integer
Dim maplage As Range
With Sheets("Feuil1")
DerLgn = .Range("A65536").End(xlUp).Row
DerCol = .Range("IV1").End(xlToLeft).Column
Set maplage = .Range(Cells(1, 1), Cells(DerLgn, DerCol))
End With
maplage.Select 'selection de la plge pour teste des cellule vides
NbreLgn = maplage.Rows.Count

With Selection
For NuLgn = NbreLgn To 1 Step -1
If Application.CountA(.Rows(NuLgn)) = 0 Then _
.Cells(NuLgn, 1).EntireRow.Delete
Next NuLgn
End With
Range("A1").Select
Application.ScreenUpdating = True

End Sub[/b]
A+++
Jean Marie

 

[tom]

Bonjour,

j'utilise plutôt celle-ci:

Sub RemoveEmptyRows()
Application.ScreenUpdating = False 'xlManual below in Xl95
Application.Calculation = xlCalculationManual
Dim rw As Long, iCol As Long
For rw = ActiveSheet.UsedRange.Rows.Count To 1 Step -1
If Application.CountA(Rows(rw).EntireRow) = 0 Then _
Rows(rw).Delete
Next
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True 'xlAutomatic above in xl95
End Sub

cela vient du lien

http://www.mvps.org/dmcritchie/excel/delempty.htm


excellent pour tout ce qui est fonction "delete".....


bye

Tom

 

[@+Thierry]

Bonjour Jean Marie, Tom, Fabien

Dans un autre style, toujours plus "short" lol

Sub CLEAN()
Sheets("Feuil1").Columns(1).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub


On peut voir ce fil pour Lien supprimé

Bonne Journée
@+Thierry