XL 2016 Retirer + a une série de nombre

[cmdavid]

Bonjour à tous,

J’ai une série de nombre avec + et je souhaite mettre ces nombres séparément dans une colonne sans +

Merci pour votre aide,

Cordialement,

 

[Staple1600]

Bonjour @cmdavid, le fil

Fonctionne sur Office 365
=FRACTIONNER.TEXTE(B3;;"+")

NB: Je ne sais plus si cette fonction est disponible sur Excel 2016

 

[cmdavid]

Bonjour Staple1600,
non la formule Fractionner ne fonctionne pas sur Excel 2016,

 

[mapomme]

Bonjour à tous,

Formule en C3 à recopier vers le bas :

=SIERREUR(--STXT($B$3;CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)));CHERCHE("]";SUBSTITUE("+"&$B$3&"+";"+";"]";1+LIGNES($3:3)))-CHERCHE("[";SUBSTITUE("+"&$B$3&"+";"+";"[";LIGNES($3:3)))-1);"")

 

[Staple1600]

Re

Décidemment @mapomme a mangé du @lion
Avec une colonne intermédiaire
Et cette formule en C3 (à recopier vers le bas)
=SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))

NB: Si la vue de colonne intermédiaire gêne, on peut lui appliquer ce format : ;;;
(pour la masquer)

 

[sylvanu]

Bonjour Cmdavid, Mapomme, Staple,
Ou encore avec cette petite fonction perso en VBA :

Function Découpe(C$, N)
    On Error GoTo Fin: Découpe = ""
    Découpe = Val(Split(C, "+")(N - 1))
Fin:
End Function

 

[Staple1600]

Bonjour @sylvanu

@cmdavid
Je joue à Madame Irma
Au cas où, le but recherché serait de sommer les nombres contenus en B3
Cette formule le fera
=SOMMEPROD(--SUPPRESPACE(STXT(SUBSTITUE(B3;"+";REPT(" ";99));(LIGNE($A$1:INDEX(A:A;NBCAR(B3)-NBCAR(SUBSTITUE(B3;"+";""))+1))-1)*99+1;99)))
Avec cette formule en B5, j'obtiens : 542
(résultat identique à la somme de C3:C10, affichée en C11))

NB: Pour sommer C3:C10, j'ai modifié ainsi ma 1ère formule en (C3)
=SIERREUR(SUPPRESPACE(STXT(SUBSTITUE($B$3;"+";REPT(" ";NBCAR($B$3)));($D3-1)*NBCAR($B$3)+1;NBCAR($B$3)))*1;"")

 

[cmdavid]

Bonjour à tous,
Un grand merci pour votre aide. Maintenant je dois choisir parmi toutes vos solutions.
Cordialement,

 

[job75]

Bonjour cmdavid, JM, mapomme, sylvanu,

Une solution un peu plus soft que celle de mapomme :

=SIERREUR(--STXT(X;PETITE.VALEUR(pos;LIGNE(C1))+1;PETITE.VALEUR(pos;LIGNE(C1)+1)-1-PETITE.VALEUR(pos;LIGNE(C1)));"")

A+

 

[cmdavid]

Bonjour cmdavid, JM, mapomme, sylvanu,

Une solution un peu plus soft que celle de mapomme :

=SIERREUR(--STXT(X;PETITE.VALEUR(pos;LIGNE(C1))+1;PETITE.VALEUR(pos;LIGNE(C1)+1)-1-PETITE.VALEUR(pos;LIGNE(C1)));"")

A+

Merci