selectionner une plage

[eduraiss]

Bonjour le forum

Je voudrais selectionner une plage suivant les cellules garnies

je joins un exemple

Merci de votre aide

 

[VDAVID]

Re : selectionner une plage

Bonjour Eduraiss,

Peut-être ai-je mal compris, mais si tu veux sélectionner en fonction du "remplissage" des colonnes AE à AG, il suffit de placer dans le code de ton bouton:

Range("AD3:AG" & Range("AG65536").End(xlUp).Row).Select

Bonne journée

 

[eduraiss]

Re : selectionner une plage

Re

merci a toi pour ta réponse mais la selection doit se faire en tenant compte de AG mais si les trois cellules a coté sont garnies

cordialement

 

[VDAVID]

Re : selectionner une plage

Re,
Autant pour moi, j'étais partit du principe que la colonne AG était remplie uniquement si celles avant l'étaient également.

Peut-être comme ceci alors:

Dim tabl As Variant
tabl = Array(Range("AD65536").End(xlUp).Row, Range("AE65536").End(xlUp).Row, Range("AF65536").End(xlUp).Row, Range("AG65536").End(xlUp).Row)
'pour chacun des éléments,
For num = 0 To 3
'on s'assure qu'aucun des éléments qui le suit ne lui est inférieur
For num2 = num + 1 To 3
'sinon, on échange les deux éléments
If tabl(num) > tabl(num2) Then
old = tabl(num)
old2 = tabl(num2)
tabl(num) = old2
tabl(num2) = old
End If
Next num2
Next num
Range("AD3:AG" & tabl(0)).Select

Toujours dans le code de ton bouton.
Inspiré de:
Formation Excel

 

[eduraiss]

Re : selectionner une plage

Re bonjour,

merci c'est presque bon sauf un petit problème
si AD3 n'est pas garni alors le code sélectionne AD2 et ça il ne le faut pas

merci

 

[VDAVID]

Re : selectionner une plage

Re,

Si il ne faut pas prendre en compte la colonne AD dans la sélection; il suffit de redimensionner le tableau comme ceci :

Private Sub CommandButton1_Click()
Dim tabl As Variant
tabl = Array(Range("AE65536").End(xlUp).Row, Range("AF65536").End(xlUp).Row, Range("AG65536").End(xlUp).Row)
'pour chacun des éléments,
For num = 0 To 2
'on s'assure qu'aucun des éléments qui le suit ne lui est inférieur
For num2 = num + 1 To 2
'sinon, on échange les deux éléments
If tabl(num) > tabl(num2) Then
old = tabl(num)
old2 = tabl(num2)
tabl(num) = old2
tabl(num2) = old
End If
Next num2
Next num
Range("AD3:AG" & tabl(0)).Select

End Sub

Du coup la sélection se fera si les colonnes AE à AG sont remplies, même si AD ne l'est pas !

 

[eduraiss]

Re : selectionner une plage

Re
il y a un problème, le nouveau code selectionne AD2:AG3 si il n'y a pas de valeurs sur la ligne AD3:AG3, il ne faut surtout pas que AD2:AG2 soit selectionné
Merci

 

[Robert]

Re : selectionner une plage

Bonjour le fil, bonjour le forum,

En pièce jointe ton fichier modifié avec le code ci-desous :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl (Dernière Ligne)
Dim pl As Range 'déclare la variable pl (Plage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim ps As Range 'déclare la variable ps (Plage de Sélection)

With Sheets("Feuil1") 'prend en compte l'onglet "" Feuil1"
    dl = .Cells(Application.Rows.Count, 30).End(xlUp).Row 'définit la dernière ligne éditée dl de la colonne AD
    Set pl = Range("AD3:AD" & dl) 'définit la plage pl
    Set ps = .Range("AD2") 'définit la plage ps (pour avoir au moins une plage de départ)
End With 'fin de la prise en compte de l'onglet "Feuil1"
For Each cel In pl 'boucle sur toutes les cellules cel de la plage pl
    'condition : si le nombre de valeurs dans la cellule cel plus les 3 cellules à coté est égal à 4
    If Application.WorksheetFunction.CountA(cel.Resize(, 4)) = 4 Then
        'redéfinit la plage ps (la ligne de cel si ps ne contient qu'une seule cellule, sinon ajoute la ligne de cel à ps)
        Set ps = IIf(ps.Cells.Count = 1, cel.Resize(, 4), Application.Union(ps, cel.Resize(, 4)))
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
ps.Select 'sélectionne la plage ps
End Sub

Le fichier :

 

[eduraiss]

Re : selectionner une plage

Re

bonjour Robert même problème si il n'y a pas de valeur en AD3:AG100 par exemple la selection s'effectue sur AD2:AG2
Merci

 

[Robert]

Re : selectionner une plage

Bonjour le fil, bonjour le forum,

Il suffisait de rajouter une ligne !

 If dl < 3 Then Exit Sub

Je ne comprends pas qu'avec le code tel que je le commente tu sois incapable de le faire toi-même... C'est grave !
Le code :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl (Dernière Ligne)
Dim pl As Range 'déclare la variable pl (Plage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim ps As Range 'déclare la variable ps (Plage de Sélection)
With Sheets("Feuil1") 'prend en compte l'onglet "" Feuil1"
    dl = .Cells(Application.Rows.Count, 30).End(xlUp).Row 'définit la dernière ligne éditée dl de la colonne AD
    If dl < 3 Then Exit Sub
    Set pl = Range("AD3:AD" & dl) 'définit la plage pl
    Set ps = .Range("AD2") 'définit la plage ps (pour avoir au moins une plage de départ)
End With 'fin de la prise en compte de l'onglet "Feuil1"
For Each cel In pl 'boucle sur toutes les cellules cel de la plage pl
    'condition : si le nombre de valeurs dans la cellule cel plus les 3 cellules à coté est égal à 4
    If Application.WorksheetFunction.CountA(cel.Resize(, 4)) = 4 Then
        'redéfinit la plage ps (la ligne de cel si ps ne contient qu'une seule cellule, sinon ajoute la ligne de cel à ps)
        Set ps = IIf(ps.Cells.Count = 1, cel.Resize(, 4), Application.Union(ps, cel.Resize(, 4)))
    End If 'fin de la condition
Next cel 'prochaine cellule de la boucle
ps.Select 'sélectionne la plage ps
End Sub

 

[VDAVID]

Re : selectionner une plage

Re Erudaiss, Bonjour Robert,

Je suis pour ma part un peu perdu, je ne comprends pas de ce que tu cherches à faire.
Pourrais-tu reposer ton problème avec quelle plage tu veux sélectionner en fonction de quels critères?

EDIT : Autant pour moi Robert à tout compris ! 🙂
Bonne soirée