SOMME CONDITIONNELLE (Suis Perdu là !!)

[FRED]

Bonsoir à toutes et à tous, Bonsori el forum,

Comment vous dire, j'ai une somme d'un nombre d'achats précis d'objet à faire par rapport à 3 critères et je n'y arrive pas !

Il y a un critère de Date et 2 critères Alpabétiques;

Merci d'avance à totues et à tous.

 

[Monique]

Bonsoir,

En D18
=SOMMEPROD((MOIS($A$5:$A$14)=1)*($B$5:$B$14="pomme")*($C$5:$C$14=$C18))
En E18
=SOMMEPROD((MOIS($A$5:$A$14)=2)*($B$5:$B$14="pomme")*($C$5:$C$14=$C18))

 

[FRED]

Hehehe ce fameux sommeprod, j'ai pourtant regarder pour le faire de la sorte mais j'avais mis un argument de trop en faisant ET devant tous les criètres !

Mais j'ai pas tout compris comment fonctionnait sommeprod dans ce cas de figure ???!!! Et là ça me chagrine un peu de ne pas comprendre !

Merci encore.

 

[Monique]

Re,

Le * équivaut à ET, le + équivaut à OU (soit, soit) et le - à SAUF

Pour avoir les pommes et les poires du mois de janvier :
=SOMMEPROD((MOIS($A$5:$A$14)=1)*(($B$5:$B$14="pomme")+($B$5:$B$14="poire"))*($C$5:$C$14=$C18))

Pour avoir les pommes et les poires de tout le premier semestre, sauf le mois de février :
=SOMMEPROD(((MOIS($A$5:$A$14)<7)-(MOIS($A$5:$A$14)=2))*(($B$5:$B$14="pomme")+($B$5:$B$14="poire"))*($C$5:$C$14=$C18))

 

[FRED]

Ok merci cela revient au même, si je ne dis pas de conneries, à faire une somme en matricielle également ??!!

Le plus dur à comprendre dans mon cas avec sommeprod, c'est que là il ne multiplie rien. Pour la somme Ok je suis, mais pour le produit là je donne ma langue au chat ?!

Enfin de compte je pourrais mettre aussi donc en matricielle ?

{=SOMME((MOIS($A$5:$A$14)=1)*($B$5:$B$14="pomme")*($C$5:$C$14=$C18))}

 

[Monique]

Re,

Tu peux remplacer par SOMME en matriciel, mais c'est moins pratique.
Et beaucoup de matricielles ralentissent le recalcul.

Sommeprod fait la somme des produits.
Les produits en question :
=MOIS($A$5:$A$14)=1
Si tu valides en matriciel en sélectionnant 10 cellules (tu as 10 lignes), ça te dit VRAI ou FAUX, selon que le mois correspond ou non

Le 2è produit, idem, tu sélectionnes 10 cellules, tu valides en matriciel et tu constates
=$B$5:$B$14="pomme"

Le 3è produit, idem
=$C$5:$C$14=C18

VRAI équivaut à 1 et FAUX à 0
1*1*1 = 1
1*1*0 = 0

 

[FRED]

Désolé de te déranger mais c'est juste pour dire merci !

C'est la moindre des choses !

Bonne nuit.