Suppression chaînes de caractère ".( )" dans une série d'emails

[xlsduzero]

Bonjour,

Je veux passer de ça "jean-noël.attard.(chefdesecteur)@yahoo.fr" saisi dans une cellule A1,
à ça : "jean.noel.attard@yahoo.fr", autrement dit une adresse email valide. Le problème c'est que j'en ai une tripotée.

Les règles de gestion sont :
-remplacer le "-" par un "."
-supprimer le ".(chefdesecteur)"
-supprimer les accents sur le "e"

Merci pour votre aide précieuse si vous pouvez m'aider à construire une formule.

 

[R@chid]

Re : Suppression chaînes de caractère ".( )" dans une série d'emails

Bonsoir et Bienvenu sur XLD,
essayer en C2,

=SUBSTITUE(SUBSTITUE(SUBSTITUE(B2;"ë";"e");"-";".");STXT(B2;TROUVE(".(";B2);TROUVE("@";B2)-TROUVE(".(";B2));"")

@ +

 

[job75]

Re : Suppression chaînes de caractère ".( )" dans une série d'emails

Bonjour xlsduzero, R@chid,

En utilisant REMPLACER :

=REMPLACER(SUBSTITUE(SUBSTITUE(A1;"é";"e");"-";".");TROUVE(".(";A1&".(");TROUVE(")";A1&")")-TROUVE(".(";A1&".(")+1;"")

Fonctionne même s'il n'y a pas de texte entre parenthèses.

Edit : dans la formule remplacez é par ë ce sera quand même mieux 🙄

A+

 

[job75]

Re : Suppression chaînes de caractère ".( )" dans une série d'emails

Re,

Plus compliqué, qu'il y ait ou non un point devant la 1ère parenthèse :

=SUBSTITUE(SUBSTITUE(REMPLACER(SUBSTITUE(SUBSTITUE(A1;"é";"e");"-";".");TROUVE("(";A1&"(");TROUVE(")";A1&")")-TROUVE("(";A1&"(")+1;"");".@";"@");"..";".")

Fichier joint.

Edit : dans la formule remplacez é par ë ce sera quand même mieux 🙄

A+

 

[job75]

Re : Suppression chaînes de caractère ".( )" dans une série d'emails

Re,

Les formules précédentes ôtaient uniquement l'accent aigu sur le é.

Sur Excel 2003 le nombre de niveaux d'imbrication est limité à 8.

Ce n'est pas le cas sur Excel 2007/2010 :

=SUBSTITUE(SUBSTITUE(REMPLACER(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(SUBSTITUE(A1;"é";"e");"è";"e");"ê";"e");"ë";"e");"-";".");TROUVE("(";A1&"(");TROUVE(")";A1&")")-TROUVE("(";A1&"(")+1;"");".@";"@");"..";".")

Fichier (2) en .xlsx.

Edit : je joins aussi le fichier .xls car il n'y a que 8 niveaux d'imbrication...

A+