somme d'une loi binomiale

[vbhdb]

Bonjour,

Je cherche une formule dans Excel (si possible sans macro) me permettant de réaliser la somme suivante :
LOI.BINOMIALE(MIN(x;y)-1;x+y;0,5;FAUX) + LOI.BINOMIALE(MIN(x;y)-2;x+y;0,5;FAUX) +
LOI.BINOMIALE(MIN(x;y)-3;x+y;0,5;FAUX) +...+ LOI.BINOMIALE(MIN(x;y)-n;x+y;0,5;FAUX)

jusqu'à ce que MIN(x;y)-n = 0
(x et y étant des variables issues d'une distribution qui change selon les résultats d'un test)

Est-ce possible ?

Merci

 

[mapomme]

Re : somme d'une loi binomiale

Bonjour,

Testez cette formule matricielle:

=SOMME(LOI.BINOMIALE(MIN(x;y)-LIGNE(INDIRECT("A1:A" & MIN(x;y)));x+y;0.5;FAUX))

Cette formule est une formule matricielle. Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique. Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades
{=.......}. Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

Je crois (à vérifier) que sur MAC, la séquence de touche pour valider une formule matricielle est : COMMANDE+RETOUR

Voir fichier:

 

[vbhdb]

Re : somme d'une loi binomiale

Bonjour et merci,

Est-ce que "A1:A" correspond à une plage de cellules ?
Si tel est le cas, je n'ai justement pas de plage de cellules directement liée à une éventuelle formule matricielle...

x est la somme des différences positives entre 2 colonnes de cellules (D1 et D2) avec variables dichotomiques (0 ou 1)
y est la somme des différences négatives entre ces 2 colonnes.

Exemple
D1 D2
1 0
1 1
1 1
1 0
1 0
1 1
1 1
0 1
1 0
0 1
0 0
1 1
1 0
1 1
1 0

x = 6
y = 2

Min(x;y) = 2


La formule que je cherche est alors la somme de toutes les formules binomiales de 0 à 2 :
LOI.BINOMIALE(MIN(x;y)-0;x+y;0,5;FAUX) + LOI.BINOMIALE(MIN(x;y)-1;x+y;0,5;FAUX) +
LOI.BINOMIALE(MIN(x;y)-2;x+y;0,5;FAUX)

En espérant avoir été plus clair.

 

[vbhdb]

Re : somme d'une loi binomiale

Je viens de voir le fichier joint.
Cela me semble correspondre (je vais tenter de l'adapter)
Merci beaucoup

 

[mapomme]

Re : somme d'une loi binomiale

(re) Bonjour,

Pour x et y (ne sachant pas ce qu'ils représentaient) j'ai nommé deux cellules (A2 et A3) avec pour nom respectif x et y.

"A1:A" fait partie de l'expression LIGNE(INDIRECT("A1:A" & MIN(x;y)))
Si x= 6 et y= 2 alors min(x,y) = 2 et :
"A1:A" & MIN(x;y) est égal à "A1:A2". Donc INDIRECT("A1:A2") fait référence aux cellules A1:A2.
et la matrice LIGNE(A1:A2) est la matrice (validée en tant que formule matricielle) retournant chaque numéro de ligne de A1:A2 soit la la matrice {1;2}.
==> Les valeurs contenues dans A1:A2 ne sont pas importantes - seuls les numéros de ligne sont recherchés.

LOI.BINOMIALE(MIN(x;y)-LIGNE(INDIRECT("A1:A" & MIN(x;y)));x+y;0.5;FAUX) se transforme donc en :
LOI.BINOMIALE(MIN(x;y)-{1;2};x+y;0.5;FAUX) soit LOI.BINOMIALE(2-{1;2};8;0.5;FAUX).

La formule matricielle va donc évaluer deux fois cette formule, une fois pour la valeur 1 et une fois pour la valeur 2 soit :
LOI.BINOMIALE(2-1;8;0.5;FAUX) puis LOI.BINOMIALE(2-2;8;0.5;FAUX) soit encore
LOI.BINOMIALE(1;8;0.5;FAUX) puis LOI.BINOMIALE(0;8;0.5;FAUX).
Comme on veut la somme de ces évaluations, il faut prendre la somme soit
somme (LOI.BINOMIALE(1;8;0.5;FAUX) puis LOI.BINOMIALE(0;8;0.5;FAUX))

PS: J'ai repris la formule avec les données de votre dernier message: à priori si min(x,y) = 2, alors la formule est évaluée trois fois (pour 0,1 et 2). l"ancienne formule n'évaluait que pour 1 et 2.