suite de lettres

[Rossi]

Bonjour,

J'ai un besoin qui me parrait relativement simple. Je cherche à prolonger automatiquement une suite du type :
sampleA
sampleB
sampleC
sampleD
sampleE
sampleF
sampleG
sampleH
sampleI
sampleJ
sampleK
sampleL
.......

Merci d'avance si vous avez une solution,

 

[Tibo]

Re : suite de lettres

Salut Rossi,

Tu peux essayer ceci :

="sample"&CAR(LIGNE()+64)

adapte le 64 si tu ne commences pas en ligne 1


@+

 

[Robert]

Re : suite de lettres

Bonjour le fil, bonjour le forum,

Ha Tibo Rossi, ne manque plus que Catarinetta bella Tchi tchi...

p.s. désolé. Mettez ça sur le compte de la chaleur...

 

[Rossi]

Re : suite de lettres

Merci pour la réponse et le jeu de mot,

ça marche, mais apres sampleZ, j'aurrais souhaité obtenir sampleAA, sampleAB

 

[Tibo]

Re : suite de lettres

re,

essaye avec ceci :

=SI(MOD(ENT((LIGNE()-1)/26);26)>0;CAR(MOD(ENT((LIGNE()-1)/26);26)+64);"")&CAR(65+MOD(LIGNE()-1;26))

toujours à partir de A1.

Il doit y avoir plus court, mais j'ai pas trouvé. La chaleur ... sans doute ...

@+

 

[Monique]

Re : suite de lettres

Bonjour,

En démarrant en ligne 1 :
="Sample"&GAUCHE(ADRESSE(1;LIGNES($1:1);4);NBCAR(ADRESSE(1;LIGNES($1:1);4))-1)

Idem :
="Sample"&GAUCHE(ADRESSE(1;LIGNES(A$1:A1);4);NBCAR(ADRESSE(1;LIGNES(A$1:A1);4))-1)

ça s'arrête à SampleIV

 

[JeanMarie]

Re : suite de lettres

Bonjour

Autre propositon
=STXT(ADRESSE(1;MIN(256;LIGNE());4);1;NBCAR(ADRESSE(1;MIN(256;LIGNE());4))-1)

A concaténer à un texte ="Exemple"&STXT(...........)

@+Jean-Marie

 

[Tibo]

Re : suite de lettres

re,

Une solution plus courte que celle que j'ai déjà proposée :

="Sample"&GAUCHE(CAR(ENT((LIGNE()-1)/26)+64);(LIGNE()>26))&CAR(MOD(LIGNE()-1;26)+65)

Valable jusqu'à ZZ

Bonne soirée

@+

 

[mjo]

Re : suite de lettres

Bonjour,

A partir de la ligne 1 :
="Sample"&SUBSTITUE(ADRESSE(1;LIGNE();4);1;"")

mjo