suppression de lignes avec critère par vba

[philmaure]

bonjour comment supprimer des lignes d'un onglet à partir d'un critère ?

sur mon fichier exemple je souhaite supprimer les lignes dont la valeur test est TSP.

Merci pour votre aide
Cdlt
philippe

 

[DoubleZero]

Re : suppression de lignes avec critère par vba

Bonjour, philmaure, le Forum,

Une suggestion avec ce code, placé dans un module :

Option Explicit
Sub Ligne_supprimer_si()
    Dim i As Long
    Application.ScreenUpdating = False
    For i = Cells(Rows.Count, "d").End(xlUp).Row To 1 Step -1
        If Range("d" & i) = "tsp" Then Rows(i).Delete
    Next i
    Application.ScreenUpdating = True
End Sub

A bientôt 🙂

 

[Staple1600]

Re : suppression de lignes avec critère par vba

Bonjour à tous, 00 😉

Une autre suggestion sans boucle utilisant le filtre automatique
(test ok sur ton fichier exemple)

Sub Macro1()
Dim a As Range, b As Range
Set a = Range(Cells(1, "A"), Cells(Rows.Count, "D").End(xlUp))
Application.ScreenUpdating = False
On Error Resume Next
a.AutoFilter 4, "tsp"
Set b = [_FilterDataBase]
b.Offset(1, 0).Resize(b.Rows.Count - 1).SpecialCells(xlCellTypeVisible).Delete Shift:=xlUp
ActiveSheet.AutoFilterMode = False
End Sub

 

[philmaure]

Re : suppression de lignes avec critère par vba

Bonjour
Un grand merci. Ca fontionne comme je le souhaitais

bonne journée
Cdlt
Philippe