Sommeprod date

[phil87]

Bonjour le forum

J'ai un petit souci, lorsque la plage de selection de "sommeprod" n'est pas totalement remplie, un message #VALEUR vient s'inscrire. jn'arrive pas à connaître la raison.

PJ pour plus de compréhension

Merci par avance

 

[ROGER2327]

Re : Sommeprod date

Bonjour phil87

Essayez

[COLOR="DarkSlateGray"][B]=SOMMEPROD((Feuil1!B15:B254=A2)*SI(Feuil1!F15:F254="";0;Feuil1!F15:F254))+SOMMEPROD((Feuil2!B15:B254=A2)*SI(Feuil1!F15:F254="";0;Feuil1!F15:F254))[/B][/COLOR]

ou

[COLOR="DarkSlateGray"][B]=SOMME((Feuil1!B15:B254=A2)*SI(Feuil1!F15:F254="";0;Feuil1!F15:F254))+SOMME((Feuil2!B15:B254=A2)*SI(Feuil1!F15:F254="";0;Feuil1!F15:F254))[/B][/COLOR]

en validant par Ctrl + Maj + Entrée.​

ROGER2327
#2829

 

[phil87]

Re : Sommeprod date

Bonjour Roger2327

Je suis désolé mais le résultat escompter avec 2 prêts à 240 mensualités est de : 24856.88
Alors qu'avec vos formules validés par Ctrl + Maj + Entrée : 19896.74
Par contre, effectivement il me met plus l'erreur #VALEUR lorsque que je diminue les mensualités des prêts.

merci en attendant

 

[ROGER2327]

Re : Sommeprod date

Re...

Une petite erreur !
Correction (en rouge) :

[B][COLOR="DarkSlateGray"]=SOMMEPROD((Feuil1!B15:B254=A2)*SI(Feuil1!F15:F254="";0;Feuil1!F15:F254))+
SOMMEPROD((Feuil2!B15:B254=A2)*SI(Feuil[COLOR="Red"]2[/COLOR]!F15:F254="";0;Feuil[COLOR="Red"]2[/COLOR]!F15:F254))[/COLOR][/B]

ROGER2327
#2830

 

[JCGL]

Re : Sommeprod date

Bonjour à tous,

Mettre la référence à Feuil2 dans le deuxième bloc

A+

Edition : Désolé pas rafraîchi A++

 

[phil87]

Re : Sommeprod date

Un grand MERCI Roger2327

Effectivement la petite erreur corrigée fonctionne à merveille.
Excuse moi, j'aurai pu vérifier par moi même que le nom des feuilles n'était pas correct.

MERCI encore

 

[ROGER2327]

Re : Sommeprod date

Re... (et bonjour, JCGL)

(...)
Excuse moi, j'aurai pu vérifier par moi même que le nom des feuilles n'était pas correct.
(...)

Oui.​

Bonne soirée !
ROGER2327
#2831

 

[Monique]

Re : Sommeprod date

Bonjour à tous,

On peut se passer du "Si"

=SOMMEPROD((Feuil1!B15:B254=A2)*1;Feuil1!F15:F254)+SOMMEPROD((Feuil2!B15:B254=A2)*1;Feuil2!F15:F254)

Somme.Si suffit :

=SOMME.SI(Feuil1!B15:B254;A2;Feuil1!F15:F254)+SOMME.SI(Feuil2!B15:B254;A2;Feuil2!F15:F254)

Si tu risques d'avoir plus de deux feuilles (NomOnglets est le nom donné à une plage de cellules contenant le nom des onglets) :

[FONT=Verdana]=SOMMEPROD(SOMME.SI(INDIRECT("'"&NomOnglets&"'!B15:B254");A2;INDIRECT("'"&NomOnglets&"'!F15:F254")))[/FONT]

Ou bien

[FONT=Verdana][FONT=Verdana]=SOMMEPROD(SOMME.SI(INDIRECT("Feuil"&LIGNE(1:2)&"!B15:B254");A2;INDIRECT("Feuil"&LIGNE(1:2)&"!F15:F254")))[/FONT]
[/FONT]