Sélectionner la première cellule en "jaune" dans une colonne

[blord]

Bonjour à tous,

J'ai besoin de votre aide pour m'aider à résoudre le problème suivant :

Je voudrais pouvoir sélectionner la première cellule de couleur jaune (Code 36 mis par macro) dans la colonne T. Si aucune cellule n'est en jaune dans la colonne, il sélectionne la cellule T10.

La ligne 10 étant les en-têtes de colonne et les données débutent à la ligne 11...

Donc, si j'ai une cellule jaune en T3456, il sélectionne cette cellule...

J'ai essayé avec le code suivant, mais ça ne fonctionne pas :

Sheets("data VIEADH").Activate
Dim Cel As Range
Dim Plage As Range
Set Plage = Sheets("data VIEADH").Range("T11:T" & Sheets("data VIEADH").Range("T65536").End(xlUp).Row)
    
For Each Cel In Plage
    
If Cel.Interior.ColorIndex = 36 Then Cel.Select Else Range("T10").Select
Exit Sub
    
Next Cel

Merci pour votre aide !

Blord

 

[kjin]

Re : Sélectionner la première cellule en "jaune" dans une colonne

Bonsoir,
A vu de nez

Dim Cel As Range
Dim Plage As Range
With Sheets("data VIEADH")
    .Activate
    Set Plage = .Range("T11:T" & .Range("T65536").End(xlUp).Row)
    For Each Cel In Plage
        If Cel.Interior.ColorIndex = 36 Then
            Cel.Select
            Exit Sub
        End If
    Next
    .Range("T10").Select
End With

Edit : Activer la feuille auparavant, c'est mieux...!
A+
kjin

 

[blord]

Re : Sélectionner la première cellule en "jaune" dans une colonne

Bonjour Kjin, le Forum,

Merci pour ton aide Kjin, ton code foncionne parfaitement......

Bonne fin de journée !

Blord

 

[Lou]

Re : Sélectionner la première cellule en "jaune" dans une colonne

Bonjour,
Je ne sais pas du tout utilisé les macros, mais je cherche un peu la même chose. J'ai essayé de comprendre les lignes de code de la macros réponse, sans succès.
Je cherche à afficher la première cellule colorié en rouge dans une colonne, puis la première en jaune. Ces cellules sont variables selon une loi binomiale. (Je cherche a mettre en évidence les intervalle de fluctuations).

Merci d'avance.

 

[blord]

Re : Sélectionner la première cellule en "jaune" dans une colonne

Bonjour,

Voici quelques explications sur le code :

Sub IdentifierCelluleJaune ()
Dim Cel As Range 'Définit la variable Cel comme un range
Dim Plage As Range 'Définit la variable Plage comme un range

With Sheets("data VIEADH") 'Nom de la feuille sur laquelle on veut utiliser la macro
.Activate 'Active la feuille
Set Plage = .Range("T11:T" & .Range("T65536").End(xlUp).Row) 'Détermine la palge ici de la cellule T11 jusqu'à la dernière cellule occupée de la colonne T
For Each Cel In Plage 'boucle sur chaque cellule ce la colonne T
If Cel.Interior.ColorIndex = 36 Then 'si la couleur de la cellule est Jaune code 36
Cel.Select 'sélectionne la cellule
Exit Sub 'sort de la macro pour arrêter sur la cellule
End If
Next 'sinon passe à la prochaine cellule
.Range("T10").Select 'si aucune cellule en jaune, affiche l'étiquette de la colonne qui est en T10
End With
End sub

Pour savoir le code de couleur qu'utilise Excel, partir l'enregistreur de macro et mettre les couleurs dans des cellules et arrêter l'enregistreur de Macro. Le code de couleur utilisé par Excel...

36 = Jaune pâle
6 = Jaune
3 = Rouge vif

En espérant que celà vous aidera !

Benoit Lord