Microsoft 365 Somme de cellules comportant une lettre en fonction de la précédente

[mini933]

Bonjour,

J'ai un fichier excel avec une séquence d'ADN qui contient environs 500 caractères

Pour exemple :

A1= A
B1= A
C1= T
D1= G
E1=A
F1=T
G1=C

J'aimerais sur cette ligne connaitre le nombre de A qui sont précédés par un autre A
pour connaitre mon nombre total de cellules avec la lettre A j'ai utilisé la fonction =NB.SI(A1:G1,"A") mais je ne comprend pas comment je pourrais ajouter ma deuxième condition.

Si quelqu'un à une idée cela m'aiderais beaucoup dans mon analyse,

En vous remerciant d'avance,

Mahwish

 

[Compte Supprimé 979]

Bonjour mahwish et bienvenue

Pas le choix que de traiter ça sur une autre ligne, colonne par colonne
En B1

=SI(B1=A1;1;0)

A tirer vers la droite et on fait ensuite une SOMME()

A+

 

[mini933]

Bonsoir,

Merci de votre réponse aussi rapide. Je vais surement finir par faire cela mais pensez vous que je puisse utiliser ce genre de formule pour ne pas devoir tout faire colonne par colonne :

=SI.MULTIPLE(ET(C$1="A",B$1="A"),1,0)

Pour le moment elle ne fonctionne pas mais je ne comprends pas d'ou vient l'erreure

Mahwish

 

[TooFatBoy]

Bonjour,

=SI(B1=A1;1;0)

Je vais surement finir par faire cela

Je pense que dans ce cas tu vas faire la somme de tous les doublons (AA, GG, CC, TT) et non uniquement des doubles A.

---

Je te propose de tester ceci pour les 500 premières cellules de la ligne 1 de la feuille :

=SOMMEPROD((A1:SE1="A")*(B1:SF1="A"))

Attention : s'il y a un triple A, c'est compté comme étant deux doubles A.


Spéciale dédicace à l'ami Gégé

 

[mapomme]

Bonjour à tous,

Pour le fun :
Une formule en E2 (peut-être matricielle-> à valider par Ctrl+Maj+Entrée en Excel 2019 ?) pour les séquences de deux ou plus à recopier vers le bas :

=SOMMEPROD(--(FREQUENCE(SI(Tableau1[Séquence ADN]=$D2;LIGNE(Tableau1[Séquence ADN]));SI(Tableau1[Séquence ADN]<>$D2;LIGNE(Tableau1[Séquence ADN])))>1))

Une formule en F2 (peut-être matricielle-> à valider par Ctrl+Maj+Entrée en Excel 2019 ?) pour les séquences de taille strictement égale à 2 , 3 ,4, ... à recopier vers la droite jusqu'en M2 et vers le bas :

=SOMMEPROD(--(FREQUENCE(SI(Tableau1[Séquence ADN]=$D2;LIGNE(Tableau1[Séquence ADN]));SI(Tableau1[Séquence ADN]<>$D2;LIGNE(Tableau1[Séquence ADN])))=F$1))

Une formule en N2 (peut-être matricielle-> à valider par Ctrl+Maj+Entrée en Excel 2019 ?) pour les séquences de deux ou plus à recopier vers le bas :

=SOMMEPROD(--(FREQUENCE(SI(Tableau1[Séquence ADN]=$D2;LIGNE(Tableau1[Séquence ADN]));SI(Tableau1[Séquence ADN]<>$D2;LIGNE(Tableau1[Séquence ADN])))>=N$1))

Le tableau a bien sûr été converti en tableau structuré.

 

[mini933]

Bonjour,

merci beaucoup pour vos réponses.

J'ai essayé le code =SOMMEPROD((A1:SE1="A")*(B1:SF1="A"))
et il fonctionne super bien!

J'ai essayé de le modifier car je dois analyser plusieurs types de motifs de 2 ou 3 lettres.

Le premier motif était AA et ton code fonctionne parfaitement @TooFatBoy merci beaucoup.

Je vous joins l'essai que j'ai fait sur le fichier de @mapomme. J'ai ensuite essayé de le modifier pour qu'il corresponde au motif TA ( tous les A précédés d'un T) mais je ne comprends pas pourquoi il me compte 2 motifs en plus de ceux que j'ai compté manuellement.

Est ce que je peux utiliser cette formule pour plus de 2 lettres ?

Je n'ai pas compris toutes tes formules @mapomme mais j'ai copié la même séquence test et ces formules ne me donnent pas le résultat attendu.

Bonne soirée,

Mahwish

 

[mapomme]

Re,

Attention! Avec la fonction FREQUENCE, je ne compte pas les couples "AA" mais les séquences consécutives de A :

• Une séquence de 2 A contient 1 couple de AA
• Une séquence de 3 A contient 2 couples de AA
• Une séquence de 4 A contient 3 couples de AA, etc.

Dans le fichier joint, la colonne couple du premier tableau indique le nombre de couple correspondant aux séquences de 2 à 9 A. Et dans ce cas, on retrouve les résultats de la formule SOMMEPROD (s'il n'y a pas de séquence supérieure à 9).

Pour ce que vous voulez dénombrer, je pense que c'est le SOMMEPROD qui s'impose (voir le dernier tableau).

 

[TooFatBoy]

Pour compter les couples TA, j'essaierai ceci :

=SOMMEPROD((A1:SE1="T")*(B1:SF1="A"))

Pour les triplets (par exemple CGT), j'essaierai ça :

=SOMMEPROD((A1:SD1="C")*(B1:SE1="G")*(C1:SF1="T"))

 

[mini933]

@mapomme d'accord je n'avais pas compris.

@TooFatBoy merci ça marche j'avais en effet inversé le T et le A dans ma formule

Et pour pousser le bouchon un peu plus loin pensez vous qu'il y a moyen de pouvoir connaitre la position de ces motifs

 

[mapomme]

Et pour pousser le bouchon un peu plus loin pensez vous qu'il y a moyen de pouvoir connaitre la position de ces motifs

Une version v3 qui utilise des MFC pour colorer les cellules concernées.
Saisir en K4 la séquence à rechercher (AA, TA, CG, etc.).

Remarque : peut-être désiriez-vous connaitre le rang des séquence à chercher plutôt que colorer le fond ?

Edit : Et une version v3b qui en ligne 2 a une formule qui indique le numéro de colonne de la première base de la séquence à chercher.

 

[mini933]

Super merci beaucoup @mapomme c'est exactement ce qu'il me fallait je cherchais bien le rang des séquences.

Merci à tous je vais pouvoir faire mes analyses bien plus rapidement grace à votre aide.