Microsoft 365 SOMMEPROD avec selection de plage de cellules multicriteres

[weezben]

Bonjour,
j'ai un onglet Database et un onglet reporting.
Dans l'onglet reporting, un P&L.

Pour la ligne 127 par exemple, j'ai mis en place la sommeprod suivante :
=-SOMMEPROD((Database!$E$2:$E$49997='P&L'!A127:T127)*(Database!$H$2:$H$49997='P&L'!$U127)*(Database!$C$2:$C$49997>='P&L'!$AE$2)*(Database!$C$2:$C$49997<='P&L'!$AE$3)*(Database!$N$2:$N$49997))

Oû :
P&L'!A127:T127 = ensemble de plusieurs comptes comptables au format txt,
P&L'!$U127 = une fonction ou un projet au format txt
>='P&L'!$AE$2) et <='P&L'!$AE$3 sont des critères de dates,
Database!$N$2:$N$49997 = les montants à additionner


Cela marche plutôt bien. Mais j'aimerais maintenant élargir la sélection à plusieurs fonction (ou projets), et comme l'ai fait pour l'ensemble de comptes comptables, c'est à dire, grosso modo :
=-SOMMEPROD((Database!$E$2:$E$49997='P&L'!A127:T127)*(Database!$H$2:$H$49997='P&L'!$U127:$Y127)*(Database!$C$2:$C$49997>='P&L'!$AE$2)*(Database!$C$2:$C$49997<='P&L'!$AE$3)*(Database!$N$2:$N$49997))
mais évidemment cela ne marche pas ..

En gros je voudrais addtionner des criteres complementaires, sur le meme modele que les comptes comptables en P&L'!A127:T127

Question 1 : pourquoi ?
Question 2 : Quelle serait la solution ?
Merci à tous .

 

[CISCO]

Bonsoir

Sans fichier, cela n'est pas très pratique pour nous pour faire des tests. Il suffit de quelques lignes, quelques valeurs, quelques noms représentatifs de la situation à étudier...

@ plus

 

[weezben]

Voilà, un peu plus de concret avec la PJ Les cellules posant problème sont en rouge.
Merci pour votre aide.

 

[JHA]

Bonjour à tous,

A essayer en "AB9"

=SOMMEPROD((ESTNUM(EQUIV(DataBase!$B$2:$B$2680;$A9:$T9;0)))*(ESTNUM(EQUIV(DataBase!$C$2:$C$2680;$U9:$W9;0)))*(DataBase!$A$2:$A$2680>=$AB$2)*(DataBase!$A$2:$A$2680<=$AB$3);(DataBase!$D$2:$D$2680))

copier vers le bas

JHA

 

[weezben]

Merci beaucoup JHA, ça fonctionne super bien, en effet
Si ce n'est pas trop demandé, j'aimerais comprendre l'apport du (ESTNUM(EQUIV ?

Merci encore !

 

[CISCO]

Bonsoir

Sans regarder la formule concernée dans le fichier...

EQUIV recherche une valeur ou un texte dans une plage, et renvoie la position, un nombre donc, de cette valeur ou de ce texte dans cette plage. SI EQUIV ne trouve pas cette valeur ou ce texte, ESTNUM(EQUIV donne FAUX

@ plus