XL 2013 Simplification Selectcase

[GADENSEB]

Hello Le Forum,
Je cherche à simplifier ce SelectCase ....
je reconnais que mon code est un peu lourd dingue.

Qui aurait une idée ?

bonne journée
Seb

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Select Case ActiveCell.Address
Case "$E$4"
ActiveSheet.ChartObjects("GR_LignesReserves").Visible = True
Case Else
'Do nothing
End Select
   
Select Case ActiveCell.Address
Case "$F$4"
ActiveSheet.ChartObjects("GR_LignesReserves").Visible = False
Case Else
'Do nothing
End Select


Select Case ActiveCell.Address
Case "$A$4"
ActiveSheet.ChartObjects("Gr_Comptes").Visible = True
Case Else
'Do nothing
End Select
   
Select Case ActiveCell.Address
Case "$B$4"
ActiveSheet.ChartObjects("Gr_Comptes").Visible = False
Case Else
'Do nothing
End Select




End Sub

 

[Lolote83]

Salut,
peut être comme ceci

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Select Case ActiveCell.Address
        Case "$E$4"
            ActiveSheet.ChartObjects("GR_LignesReserves").Visible = True
        Case "$F$4"
            ActiveSheet.ChartObjects("GR_LignesReserves").Visible = False
        Case "$A$4"
            ActiveSheet.ChartObjects("Gr_Comptes").Visible = True
        Case "$B$4"
            ActiveSheet.ChartObjects("Gr_Comptes").Visible = False
        Case Else
        'Do nothing
    End Select
End Sub

@+ Lolote83

 

[gosselien]

Bonjour,

je verrais ça comme ceci 🙂

P.

cel = ActiveCell.Address
Select Case cel ' ActiveCell.Address
Case Is = "$E$4"
ActiveSheet.ChartObjects("GR_LignesReserves").Visible = True
Case Is = "$F$4"
ActiveSheet.ChartObjects("GR_LignesReserves").Visible = False
Case Is = "$A$4"
ActiveSheet.ChartObjects("Gr_Comptes").Visible = True
Case Is = "$B$4"
ActiveSheet.ChartObjects("Gr_Comptes").Visible = False
End Select

 

[Si...]

salut
et ainSi... ?

Private Sub Worksheet_BeforeDoubleClick(ByVal R As Range, Cancel As Boolean)
  Me.ChartObjects("GR_LignesReserves").Visible = R.Address = "$E$4"
  Me.ChartObjects("GR_LignesReserves").Visible = R.Address <> "$F$4"
  Me.ChartObjects("Gr_Comptes").Visible = R.Address = "$A$4"
  Me.ChartObjects("Gr_Comptes").Visible = R.Address <> "$B$4"
End Sub

 

[GADENSEB]

Hello
Parfait !
C'est que je cherchais !!!
ps : Je garde le code de lolotte
A+
Merci
Seb

 

[ChTi160]

Bonjour Seb
Bonjour le fil,Le Forum
si les ChartObject ne sont affichées que lorsque les cellules cibles sont E4 et A4
alors peut être !!!!!

Private Sub Worksheet_BeforeDoubleClick(ByVal R As Range, Cancel As Boolean)
  With Me.ChartObjects("GR_LignesReserves")
              .Visible = IIf(R.Address = "$E$4", True, False)
  End With
  With Me.ChartObjects("Gr_Comptes")
        .Visible = IIf(R.Address = "$A$4", True, False)
  End With
End Sub

Bonne journée
Amicalement
Jean marie

 

[GADENSEB]

Pas mal !!!
Merci

 

[eriiic]

Bonjour,

et ma participation avec un brin de retard :
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Select Case Target.Address
Case "$E$4", "$F$4"
ActiveSheet.ChartObjects("GR_LignesReserves").Visible = Target.Column = 5
Case "$A$4", "$B$4"
ActiveSheet.ChartObjects("Gr_Comptes").Visible = Target.Column = 1
End Select
End Sub
eric

PS : il n'y a plus d'icone pour la mise en forme du code ?

 

[GADENSEB]

Sisis i icone inserer .... puis code
Joli code aussi
Thanks