XL pour MAC =SI(SOMMEPROD.....

[pilou010]

Bonjour à tous,
Je souhaite remplir un tableau en fonction de critères se trouvant dans un autre tableau. J'ai tenté une bidouille avec =SI(SOMMEPROD mais je ne maitrise pas la formule et je ne sais pas si c'est la bonne formule donc je n'arrive pas au résultat.
Est-ce que quelqu'un ici aurait la gentillesse de jeter un coup d’œil sur mon souci ?
En PJ un classeur pour exemple
Merci

 

[sylvanu]

Bonjour Pilou,
Somme.Si.Ens semble plus approprié pour votre problématique:

=SOMME.SI.ENS($E$3:$E$100;$B$3:$B$100;"1 "&$G3&" "&H$2)

Fonction SOMME.SI.ENS - Support Microsoft

Comment utiliser la fonction SOMME.SI.ENS dans Excel, l'une des fonctions mathématiques et trigonométriques d'Excel, pour additionner les arguments qui répondent à plusieurs critères.

support.microsoft.com

 

[job75]

Bonjour pilou010, sylvanu,

Puisque les dates de Tableau1 sont toutes le 1er de chaque mois formule en H3 :

=SIERREUR(RECHERCHEV(DATEVAL($G3&H$2);Tableau1;4;0);"")

A+

 

[job75]

Maintenant si les dates de Tableau1 sont quelconques on utilisera en H3 :

=SOMMEPROD((ANNEE(INDEX(Tableau1;;1))=--H$2)*(MOIS(INDEX(Tableau1;;1))=MOIS("1/"&$G3));INDEX(Tableau1;;4))

 

[pilou010]

Super, merci pour vos solutions. Je vais utiliser la dernière de job75.
Merci, Merci, Merci ! ! !

 

[job75]

Une formule plus simple dans ce fichier (3) :

=SOMMEPROD((INDEX(Tableau1;;1)-JOUR(INDEX(Tableau1;;1))+1=DATEVAL($G3&H$2))*INDEX(Tableau1;;4))

 

[R@chid]

Bonjour @ tous,
Un TCD ne fera pas l'affaire ?

 

[pilou010]

Oui R@chid cela fonctionne avec un TCD j'en ai fait un mais je n'y avais pas pensé...

job75, comment faire pour que soit pris en compte que les sommes du crédit si il y a "Loyer" dans la colonne "action" ?
En effet j'ai d'autres revenus qui ne sont pas des loyers.
Merci

 

[job75]

job75, comment faire pour que soit pris en compte que les sommes du crédit si il y a "Loyer" dans la colonne "action" ?

Il y a des espaces superflus en colonne "Action", fichier (4) avec SUPPRESPACE :

=SOMMEPROD((INDEX(Tableau1;;1)-JOUR(INDEX(Tableau1;;1))+1=DATEVAL($G3&H$2))*(SUPPRESPACE(INDEX(Tableau1;;2))="Loyer");INDEX(Tableau1;;4))

Salut R@chid.

 

[pilou010]

Nickel ! ! ! Merci