XL 2016 Retirer + a une série de nombre

cmdavid

XLDnaute Occasionnel
Bonjour à tous,

J’ai une série de nombre avec + et je souhaite mettre ces nombres séparément dans une colonne sans +

Merci pour votre aide,

Cordialement,
 

Pièces jointes

  • Nombre sans plus.xlsx
    8.8 KB · Affichages: 7
Solution
Bonjour @sylvanu

@cmdavid
Je joue à Madame Irma
Au cas où, le but recherché serait de sommer les nombres contenus en B3
Cette formule le fera ;)
=SOMMEPROD(--SUPPRESPACE(STXT(SUBSTITUE(B3;"+";REPT(" ";99));(LIGNE($A$1:INDEX(A:A;NBCAR(B3)-NBCAR(SUBSTITUE(B3;"+";""))+1))-1)*99+1;99)))
Avec cette formule en B5, j'obtiens : 542
(résultat identique à la somme de C3:C10, affichée en C11))
SommePlus.png

NB: Pour sommer C3:C10, j'ai modifié ainsi ma 1ère formule en (C3)
=SIERREUR(SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))*1;"")

mapomme

XLDnaute Barbatruc
Supporter XLD
Bonjour à tous,

Formule en C3 à recopier vers le bas :
VB:
=SIERREUR(--STXT($B$3;CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)));CHERCHE("]";SUBSTITUE("+"&$B$3&"+";"+";"]";1+LIGNES($3:3)))-CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)))-1);"")
 

Pièces jointes

  • cmdavid- Nombre sans plus- v1.xlsx
    9.5 KB · Affichages: 3

Staple1600

XLDnaute Barbatruc
Re

Décidemment @mapomme a mangé du @lion ;)
Avec une colonne intermédiaire
Et cette formule en C3 (à recopier vers le bas)
=SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))

extraire.png

NB: Si la vue de colonne intermédiaire gêne, on peut lui appliquer ce format : ;;;
(pour la masquer)
 
Dernière édition:

Staple1600

XLDnaute Barbatruc
Bonjour @sylvanu

@cmdavid
Je joue à Madame Irma
Au cas où, le but recherché serait de sommer les nombres contenus en B3
Cette formule le fera ;)
=SOMMEPROD(--SUPPRESPACE(STXT(SUBSTITUE(B3;"+";REPT(" ";99));(LIGNE($A$1:INDEX(A:A;NBCAR(B3)-NBCAR(SUBSTITUE(B3;"+";""))+1))-1)*99+1;99)))
Avec cette formule en B5, j'obtiens : 542
(résultat identique à la somme de C3:C10, affichée en C11))
SommePlus.png

NB: Pour sommer C3:C10, j'ai modifié ainsi ma 1ère formule en (C3)
=SIERREUR(SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))*1;"")
 
Dernière édition:

job75

XLDnaute Barbatruc
Bonjour cmdavid, JM, mapomme, sylvanu,

Une solution un peu plus soft que celle de mapomme :
Code:
=SIERREUR(--STXT(X;PETITE.VALEUR(pos;LIGNE(C1))+1;PETITE.VALEUR(pos;LIGNE(C1)+1)-1-PETITE.VALEUR(pos;LIGNE(C1)));"")
A+
 

Pièces jointes

  • Nombre sans plus.xlsx
    10.4 KB · Affichages: 1

Discussions similaires

Statistiques des forums

Discussions
311 720
Messages
2 081 910
Membres
101 837
dernier inscrit
Ugo