Suppression ligne, macro inefficace

[britchouleloup]

Bonjour,
J'exporte depuis un logiciel comptable des données sur Excel. Je dois les retraiter, notamment supprimer des lignes vides et des contenant certain caractère.

J'ai créé mes petites macro, mais je ne trouve pas la solution. Une pour supprimer les lignes dont la cellule en "E" ne contient pas "MIG", l'autre est censée supprimer toutes les vides. Mais elle ne marche pas completement, je dois répéter l'action plusieurs fois pour toutes les avoir.

Je joins un petit fichier qui illustrera bien mon propos.


Quelqu'un pourrait-il m'aider, et me commenter mon (mes) erreur(s). Merci beaucoup par avance

 

[Cousinhub]

Re : Suppression ligne, macro inefficace

Bonsoir,

les 2 en 1

A partir d'un code de JB

Si tu n'as rien dans la cellule E5
Si tu as quelque chose, supprime .Value... et .ClearContents

Sub supp()
    With [E5]
        .Value = "MIG"
        .AutoFilter Field:=5, Criteria1:="<>MIG"
        Range("_FilterDataBase").Offset(1, 0).Resize(Range("_FilterDataBase"). _
            Rows.Count - 1).SpecialCells(xlCellTypeVisible).Delete Shift:=xlUp
        .AutoFilter
        .ClearContents
    End With
End Sub

 

[mromain]

Re : Suppression ligne, macro inefficace

Bonsoir le forum,

bonsoir Bhbh. Ta macro est tombée sur une boucle sans fin avec mon PC.

bonsoir Britchoulelou, je te propose ça

Public Sub toto()
With ActiveSheet
Dim i As Integer
toto:
For i = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
    If (.Range("E" & i).Value <> "MIG") Then
        Rows(i).Delete
        GoTo toto
    End If
Next
End With
End Sub

Bonne soirée

 

[Cousinhub]

Re : Suppression ligne, macro inefficace

Re-,

En boucle?

essaie le fichier joint

Pour ton code, une suppression de ligne se fait de bas en haut, et ne connaissant pas le nombre de lignes, il vaut mieux mettre i en Long :

Public Sub toto()
With ActiveSheet
Dim i As Long
For i = .Cells(.Rows.Count, 1).End(xlUp).Row To 6 Step -1
    If (.Range("E" & i).Value <> "MIG") Then
        Rows(i).Delete
    End If
Next
End With
End Sub

 

[mromain]

Re : Suppression ligne, macro inefficace

Pour ton code, une suppression de ligne se fait de bas en haut, et ne connaissant pas le nombre de lignes, il vaut mieux mettre i en Long

C'est vraiment pas bête, c'est vrai qu'avec de haut en bas, j'étais em**** quand je supprimais une ligne (du coup, j'analyse pas la deuxième...).

mais je ne connaissais pas le "Step" (très utile pour le coup)

Une fois de plus, je remercie ce magnifique forum, où on apprend des choses à chaque clic...


Bonne nuit à tous

 

[britchouleloup]

Re : Suppression ligne, macro inefficace

merci beaucoup de votre aide. Et comme dit romain merci aussi à tous les forumeurs qui apportent une aide précieuse (pas besoin de poster beaucoup de message pour avoir des réponses, suffit de chercher un peu, pour le coup j'avais vraiment pas trouvé de réponse.)

Merci