simplifié une vba

[poussy67]

Bonjour le forum,

Je suis à la recherche d'une vba qui me permet de masquer des lignes contenant une valeur ("1"). Pour me moment j'utilise cette vba pour une ligne
If Range("H7") = 1 Then Rows("7:7").EntireRow.Hidden = True
If Range("H7") = 0 Then Rows("7:7").EntireRow.Hidden = False
Mais le problème il y a 100 lignes qui sont concernés, aurait il un moyen d'éviter d'écrire 100 fois les lignes VBA.
Merci d'avance pour votre aide le Forum

cdt Poussy

 

[JNP]

Re : simplifié une vba

Bonjour Poussy67

Mais le problème il y a 100 lignes qui sont concernés, aurait il un moyen d'éviter d'écrire 100 fois les lignes VBA.

Heureusement 😛...

Sub Test()
Dim I As Integer
For I = 1 To 100
If Range("H" & I) = 1 Then Rows(I & ":" & I).EntireRow.Hidden = True
If Range("H" & I) = 0 Then Rows(I & ":" & I).EntireRow.Hidden = False
Next I
End Sub

Bonne journée 😎

 

[poussy67]

Re : simplifié une vba

Merci JNP pour ta rapidité

Cela fonctionne tres et cela m'evite plein ligne inutile

encore merci

Passe une bonne journée

Cdt poussy

 

[Dull]

Re : simplifié une vba

Salut poussy67, le Forum

Peut-être avec un Boucle
dans le Module de la Feuille

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Long
Dim Derlig As Long
Derlig = Cells(Rows.Count, 8).End(xlUp).Row
For i = 1 To Derlig
    If Range("H" & i) = 1 Then
        Rows(i).EntireRow.Hidden = True
            Else
        Rows(i).EntireRow.Hidden = False
    End If
Next i
End Sub

EDITION: Salut JNP 🙂 encoreàlabourremoi 😛

Bonne Journée

 

[Pierrot93]

Re : simplifié une vba

Bonjour à tous

peut être une autre solution comme ceci :

Option Explicit
Sub test()
Dim i As Long
Application.ScreenUpdating = False
For i = 1 To Range("H65536").End(xlUp).Row
    Rows(i).Hidden = Cells(i, 8).Value = 1
Next i
Application.ScreenUpdating = True
End Sub

bonne journée
@+