selectionnez feuille à copier sur classeur fermé.

[yves03]

Bonjour,
Je copie une feuille d'un classeur fermé vers mon classeur actif, mais je voudrais pouvoir selectionner la feuille à copier et non pas toujours "feuil1".
Si vous avez des idées
Merci d'avance

 

[bouley]

Re : selectionnez feuille à copier sur classeur fermé.

bonjour,
quelle méthode utilises-tu pour lire le fichier fermé ?
le modèle ADO ?

merci

 

[Guest]

Re : selectionnez feuille à copier sur classeur fermé.

Bonjour Yves,

Il nous faudrait plus de précision pour pouvoir te répondre.
Quelle macro est utilisée?
Comment est défini le nom de la feuille?

Un classeur exemple serait le bienvenu.

A+

 

[yves03]

Re : selectionnez feuille à copier sur classeur fermé.

j'utilise ce code que quelqu'un du forum m'a indiqué.
ça me va tres bien , sinon le fait que le nom de la feuille est en dur à l'interieur, j'aimerais pouvoir selectionner le nom, car les fichiers que j'ai ont plusieurs feuilles et ne s'appelent pas toujours pareil.
Merci

Sub Copie()
Application.DisplayAlerts = False
Application.ScreenUpdating = False
FichDest = ActiveWorkbook.Name
Workbooks(FichDest).Sheets("Inventaire").Delete
FichDep = Application.GetOpenFilename
If FichDep = False Then Exit Sub
Workbooks.Open FichDep
NomFich = ActiveWorkbook.Name
Sheets("Inventaire").Copy Before:=Workbooks(FichDest).Sheets(1)
Workbooks(NomFich).Close
Application.DisplayAlerts = True
Application.ScreenUpdating = True
Range("A2").Select

End Sub

 

[bouley]

Re : selectionnez feuille à copier sur classeur fermé.

puisque tu ouvres le fichier avant de copier la feuille le titre de ton post n'est pas adéquat !

cela dit il suffit de mettre le nom de la feuille que tu veux copier

  Sheets("texte de l'onglet").Copy Before:=Workbooks(FichDest).Sheets(1)

ou récuperer ce nom dans une variable ex nomfeuille = "texte de l'onglet de la à copier"

Sheets(nomfeuille).Copy Before:=Workbooks(FichDest).Sheets(1)

 

[yves03]

Re : selectionnez feuille à copier sur classeur fermé.

puisque tu ouvres le fichier avant de copier la feuille le titre de ton post n'est pas adéquat !

cela dit il suffit de mettre le nom de la feuille que tu veux copier

  Sheets("texte de l'onglet").Copy Before:=Workbooks(FichDest).Sheets(1)

ou récuperer ce nom dans une variable ex nomfeuille = "texte de l'onglet de la à copier"

Sheets(nomfeuille).Copy Before:=Workbooks(FichDest).Sheets(1)

Je suis d'accord avec toi, mais le nom de la feuille n'est pas toujours le meme, et je ne veux pas modifier le code à chaque fois.

 

[Guest]

Re : selectionnez feuille à copier sur classeur fermé.

Re,

voici le code de la macro réécrit.
elle demande le nom de la feuille à copier.

Sub Copie()
    Dim NomFeuille As String
    Dim sh As Worksheet
    NomFeuille = InputBox("Indiquez le nom de la feuille à copier", "Copie")
    If NomFeuille = vbNullString Then Exit Sub

    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    FichDest = ActiveWorkbook.Name
    Workbooks(FichDest).Sheets("Inventaire").Delete
    FichDep = Application.GetOpenFilename
    If FichDep = False Then Exit Sub
    Workbooks.Open FichDep
    NomFich = ActiveWorkbook.Name
    'Vérifier que la feuille existe bien dans le classeur actif
    On Error Resume Next
    Set sh = Sheets(NomFeuille)
    On Error GoTo 0
    If sh Is Nothing Then
        'Elle existe pas, on avertit et on sort
        MsgBox "La feuille '" & NomFeuille & "' est introuvable", vbExclamation
    Else
        'Elle existe on la copie
        sh.Copy Before:=Workbooks(FichDest).Sheets(1)
    End If
    Workbooks(NomFich).Close
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
    Range("A2").Select
End Sub

 

[yves03]

Re : selectionnez feuille à copier sur classeur fermé.

Merci à toi Hasco 🙂🙂
C'est exactement ce que je voulais.