Microsoft 365 sumproduct et subtotal avec filtre

[almourasel]

Salut les amis

j essaye d avoir résultat de totale d un matrice suite au filtre pour avoir a la fin le totale des heures a produire suite au filtre du tableau:

ceci la formule de sum demandé.

=SUMPRODUCT($I$2:$I$14;K2:K14)

le problème quand je filtre par "Drawing , Ligne 2 " par example il ne me change pas le totale des heures a produire.
comment avoir sumproduct relié avec subtotale et varie selon lun filtre.

Merci d'avance.

 

[Chris401]

Bonsoir
Pas sûr de comprendre.
Essaye :

=SOMMEPROD((SOUS.TOTAL(9;DECALER(K$1;LIGNE(INDIRECT("1:"&LIGNES($A$2:$A$14)));)))*($I$2:$I$14))

 

[sylvanu]

Bonsoir almourasel,
Un essai en PJ inspiré de https://forum.excel-pratique.com/excel/sommeprod-et-filtres-101672
Par exemple pour Lundi, créer une plage nommée avec :

Pour MH :
=SOUS.TOTAL(109;DECALER(Sheet1!$I$2:$I$14;LIGNE(Sheet1!$I$2:$I$14)-LIGNE(Sheet1!$I$2);;1;1))
Pour Lundi :
=SOUS.TOTAL(109;DECALER(Sheet1!$K$2:$K$14;LIGNE(Sheet1!$K$2:$K$14)-LIGNE(Sheet1!$K$2);;1;1))

Etc, jusqu'à vendredi.

Et pour la somme :
=SOMMEPROD(MH;Mon) jusqu'à =SOMMEPROD(MH;Fri)

 

[almourasel]

Bonsoir
Pas sûr de comprendre.
Essaye :

=SOMMEPROD((SOUS.TOTAL(9;DECALER(K$1;LIGNE(INDIRECT("1:"&LIGNES($A$2:$A$14)));)))*($I$2:$I$14))

parfait , exactement ce que je cherche.
Merci bcp

 

[almourasel]

Bonsoir almourasel,
Un essai en PJ inspiré de https://forum.excel-pratique.com/excel/sommeprod-et-filtres-101672
Par exemple pour Lundi, créer une plage nommée avec :

Pour MH :
=SOUS.TOTAL(109;DECALER(Sheet1!$I$2:$I$14;LIGNE(Sheet1!$I$2:$I$14)-LIGNE(Sheet1!$I$2);;1;1))
Pour Lundi :
=SOUS.TOTAL(109;DECALER(Sheet1!$K$2:$K$14;LIGNE(Sheet1!$K$2:$K$14)-LIGNE(Sheet1!$K$2);;1;1))

Etc, jusqu'à vendredi.

Et pour la somme :
=SOMMEPROD(MH;Mon) jusqu'à =SOMMEPROD(MH;Fri)

Salut

Merci bcp aussi , j suis pas expert en VB mais c tres interessant vraiment.

 

[sylvanu]

j suis pas expert en VB

Ce n'est pas du VB, uniquement des formules.

 

[almourasel]

Ce n'est pas du VB, uniquement des formules.

Merci