[RÉSOLU] Si cellule contient un des arguments d'une liste

chouch2 · 3 Février 2014

Bonjour à tous, forumeuses et forumeux !

Dans le principe, ma question est la suivante : existe-t-il une formule telle que si A1 contient un des mots de LISTE_1, alors renvoyer "MOT_CLEF_1" en B1 ?

Dans le détail :
- la colonne A contient une liste d'expressions (par ex. : "avoir l'eau à la bouche" ; "Tirer les vers du nez" ; "Sur le bout des doigts")

- la liste LISTE 1 contient un certain nombre de mots ayant trait aux bras, aux mains (par ex. : doigts, pouce, main, coude, bras) et la liste LISTE 2 contient des mots relatifs au visage, à la tête (nez, bouche, lèvres, front...)

- la colonne B est ma cible => si A1 contient un mot appartenant à la liste CIBLE 1, je souhaite que B1 affiche "mot clef 1" ; et si A1 contient un des mots de la liste CIBLE 2, je souhaite que B1 renvoie "mot clef 2"

Ainsi, un exemple :
- si A1 contient l'expression "avoir l'eau à la bouche" => B1 devrait renvoyer "mot clef 2" puisque "bouche" fait partie de la liste LISTE 2

Je joins un classeur pour me rendre plus compréhensible !

Pour info, et afin de me passer des listes, j'ai déjà essayé cette formule en B1 :

=SI(NB.SI(A1;OU("*nez*";"*bouche*";"*oeil*";"*yeux*");"mot clef 2";"")

Malheureusement, cette formule ne semble pas supporter le OU

Je continue à chercher sur le forum en attendant la bienheureuse aide que l'un de vous pourra peut-être m'apporter ^^

D'avance merci à vous !

chouch

R@chid · 3 Février 2014

Re : Si cellule contient un des arguments d'une liste

Bonsoir,
Si j'ai bien compris, en B2,

Code:

=SI(SOMMEPROD(NB.SI(A2;"*"&F$2:F$10&"*"));"Bras / Mains / Doigts";SI(SOMMEPROD(NB.SI(A2;"*"&G$2:G$13&"*"));"Tête / Visage";""))

@ tirer vers le bas

@ + +

chouch2 · 3 Février 2014

Re : Si cellule contient un des arguments d'une liste

Merci infiniment R@chid !!! C'est exactement ça !

Je ne connaissais pas la fonction SOMMEPROD employée ainsi, ni le pouvoir du "*", je vais de ce pas essayer d'en savoir davantage sur eux. En attendant, encore mille mercis pour ta réponse si rapide et si exactement-ce-qu'il-fallait !!

Salut !

Jouxte · 4 Janvier 2021

Bonjour à toutes et tous,

Je rouvre ce fil qui correspond bien à ce que je recherche sauf que je souhaiterai que la formule me dise, si cellule contient un des arguments d'une liste quel est cet argument.

Meilleurs vœux pour 2021.

R@chid · 4 Janvier 2021

Bonjour,
en B2 :

VB:

=SIERREUR(SIERREUR(INDEX(F$2:F$10;EQUIV(9^9;CHERCHE(F$2:F$10;A2)));INDEX(G$2:G$13;EQUIV(9^9;CHERCHE(G$2:G$13;A2))));"")

@ valider par Ctrl+Maj+Entrée
@ tirer vers le bas

Cordialement

Jouxte · 4 Janvier 2021

Bonjour R@chid,
merci pour cette réponse rapide et efficace. Bonne soirée.

ManRUE · 1 Mars 2022

R@chid à dit:
Bonjour,
en B2 :

VB:

=SIERREUR(SIERREUR(INDEX(F$2:F$10;EQUIV(9^9;CHERCHE(F$2:F$10;A2)));INDEX(G$2:G$13;EQUIV(9^9;CHERCHE(G$2:G$13;A2))));"")

@ valider par Ctrl+Maj+Entrée
@ tirer vers le bas

Cordialement

Bonjour R@chid,

Merci pour ta formule !
Pourquoi avoir écrit 9^9 en valeur recherchée pour EQUIV ?
Merci d'éclairer ma lanterne ...

Belle journée !

[RÉSOLU] Si cellule contient un des arguments d'une liste

chouch2

XLDnaute Nouveau

Pièces jointes

R@chid

XLDnaute Barbatruc

chouch2

XLDnaute Nouveau

Jouxte

XLDnaute Occasionnel

R@chid

XLDnaute Barbatruc

Jouxte

XLDnaute Occasionnel

ManRUE

XLDnaute Nouveau

Discussions similaires