Soustraire des heures sous condition

[excelmagnon]

Bonjour,

Je cherche à soustraire les heure de 2 évènements pour en déduire une durée. Mais la soustraction doit être faite avec les bons éléments, qui ne se suivent pas toujours dans ma liste. Est ce que quelqu'un peu m'aider, s'il vous plait.

Merci

 

[tototiti2008]

Re : Soustraire des heures sous condition

Bonjour paul,

à tester en E4

=SI(C4="Réponse";B4-INDEX($B$4:$B$9;EQUIV(D4;$D$4:$D$9;0))+SI(INDEX($B$4:$B$9;EQUIV(D4;$D$4:$D$9;0))>B4;1;0);"")

puis à recopier vers le bas

 

[Dugenou]

Re : Soustraire des heures sous condition

Bonjour,

un essai en considérant que chaque adresse n'est présente que 2 fois (appel et réponse) et que en cas de date différente il n'y a qu'une journée d'écart.

Cordialement

edit :
Salut Tototiti : belle solution plus élégante que la mienne

 

[excelmagnon]

Re : Soustraire des heures sous condition

Bonjour,

Effectivement dans ma liste les adresses reviennent plusieurs fois, car une fois qu'une réponse est apportée un nouvel appel peut être lancé.

Avec la formule de tototiti, la soustraction se fait toujours à partir du premier appel, alors qu'il faudrait que cela se fasse depuis le dernier. Est ce qu'il y a un fonction comme index, mais qui lise la liste à l'envers (du bas vers le haut)?

Merci. Paul

 

[tototiti2008]

Re : Soustraire des heures sous condition

Bonjour Dugenou,
Re,

en E4

=SI(C4="Réponse";B4-SOMMEPROD(MAX(($B$3:$B4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1)+SI(SOMMEPROD(MAX(($B$3:$B4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1)>B4;1;0);"")

 

[excelmagnon]

Re : Soustraire des heures sous condition

Merci tototiti pour ton aide.

Il reste toujours un problème:
Le fait de mettre MAX dans la formule retient l'heure la plus grande de la journée et donc cela pose problème quand on change de jour. Je m'en suis aperçu en complétant le tableau. Normalement j'ai plus de 7000 lignes dans le fichier. On a l'impression que ça marche sur le première lignes mais si on fait référence à une adresse qui a déjà appelé, ça ne marche plus.

Est ce qu'il est possible de faire un MAX sur le jour+heure plutôt que seulement sur l'heure? Pour être sur que cela prenne en compte le dernier appel et non pas l'appel le plus tardif sur les jours précédents.

Paul

 

[tototiti2008]

Re : Soustraire des heures sous condition

Re,

Peut-il y avoir plus d'un jour entre un appel et une réponse ?

si non

=SI(C4="Réponse";B4-INDIRECT("B"&SOMMEPROD(MAX(LIGNE($A$3:$A4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1))+SI(INDIRECT("B"&SOMMEPROD(MAX(LIGNE($A$3:$A4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1))>B4;1;0);"")

si oui

=SI(C4="Réponse";A4+B4-INDIRECT("A"&SOMMEPROD(MAX(LIGNE($A$3:$A4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1))-INDIRECT("B"&SOMMEPROD(MAX(LIGNE($A$3:$A4)*($D$3:$D4=D4)*($C$3:$C4="Appel"))*1));"")

pas forcément plus compliqué d'ailleurs...

 

[excelmagnon]

Re : Soustraire des heures sous condition

Merci,

il ne me reste plus qu'à comprendre la formule!

Paul

 

[tototiti2008]

Re : Soustraire des heures sous condition

Bonjour à tous,

dis-nous si tu bloques à la compréhension d'une partie...